{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: SJMESS867)}}
====== SJMESS867 ======
(George Source)
**Macros used:** [[george:macro:ALTLEN|ALTLEN]], [[george:macro:CATMASK|CATMASK]], [[george:macro:CHEKPRIV|CHEKPRIV]], [[george:macro:CHNUMCO1|CHNUMCO1]], [[george:macro:COMERR|COMERR]], [[george:macro:COMERRX|COMERRX]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FJOCA|FJOCA]], [[george:macro:FREECORE|FREECORE]], [[george:macro:HUNTW|HUNTW]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREE|MFREE]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:PARABEG|PARABEG]], [[george:macro:PARAFREE|PARAFREE]], [[george:macro:PARALYSE|PARALYSE]], [[george:macro:PARANUMB|PARANUMB]], [[george:macro:PARAPASS|PARAPASS]], [[george:macro:PARSPLIT|PARSPLIT]], [[george:macro:PARUNACC|PARUNACC]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SJANAMON|SJANAMON]], [[george:macro:SJCHAIN|SJCHAIN]], [[george:macro:SPARANOT|SPARANOT]], [[george:macro:TESTHOOK|TESTHOOK]], [[george:macro:TESTREP|TESTREP]], [[george:macro:TESTREP2|TESTREP2]], [[george:macro:TESTREPNOT|TESTREPNOT]], [[george:macro:TRACE|TRACE]], [[george:macro:UNIFREE|UNIFREE]]
22FL #SEG SJMESS70 [K.KOSKUBA
22KH .._
22PD ...[ (C) COPYRIGHT INTERNATIONAL CCOMPUTERS LTD 1982
22T* ...[
22^= #LIS K0SJMESS>K0ALLGEO>0
23DW 8HSJMESS
23YG # THIS SEGMENT ANALYSES THE PARAMETERS FOR THE SJMESS OR
24D6 # SJ COMMAND, AND PROCESSES THE COMMAND IF THESE ARE VALID
24K# ...#UNS G400
24QG ...# THIS CHAPTER IS FOR G3PLUS-IH MK2
24XQ # THAT IS A GMON/JRNAL BLOCK IS APPROPRIATELY SET UP AND
25CB # PUT ON THE JOURNAL CHAIN
25X2 # CHECK CONTEXT AND PRIVILEGE IF NOT OPERATOR
26BL SEGENTRY K1SJMESS,XK1SJ
26W= SJPNL +JPARNULL
27*W SJPARMIS +JPARMIS
27TG SJTOOMANY +JTOOMANY
28*6 SJOPUCON +JOPUCON
28SQ SJMAX +JMAX
29#B SPUNP +ERUNPAIR
29S2 SERB4 +ERB4
2=?L SJEXCHARS +JEXCHARS
2=R= SJERMCH +ERMCH
2?34 ...SJMAXPAR +JMAXPAR
2?=W SCONT 8HCONTEXT
2?QG SJMK CATMASK OL,JL
2#=6 XK1SJ
2#C# ...#UNS G400
2#JG ... TESTHOOK SJMS1
2#PQ LDX 5 CONTEXT(2) [PICK UP CONTEXT WORD FROM CPAT
2*9B ANDN 5 #12
2*P2 ERN 5 #12
2B8L BZE 5 R10 [J TO COMERR IF MOP AND NO USER
2BN= LDX 5 CONTEXT(2)
2C7W ANDN 5 #42
2CMG ERN 5 #42
2D76 BZE 5 R10 [J TO COMERR IF READER AND NO USER
2DLQ LDX 5 CONTEXT(2)
2F6B ANDN 5 #22
2FL2 ERN 5 #22
2G5L BZE 5 SJMS1 [J IF OPERATOR
2GK= LDX 5 CONTEXT(2)
2H4W ANDN 5 1
2HJG BZE 5 R10 [J IF USER CONTEXT BIT NOT SET
2J46 CHEKPRIV JOB,0(1),R20,NOTOPEN [CHECK IF USER HAS SJMESS PRIVILEGE
2JHQ # IF COMMAND ISSUED IN USER CONTEXT
2K3B #PAGE
2KH2 SJMS1
2L2L LDCT 7 #430
2LG= #SKI K6SJMESS>99-99
2L^W (
2MFG TRACE 7,SJME
2M^6 )
2NDQ CALL 4 SP1 [FIND C PARAMETER
2NYB MHUNT 3,CPB,CUNI
2PD2 LDX 5 JPARNUM(3)
2PXL LDX 4 ANUM(3)
2QC= BZE 4 SJMS2
2QWW SRL 4 12
2RBG SBN 4 2
2RW6 BNZ 4 R30 [J TO COMMAND ERROR IF FORMAT INVAL
2S*Q CALL 7 PRBK
2STB LDN 5 1
2T*2 PARALYSE #34,,5
2TJS ... TESTREP2 TOOMANY,SJERR
2TSL SJANAMON SJE
2W#= LDX 4 ACOMMUNE1(2)
2WRW SJMS2
2X?G ORX 4 SJMK(1) [SET OL & JL CATEGORIES
2XR6 #SKI K6SJMESS>99-99
2Y=Q (
2YQB TRACE 4,SJCX
2^=2 )
2^PL STO 4 AWORK2(2) [REMEMBER CATEGORIES IN AWORK2
329= PARAFREE
32NW #PAGE
338G LDCT 7 #520
33N6 CALL 4 SP1 [FIND MANDATORY J PARAMETER
347Q MHUNT 3,CPB,CUNI
34MB LDX 4 ANUM(3)
3572 BZE 4 SJM10 [J IF NULL PARAMETER
35LL LDX 4 APARA(3)
366= CALL 6 SCHNUM
36KW LDX 5 ACOMMUNE1(2)
375G ADN 5 1
37K6 BNZ 5 SJM20 [J IF NOT NULL PARAMETER
384Q SJM10
387W ... LDX 3 CTEXT(2) [LET'S SEE IF IT'S
38?2 ... ANDN 3 2 [IN USER CONTEXT
38B6 ... LDN 5 1
38F= ... BNZ 3 SJM25 [J IF NOT
38JB FJOCA 3,2
3942 LDX 5 JOBNM(3)
39HL ADN 5 1
3=3= SJM20
3=GW BPZ 5 SJM25 [J IF VALID JOB NUMPER
3?2G COMERR APFERR,JINVJNO
3?G6 SJM25
3?^Q SBN 5 1
3#FB STO 5 AWORK3(2) [STORE JOB NUMBER IN AWORK3
3#^2 MFREE CPB,CUNI
3*DL LDCT 7 #550
3*Y= CALL 4 SP1 [FIND MANDATORY M PARAMETER
3BCW STOZ AWORK4(2)
3BXG MHUNT 3,CPB,CUNI
3CC6 LDX 4 ANUM(3)
3CWQ BZE 4 SJM30 [J IF M PARAMETER NULL IE
3DBB # IF MESSAGE NO. ZERO
3DW2 LDX 4 APARA(3)
3F*L CALL 6 SCHNUM
3FT= LDX 5 ACOMMUNE1(2)
3G#W STO 5 AWORK4(2) [SET MESSAGE NUMBER
3GSG LDN 5 #7777
3H#6 TXL 5 AWORK4(2)
3HRQ BCC SJM30
3J?B LDX 5 SJMAX(1)
3JR2 LDN 6 4
3K=L LDCT 7 #40
3KQ= ADN 7 #1105
3L9W BRN SPER
3LPG SJM30
3M96 MFREE CPB,CUNI
3MNQ #PAGE
3N8B LDCT 6 #412
3NN2 ADN 6 #2020
3P7L LDN 7 #6564
3PM= SLL 7 6
3Q6W ORX 7 6
3QLG CALL 4 SPO1 [TRY TO FIND A OR AUT PARAMETER
3R66 LDX 2 FX2
3RKQ STO 7 ACOMMUNE6(2)
3S5B LDCT 6 #560
3SK2 ADN 6 #2020
3T4L LDN 7 #5767
3TJ= SLL 7 6
3W3W ORX 7 6
3WHG STOZ AWORK1(2)
3X36 CALL 4 SPO1
3XGQ LDX 2 FX2
3Y2B LDX 4 ACTNUM(2)
3YG2 BZE 7 SJM40 [J IF NON AUT INDICATOR NOT SET
3Y^L STO 4 AWORK1(2)
3^F= SJM40
3^YW ADX 7 ACOMMUNE6(2)
42DG BVSR SPO60
42Y6 BNZ 7 SJM45
43CQ LDX 7 6
43XB LDX 6 5
44C2 BRN SPER1
44WL SJM45
45B= LDCT 6 #650
45TW LDCT 7 #650
46*G CALL 4 SPO1 [TRY AND FIND U PARAMETER
46T6 LDX 2 FX2
47#Q STO 7 ACOMMUNE6(2)
47SB # FREE ALL CPB/CUNI BLOCKS
48#2 UNIFREE
48RL SJM49
49?= LDCT 6 #600
49QW LDCT 7 #600
4==G CALL 4 SPO1 [TRY AND FIND P PARAMETER
4=Q6 LDX 2 FX2
4?9Q ADX 7 ACOMMUNE6(2)
4?PB BVSR SPO60
4#92 BNZ 7 SJM50
4#NL LDX 7 6
4*8= LDX 6 5
4*MW BRN SPER1
4B7G SJM50
4BM6 LDX 5 ACOMMUNE6(2)
4C6Q LDX 6 AWORK2(2)
4CLB LDCT 4 #40
4D62 ANDX 6 4
4DKL BPZ 5 SJM60 [J IF PACKED
4F5= BZE 6 SJM70 [J IF NON-PACKED
4FJW SJM55
4G4G COMERR APFERR,JINCPM
4GJ6 SJM60
4H3Q LDX 7 AWORK4(2)
4HHB BZE 7 SJM55 [J IF ZERO MESSAGE NO. & PACKED
4J32 ORS 4 AWORK2(2) [STORE BIT 3 IN CATEGORY WORD
4JGL #PAGE
4K2= SJM70
4KFW SETNCORE 24+JMESSAGE-JWAITER,3,GMON,JRNAL
4K^G STOZ JWAITER(3)
4LF6 LDN 4 JWAITER(3)
4LYQ LDN 5 JRECHEAD1(3)
4MDB MOVE 4 23+JMESSAGE-JWAITER
4MY2 LDX 4 AWORK1(2)
4NCL STO 4 JWAITER(3) [SET JWAITER
4NX= LDX 5 AWORK2(2)
4PBW LDX 6 AWORK3(2)
4PWG STO 5 JCATS(3) [SET CATEGORIES
4QB6 STO 6 JJOBNO(3) [STORE JOBNO.
4QTQ LDX 6 AWORK4(2) [PICK UP MESSAGE NO.
4R*B SLL 6 12
4RT2 STO 6 JPACKORG(3) [STORE MESSAGE NO. IN M S G 12 BITS
4S#L LDN 7 24
4SS= STO 7 AWORK3(2) [SET COUNT OF UNUSED WORDS
4T?W # SET GMON/JRNAL POINTER
4TRG LDN 7 JMESSAGE
4W?6 STO 7 AWORK4(2)
4WQQ SLL 5 3
4X=B BPZ 5 WA1 [ J IF UNPACKED MESSAGE
4XQ2 #PAGE
4Y9L # ROUTINE TO ANALYSE THE P PARAMETER
4YP= MHUNT 2,CPB,CUNI
4^8W LDX 4 ANUM(2)
4^NG BZE 4 WA1
5286 LDX 5 JPARNUM(2)
52MQ SRL 4 12
537B BZE 4 SPA10
53M2 SBN 4 1
546L BZE 4 SPA10 [J TO PACKED CHAR. FORMAT ROUTINE
54L= SBN 4 1
555W BZE 4 SPOCT
55KG FREECORE 3
5656 BRN SJM55
56JQ SPOCT
574B CALL 7 PRBK
57J2 LDN 5 1
583L PARALYSE #34,,5
58?D ... TESTREP2 TOOMANY,SJERR
58H= MHUNT 2,CPB,CMULTI
592W LDX 5 ANALEV(2)
59GG PARANUMB 4,5
5=26 ANDN 4 #7777
5=FQ MHUNT 3,GMON,JRNAL
5=^B DSA 4 JPACKORG(3) [DUMP NO. OF PDC'S IN LSG 12BTS
5?F2 # IN JPACKORG
5?YL ADN 4 1 [ADD 1 FOR ROUNDING
5#D= SRA 4 2
5#XW CALL 6 SALT [SSEE IF GMON/JRNAL SIZE O.K.
5*CG LDN 4 #7777
5*X6 ANDX 4 JPACKORG(3) [ISOLATE PDC'S
5BBQ LDN 5 4
5BWB LDN 3 0
5CB2 LDN 7 0
5CTL SPA1
5D*= PARAPASS
5DSW CALL 6 SCHNUM
5F#G LDX 6 ACOMMUNE1(2)
5FS6 DCH 6 7(3)
5G?Q SBN 6 64
5GRB BNG 6 SPA25
5H?2 LDN 6 63
5HQL MHUNT 2,CPB,CUNI
5J== STO 6 APARA(2)
5JPW LDX 5 SJMAX(1)
5K9G BRN SPERCX
5KP6 SPA25
5L8Q MFREE CPB,CUNI
5LNB BCHX 3 £
5M82 BCT 5 SPA4
5MML SPA3
5N7= MHUNTW 1,GMON,JRNAL
5NLW LDX 2 FX2
5P6G LDX 6 AWORK4(2) [X6= POSITION IN GMON/JRNAL
5PL6 SMO 6
5Q5Q STO 7 0(1)
5QKB ADN 6 1 [UPDATE POINTER WI0HIN GMON/JRNAL
5R52 STO 6 AWORK4(2)
5RJL LDN 5 4
5S4= LDN 7 0
5SHW LDN 3 0
5T3G BZE 4 WA10
5TH6 SPA4
5W2Q BCT 4 SPA1
5WGB SBN 5 4
5X22 BNZ 5 SPA3
5XFL WA10
5X^= PARAFREE
5YDW BRN WA1
5YYG # PDC CHARACTER FORMAT
5^D6 SPA10
5^XQ LDX 4 ANUM(2)
62CB ANDN 4 #7777
62X2 ADN 4 1 [ADD 1 FOR ROUNDING
63BL SRA 4 2
63W= CALL 6 SALT [LENGTHEN GMON/JRNAL IF NECESSARY
64*W MHUNT 2,CPB,CUNI
64TG SMO 4
65*6 STOZ JPACKORG(3) [ZEROISE LAST MESSAGE WD FOR FILLING
65SQ LDX 1 ANUM(2)
66#B ANDN 1 #7777
66S2 DSA 1 JPACKORG(3) [SET PDC COUNT
67?L ADN 3 JMESSAGE
67R= ADN 2 APARA
68=W MVCH 2 0(1) [MOVE IN PDC'S
68QG SMO FX2
69=6 ADS 4 AWORK4
69PQ #PAGE
6=9B # WORD PARAMETER ANALYSING ROUTINE
6=P2 WA1
6?8L PARUNACC [GET NEXT UNACCESSED PARAMETER
6?N= # IF IT EXISTS
6#7W MHUNT 2,CPB,CUNI
6#MG LDX 5 ANUM(2)
6*76 ADN 5 1
6*LQ BZE 5 TEND [J IF NO MORE PARAMETERS
6B6B ADN 2 APARA
6BL2 LDCH 3 0(2) [PICK UP MSG CHARACTER
6C5L LDN 4 #67
6CK= TXU 3 4
6D4W BCS TA1 [J IF NOT W
6DJG LDN 4 1
6F46 CALL 6 SALT [LENGTHEN GMON/JRNAL IF NECESSARY
6FHQ PARSPLIT 5
6G3B TESTREPNOT OK,R30
6GH2 LDX 6 ACOMMUNE1(2)
6H2L MHUNTW 3,GMON,JRNAL
6HG= ADX 3 AWORK4(2)
6H^W STO 6 0(3)
6JFG LDN 5 1
6J^6 ADS 5 AWORK4(2) [RESET POINTER WITHIN GMON/JRNAL
6KDQ BRN WA1 [J TO LOOK AT NEXT PARAMETER
6KYB #PAGE
6LD2 TA1
6LXL LDN 4 #64
6MC= SBN 2 APARA
6MWW LDX 5 JPARNUM(2)
6NBG TXU 3 4
6NW6 BCS RG2 [J IF PARAMETER NOT RECOGNIZED
6P*Q CALL 7 PRBK
6PTB MFREE CPB,CMULTI
6Q*2 SPARANOT 2 [COPY CPB/CMULTI TO CPB/CUNI
6QSL MHUNT 2,CPB,CUNI
6R#= LDX 4 ANUM(2)
6RRW ANDN 4 #7777 [ISOLATE CHARACTER COUNT
6S?G SBN 4 1 [REDUCE CH COUNT FOR TEXT I.E FOR ()
6SR6 SRA 4 2
6T=Q BZE 4 WA1 [J IF TEXT PARAMETER NULL
6TQB CALL 6 SALT [ALTER GMON/JRNAL LENGTH IF NEC.
6W=2 SMO FX2
6WPL ADX 3 AWORK4 [GET POINTER FOR GMON/JRNAL
6X9= MHUNT 2,CPB,CUNI
6XNW LDX 5 ANUM(2) [PICK UP CHARACTER COUNT
6Y8G SBN 5 2 [REDUCE IT BY 2
6YN6 STO 5 ANUM(2) [RESET ANUM
6^7Q ADN 2 APARA
6^MB ANDN 5 #7777
7272 LDX 6 2 [REMEMBER ADDRESS OF APARA
72LL LDCT 1 #200 [SET CH BIT FOR CH1.
736= ADX 1 2 [X1=APARA.1
73KW SMO 5
745G MVCH 1 0 [REMOVE (
74K6 LDN 7 #20
754Q DCH 7 0(2) [SET MOVED )= SPACE
75JB BCHX 2 £
7642 DCH 7 0(2) [SET ORIGINAL )= SPACE
76HL LDX 2 6 [RESET X2=ADDRESS OF APARA
773= SMO 4
77GW MOVE 2 0
782G SMO FX2
78G6 ADS 4 AWORK4 [RESET POINTER WITHIN GMON/JRNAL
78^Q BRN WA10
79FB TEND
79^2 MHUNTW 3,GMON,JRNAL
7=DL LDX 2 FX2
7=Y= #PAGE
7?CW SJC
7?XG LDX 5 AWORK4(2)
7#C6 SBN 5 JMESSAGE
7#WQ SLA 5 2
7*BB SJCHAIN 3,5
7*W2 SJE
7B*L ENDCOM
7BT= #PAGE
7C#W # SUBROUTINE TO VERIFY THAT A PARAMETEREXISTS AND IS NOT
7CSG # ERRONEOUSLY REPEATED
7D#6 SP1
7DRQ SBX 4 FX1
7F?B STOZ AWORK1(2)
7FR2 LDN 6 1
7G=L SP2
7GQ= PARABEG 1,6,,,0
7H9W MHUNT 3,CPB,CUNI
7HPG LDX 5 ANUM(3)
7J96 ADN 5 1
7JNQ BNZ 5 SP3
7K8B LDX 5 AWORK1(2)
7KN2 BNG 5 SP5 [J TO EXIT IF NO 2ND PARAMETER FOUND
7L7L SPER1
7LM= LDX 5 SJPARMIS(1)
7M6W BRN SPER
7MLG SP3
7N66 LDX 5 AWORK1(2)
7NKQ BPZ 5 SP4
7P5B SPER2
7PK2 LDX 5 SJTOOMANY(1)
7Q4L BRN SPERCX
7QJ= SPER
7R3W LDN 4 4
7RHG SPER3
7S36 MHUNT 3,CPB,CUNI
7SGQ ALTLEN 3,4,CPB,CUNI
7T2B MHUNT 1,CPB,CUNI
7TG2 STO 6 ANUM(1)
7T^L STO 7 APARA(1)
7WF= SBN 6 5
7WYW BNG 6 SPERCX
7XDG LDX 0 7
7XY6 ADN 1 APARA
7YCQ MOVE 0 2
7YXB SPERCX
7^C2 COMERRX 5
7^WL SP4
82B= LDCT 5 #400
82TW STO 5 AWORK1(2)
83*G BRN SP2
83T6 SP5
84#Q FREECORE 3 [FREE CPB/CUNI BLOCK
84SB ADX 4 FX1
85#2 EXIT 4 0
85RL #PAGE
86?= # SUBROUTINE TO ALTER LENGTH OF GMON/JRNAL
86QW SALT
87=G SBX 6 FX1
87Q6 SMO FX2
889Q LDX 7 AWORK3
88PB MHUNTW 3,GMON,JRNAL
8992 TXL 4 7
89NL BCS SALT1
8=8= SBX 7 4
8=MW NGX 7 7
8?7G ADN 7 10
8?M6 ADX 7 ALOGLEN(3)
8#6Q ALTLEN 3,7,GMON,JRNAL
8#LB LDN 7 10
8*62 MHUNTW 3,GMON,JRNAL
8*KL SMO FX2
8B5= STO 7 AWORK3
8BJW SMO FX2
8C4G LDX 7 AWORK4
8CJ6 ADX 7 4
8D3Q SBN 7 501
8DHB BNG 7 SALT2
8F32 FREECORE 3
8FGL LDX 5 SJEXCHARS(1)
8G2= BRN SPERCX
8GFW SALT1
8G^G SMO FX2
8HF6 SBS 4 AWORK3
8HYQ SALT2
8JDB ADX 6 FX1
8JY2 EXIT 6 0
8KCL # SUBROUTINE TO VALIDATE AND CONVERT A DECIMAL NO. TO BIN.
8KX= SCHNUM
8LBW SBX 6 FX1
8LWG CHNUMCO1
8MB6 TESTREP CHNUMERR,RG1
8MTQ ADX 6 FX1
8N*B EXIT 6 0
8NT2 #PAGE
8P#L SPO1
8PS= SBX 4 FX1
8Q?W STOZ 3
8QRG LDN 5 1
8R?6 SPO20
8RQQ PARABEG 1,5,,,0
8S=B MHUNT 2,CPB,CUNI
8SQ2 LDX 0 ANUM(2)
8T9L ADN 0 1
8TP= BZE 0 SPO30
8W8W ADN 3 1 [ADD 1 TO PARAMETER COUNT
8WNG BRN SPO20
8X86 SPO30
8XMQ TXU 6 7
8Y7B BCC SPO40 [J IF SINGLE CH. ONLY
8YM2 LDX 6 7
8^6L ADN 5 2
8^L= BRN SPO20
925W SPO40
92KG LDN 7 0
9356 BZE 3 SPO50 [J IF NO PARAMETER
93JQ SBN 3 1
944B BNZ 3 SPO60
94J2 LDCT 7 #400
953L SPO50
95H= ADX 4 FX1
962W BNZ 7 SPO52 [FREE CPB/CUNI
96GG LDCT 3 #600
9726 TXU 3 6
97FQ BCC SPO55
97^B SPO52
98F2 MFREE CPB,CUNI
98YL SPO55
99D= EXIT 4 0
99XW SPO60
9=CG LDX 7 6
9=X6 LDX 6 5
9?BQ BRN SPER2 [J TO ERROR : TOO MANY PARAMETERS
9?WB #PAGE
9#B2 # SUBROUTINE TO PARABEG A SINGLE PARAMETER
9#TL SPBG
9**= SBX 7 FX1
9*SW PARABEG 1,5,,,0
9B#G MHUNT 2,CPB,CUNI
9BS6 LDX 4 ANUM(2)
9C?Q ADX 7 FX1
9CRB BZE 4 SPBG2
9D?2 ADN 4 1
9DQL BZE 4 SPBG1 [J IF PARAMETER NOT FOUND
9F== EXIT 7 2
9FPW SPBG1
9G9G EXIT 7 0
9GP6 SPBG2
9H8Q EXIT 7 1
9HNB #PAGE
9J82 # SUBROUTINE TO SET UP MULTI BLK TO BE PARAPASSED
9JML PRBK
9K7= SBX 7 FX1
9KLW PARALYSE ,,5
9KWN ... TESTREP2 TOOMANY,SJERR
9L6G TESTREP UNPAIR,RG3
9LL6 LDN 5 2
9M5Q PARALYSE ,,5
9M*J ... TESTREP2 TOOMANY,SJERR
9MKB TESTREP UNPAIR,RG3
9N52 ADX 7 FX1
9NJL EXIT 7 0
9P4= #PAGE
9PHW RG1
9Q3G HUNTW 3,GMON,JRNAL
9QH6 BNG 3 SJE
9R2Q FREECORE 3 [FREE GMON/JRNAL IF IT EXISTS
9RGB BRN SJE
9S22 RG2 MFREEW GMON,JRNAL
9SFL SMO FX1
9S^= LDX 5 SJTOOMANY
9TDW BRN SPERCX
9TYG R10
9WD6 SMO FX1
9WXQ LDX 5 SJOPUCON
9XCB BRN SPERCX
9XX2 R20
9YBL COMERR ERB4,ERSJMESS
9YW= R30
9^*W COMERR APFERR
9^TG TERX
=2*6 LDX 7 6
=2SQ LDX 6 5
=3#B SMO FX1
=3S2 LDX 5 SJPNL
=4?L TERX1
=4R= MFREEW GMON,JRNAL
=5=W BRN SPER
=5QG RG3
=6=6 HUNTW 3,GMON,JRNAL
=6PQ BNG 3 RG32 [J IF NO GMON/JRNAL
=79B FREECORE 3
=7P2 RG31
=88L SMO FX1
=8N= LDX 5 SPUNP
=97W BRN SPERCX
=9MG RG32
==76 MFREE CPB,CUNI
==LQ BRN RG31
==QM ...SJERR
==WJ ... LDX 5 SJMAXPAR
=?2F ... BRN SPERCX
=?6B MENDAREA 150
=?L2 #END
^^^^ ...15513170000100000000