{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: SOUP867)}}
====== SOUP867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:CAPCA|CAPCA]], [[george:macro:CHECKEXT|CHECKEXT]], [[george:macro:COMBRKIN|COMBRKIN]], [[george:macro:COMERR|COMERR]], [[george:macro:COMERRX|COMERRX]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FNORM|FNORM]], [[george:macro:FOUTMOVE|FOUTMOVE]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HLSXONCH|HLSXONCH]], [[george:macro:ILLEGAL|ILLEGAL]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUT|MONOUT]], [[george:macro:NAMETOP|NAMETOP]], [[george:macro:OFF|OFF]], [[george:macro:OUTBLOCN|OUTBLOCN]], [[george:macro:OUTPACK|OUTPACK]], [[george:macro:PHOTO|PHOTO]], [[george:macro:PROGBRKIN|PROGBRKIN]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SPARANOT|SPARANOT]], [[george:macro:STEPBACK|STEPBACK]], [[george:macro:TESTMOVE|TESTMOVE]], [[george:macro:TESTREPNOT|TESTREPNOT]]
228= ...#SEG SOUP867
22BG ...#
22JQ ...# COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
22R2 ...#
22^= #LIS K0SOUP
23DW 8HSOUP
23YG #
24D6 # STORAGE DEVICE ONLINE COMMAND AND UNANTICIPATED OPEN PERI
24XQ # - - - -
25CB #
25X2 #
26BL SEGENTRY K1SOUP,QK1SOUP
26W= SEGENTRY K2SOUP,QK2SOUP
27*W #
27TG #
28*6 # ONLINE
28SQ #
29#B # THIS SECTION DEALS WITH ONLINE COMMAND FOR SD,EXCEPT SCRATCH
29S2 # ON ENTRY,PARAMETER 1 HAS BEEN ANALYSED AND RESULT IS IN A CPAR/
2=?L # GPERCON BLOCK.PARAMETER 2 IS FILENAME,WHICH WE ANALYSE.EXITS TO
2=R= ...# EXOPEN WITH EWDAS/GEXD AND EWDAS/EXOF BLOCKS SET UP
2?=W ...# FOR OPENING THE FILE
2?QG #
2#=6 #
2#PQ #DEF RVGE=20
2*9B XGIVE +AGIVE [FOR MASKING GIVE QUALIFIER
2*P2 X4096 +4096 [GENERATION NR COMPARISON
2B8L SIX7S #777777 [MASK FOR SERIAL NR
2BN= RMESS +JEXCSN [INVALID SERIAL NUMBER
2C7W #
2CMG #
2D76 QK1SOUP
2F6B MHUNTW 1,CPAR,GPERCON
2FL2 LDX 0 A1+1(1)
2G5L ANDN 0 #777
2GK= SBN 0 #600
2H4W BNZ 0 NOTS [J IF NOT SCRATCH
2HJG ACROSS SCRATCH,2
2J46 NOTS
2JHQ #SKI K6SOUP>199-199
2K3B (
2KH2 ADN 0 #600 [CHECK THAT MODE IS #100-#400
2L2L LDN 6 4
2LG= NTB SBN 0 #100
2L^W BZE 0 NTA
2MFG BCT 6 NTB
2M^6 NTC GEOERR 1,SD OL
2PD2 NTA LDX 0 A1(1)
2PXL SRL 0 15
2RW6 SBN 0 6
2W#= BZE 0 NTD
2WRW ... SBN 0 20
2X?G BNZ 0 NTC
2XR6 NTD
2Y=Q )
2YQB SPARANOT 2 [GET SECOND PARAMETER IN UNI BLOCK
2^=2 MHUNT 3,CPB,CUNI
2^PL NAMETOP 3,FILE,FNAME
329= PHOTO 6
32NW FNORM 1 [CONVERT FILENAME
338G TESTMOVE 6,MOVF
33N6 MHUNT 3,FILE,FNAME
347Q MOVF NAMETOP 3,CPB,CUNI
34MB TESTREPNOT NAMEFORM,NF [J IF FILENAME OK
3572 ENDCOM [ELSE END,FNORM HAS OUTPUT ERROR
35LL NF SETNCORE FDCELLS-A1,1,EWDAS,EXOF [CREATE EXOF
366= STOZ BACK1(1)
36KW STOZ BACK2(1) [CLEAR BACK1,ETC
375G STOZ COPEN(1)
37K6 STOZ EXMARK(1)
384Q LDX 7 1 [SAVE ITS ADDRESS
38JB PHOTO 6
3942 SETNCORE GEXDLEN,3,EWDAS,GEXD [CREATE GEXD
39HL STOZ A1(3)
3=3= LDN 4 A1(3) [AND ZEROISE IT
3=GW LDN 5 A1+1(3)
3?2G MOVE 4 GEXDLEN-1
3?G6 LDCT 4 256 [REVISED GENERATION NUMBER
3?^Q TESTREPNOT ADJUNCTS,NAJ [J IF NO QUALIFIER TO FILE NAME
3#FB MHUNTW 2,FILE,ADJUNCTS [FIND ADJUNCTS BLOCK
3#FY ...#
3#GG ...# LOOK FOR 'NOWAIT' AND 'REPLY' QUALIFIERS
3#H4 ...#
3#HL ... LDN 5 0
3#J8 ... LDX 0 A1+1(2) [PICK UP QUALIFIERS WORD
3#JQ ... ANDN 0 AREPLY
3#K# ... BZE 0 NOTREPLY [JIF NO REPLY QUALIFIER
3#KW ... ORN 5 BREPQUAL [ELSE SET MARKER FOR /EXOF
3#LD ...#
3#M2 ...NOTREPLY
3#MJ ... LDX 0 A1+1(2) [NOW WE LOOK AGAIN FOR THE NOWAIT
3#N6 ... ANDN 0 ANOWAIT [QUALIFIER
3#NN ... BZE 0 NOTNOWAIT [JIF NO NOWAIT QUALIFIER
3#P= ... ORN 5 BSUPP [SET DON'T SUSPEND MARKER FOR /EXOF
3#PS ...#
3#QB ...NOTNOWAIT
3#QY ... BZE 5 TRYGIVE [JIF NOTHING TO ADD TO /EXOF
3#RG ... LDX 1 7 [ELSE GET BACK POINTER TO /EXOF
3#S4 ... TESTMOVE 6,NOTMOVED [JIF POINTER TO /EXOF IS STILL OK
3#SL ... MHUNTW 1,EWDAS,EXOF [ELSE REFIND BLOCK
3#T8 ...#
3#TQ ...NOTMOVED
3#W# ... ORS 5 EXMARK(1) [NOTE PRESENCE SPECIFIED QUALIFIERS
3#WW ... LDX 1 FX1
3#XD ...#
3#Y2 ...TRYGIVE
3#^2 LDX 0 XGIVE(1)
3*DL ANDX 0 A1+1(2)
3*Y= BZE 0 NGIV [J IF GIVE QUALIFIER ABSENT
3BCW LDN 0 1
3BXG STO 0 GIVEX(3) [SET MARKER IN GEXD
3CC6 NGIV LDX 0 ALOGLEN(2)
3CWQ SBN 0 ADPAIR-A1 [SEE IF ANY MORE QUALIFIERS
3DBB NEXT BZE 0 NRVG [BRANCH IF NO
3DW2 SMO 0
3F*L LDX 5 ADPAIR-2(2)
3FT= SBN 5 RVGE [SEE IF REVISED GENERATION....
3G#W BZE 5 NOKR [...NUMBER QUALIFIER(REVGEN)
3GSG SBN 0 2
3H#6 BRN NEXT
3HRQ NOKR SMO 0
3J?B LDX 4 ADPAIR-1(2) [REMEMBER REVGEN
3JR2 NRVG FREECORE 2 [FREE ADJUNCTS BLOCK
3K=L NAJ MHUNTW 2,CPAR,GPERCON
3KQ= STO 4 ENEWG(3) [STORE REVGEN IN GEXD FOR CHINTEG
3L9W LDX 0 A1+1(2)
3LPG ANDN 0 #777
3M96 BNZ 0 NOQ [J IF QUALIFIER
3MNQ LDN 0 #200 [ELSE SET AS READ
3N8B NOQ STO 0 EOPMODE(3)
3NN2 BNG 4 NNRV
3P7L SBN 0 #300
3PM= BZE 0 NNRV
3Q6W LDCT 0 256
3QLG STO 0 ENEWG(3)
3R66 NNRV
3RKQ LDX 0 A1(2)
3SK2 ANDX 0 BSP16
3W3W STO 0 EXCHNL(3) [AND CHANNEL NR IN GEXD
3WHG FREECORE 2 [FREE /GPERCON BLOCK
3X36 LDX 1 7
3XGQ TESTMOVE 6,MOVN
3Y2B MHUNTW 1,EWDAS,EXOF [RESET POINTER TO EXOF
3YG2 MOVN MHUNT 2,FILE,FABSNB
3Y^L LDX 0 HDREC(2)
3^F= SBN 0 10 [CHECK RECORD LENGTH=10,OTHERWISE
3^YW BNZ 0 NER [NAME IS OF WRONG SORT
42DG LDX 0 A1+4(2)
42Y6 BZE 0 NER [ERROR IF LOCAL NAME ZERO
43CQ LDX 0 ATYPE(2)
43XB ANDN 0 #5200 [FOR CORRECT NAME,B14=1,B12,16=0 IN
44C2 ERN 0 #1000 [ATYPE,
44WL BZE 0 NOK [J IF SO,
45B= NER FREECORE 1 [ELSE FREE BLOCKS
45TW FREECORE 3
46*G COMERR EWNAME [AND REPORT NAME ERRORS
46T6 NOK LDN 4 A1+4(2)
47#Q LDN 5 FIP(1)
47SB MOVE 4 3 [PUT FILENAME IN FIP IN EXOF
48#2 LDX 0 A1+8(2)
48RL BZE 0 NEG [J IF GEN WORD ZERO (NO GEN)
49?= BPZ 0 POZ [J IF GEN POSITIVE,
49QW NEG LDN 0 BHIGH [ELSE HIGHEST GEN REQUIRED,
4==G BRN RP [SET BHIGH
4=Q6 POZ SMO FX1
4?9Q TXU 0 X4096
4?PB BCS NANY [J UNLESS GEN=4096,
4#92 LDN 0 BANY [ELSE SET BANY
4#NL BRN RP
4*8= NANY SLL 0 12
4*MW STO 0 FIP+4(1) [PUT SPECIFIED GEN IN FIP
4B7G LDN 0 BSPEC [AND SET BSPEC
4BM6 RP ORS 0 EXMARK(1)
4C6Q LDX 0 ALOGLEN(2)
4CLB SBN 0 10
4D62 BZE 0 NRP [J IF NO RP OR SERIAL NUMBER
4DKL LDX 0 A1+10(2)
4F5= BNG 0 NRP [J IF NO RETENTION PERIOD
4FJW DSA 0 ENEWRP(3) [ELSE SAVE RP IN GEXD
4G4G BRN SER
4GJ6 NRP LDCT 0 #200
4H3Q STO 0 ENEWRP(3) [SET B1=1 TO INDICATE NO RP
4HHB SER LDX 0 ATYPE(2)
4J32 ANDN 0 #2000
4JGL BZE 0 NSER [J IF NO SERIAL NUMBER
4K2= LDX 0 A1+11(2)
4KFW SMO FX1
4K^G LDX 4 SIX7S [TEST CSN NOT GREATER
4LF6 TXL 4 0 [THAN 7 DIGITS AND
4LYQ BCC XOK [J IF OK
4MDB FREECORE 1 [FREE EXOF
4MY2 FREECORE 3 [FREE GEXD
4NCL COMERRX RMESS(1)
4NDR ...XOK STO 0 ASUSN(1) [PUT CSN IN EXOF
4NFY ...#
4NGN ... SEGENTRY AOLDA2SJMES
4NHD ... BRN NOMESS
4NJ= ...#
4NKC ...# SPECIAL CODE TO SEND OL MESSAGES FOR DISC EXOFILES TO SJ
4NLJ ...# - ONLY OBEYED IF RESTORE TIME MACRO "OLDA2SJMESS" IS USED
4NMP ...#
4NNW ... OUTBLOCN 10 [ GET A PARAMETER BLOCK
4NQ3 ...XLOC MHUNTW 3,EWDAS,EXOF
4NR8 ... OUTPACK FIP(3),3,LOCNAME,XLOC
4NS* ...XGEN MHUNTW 3,EWDAS,EXOF
4NTG ... OUTPACK FIP+4(3),1,GENNUM,XGEN
4NWM ...#
4NXS ...# FIP+4 : B0-11=GEN NO ; B12-23=VERSION. IF GEN NO NOT
4NY^ ...# SPECIFEID IN OL COMMAND FIP+4 IS PROBABLY RUBBISH
4P26 ...#
4P3? ...XSER MHUNTW 3,EWDAS,EXOF
4P4D ... OUTPACK ASUSN(3),1,OCTA,XSER
4P5K ...XCHN MHUNTW 3,EWDAS,GEXD
4P6Q ... OUTPACK EXCHNL(3),1,NUMA,XCHN
4P7X ... MONOUT BISJ [ PUT MESSAGE IN SJ
4P94 ... MHUNTW 1,EWDAS,EXOF
4P=9 ... MHUNT 2,FILE,FABSNB
4P?B ... MHUNTW 3,EWDAS,GEXD
4P#H ...NOMESS [ OLDA2SJMESS NULLS BRANCH TO HERE
4P*N ...#
4PBW LDN 0 BSERL
4PWG ORS 0 EXMARK(1) [AND SET BSERL
4QB6 NSER LDN 0 BOPEN
4QTQ ORS 0 EXMARK(1) [SET BOPEN
4R*B LDCT 0 #400
4RT2 ORS 0 GIVEX(3) [SET ONLINE MARKER
4S#L FREECORE 2 [FREE FABSNB
4SMJ ...# INPUT BLOCKS ARE NOW CORRECTLY SET UP FOR EXOPEN/WRITEFIP
4T2G ... BRN TFIN
4TRG #
4W?6 #
4WQQ #
4X=B #
4XQ2 #
4Y9L # UNANT
4YP= #
4^8W # THIS SECTION DEALS WITH UNANTICIPATED OPEN PERIS,OTHER
4^NG # THAN MODE #600.IT IS ENTERED FROM PERIXCOD (ON PCA,
5286 # PROGRAM UNPLUGGED) IF MODE OF UNANTICIPATED PERI IS
52MQ # *100-*400 OR *1200 (+*2000 &/ *4000).ON ENTRY,
537B # X4 CONTAINS CHANNEL NO IN B14-23
53M2 # X5 CONTAINS A COPY OF WORD 0 OF CONTROL AREA
546L # XCA(=EXEC/ANEVENT2) CONTAINS CONTROL AREA ADDRESS.
54L= # ROUTINE CHECKS CONTROL AREA,AND SETS UP EWDAS/GEXD AND
555W ...# EWDAS/EXOF BLOCKS FOR EXOPEN/WRITEFIP,THEN GOES TO OPEN
55KG # FILE,ETC.
5656 #
56JQ #
574B #DEF XCA=EVENT2
57J2 #
583L #
58H= UC #1200 [CREATE MODE
592W #
59GG #
5=FQ QK2SOUP
5=^B #SKI K6SOUP>199-199
5?F2 (
5?YL LDX 0 5 [CHECK X5
5#D= SRL 0 15
5#XW ANDN 0 #377
5*CG SBN 0 6
5*X6 BZE 0 XCH1
5BBQ ... SBN 0 20 [ERROR IF TYPE NOT 6 OR 26
5DSW BNZ 0 XCH4
5F#G XCH1 LDX 0 5
5FS6 ANDX 0 XCMASK(1) [TAKE OUT ADDITIVE MODES
5G?Q SBN 0 #1200
5GRB BZE 0 XCH2 [J IF MODE *1200,OK,
5H?2 ADN 0 #1200
5HQL LDN 6 4
5J== XCH3 SBN 0 #100
5JPW BZE 0 XCH2 [OR *100-*400,ELSE
5K9G BCT 6 XCH3
5KP6 XCH4 GEOERR 1,SD UNANT [ERROR,WRONG MODE
5L8Q XCMASK #71777
5LNB XCH2
5M82 )
5MML LDX 6 5
5N7= ANDN 6 #1777 [GET BASIC MODE
5NLW LDN 7 9
5P6G TXU 6 UC(1) [J UNLESS CREATE
5PL6 BCS NC [SET LENGTH OF CA TO 9(OPEN) OR 17(C)
5Q5Q LDN 7 17
5QKB NC CHECKEXT XCA(2),7,RVIOL,,W,WCOR,HLOCK1
5R52 WCOR SETNCORE GEXDLEN,3,EWDAS,GEXD [SET UP GEXD BLOCK,
5RJL STOZ A1(3)
5S4= LDN 0 A1(3)
5SHW LDN 1 A1+1(3)
5T3G MOVE 0 GEXDLEN-1 [ZEROISE IT
5TH6 LDN 0 1
5W2Q STO 0 GIVEX(3) [SET GIVE MARKER,AND PERI (B0=0)
5WGB STO 6 EOPMODE(3) [STORE OPEN MODE
62CB ANDN 4 #1777
62X2 STO 4 EXCHNL(3) [CHANNEL NO.
63W= LDX 0 XCA(2)
64*W STO 0 CNR(3) [CONTROL AREA ADDRESS
64TG PHOTO 6
65*6 SETNCORE FDCELLS-A1,1,EWDAS,EXOF [SET UP EXOF BLOCK
65SQ TESTMOVE 6,MVE
66#B MHUNTW 3,EWDAS,GEXD
66S2 MVE STOZ BACK1(1) [CLEAR BACK1,ETC
67?L STOZ BACK2(1)
67R= STOZ COPEN(1)
68=W LDN 4 EXMARK(1)
68QG LDX 6 3
69=6 LDX 3 XCA(2)
69PQ FOUTMOVE 2,3,4,7,HLOCK1
6=9B LDX 3 6
6=P2 #SKI K6SOUP>199-199
6?8L (
6?N= TXU 5 EXMARK(1)
6#7W BCS XCH4 [ERROR IF WORD 0 WRONG]
6#MG )
6*76 STOZ EXMARK(1) [CLEAR MARKER WORD:-NOW SERIAL NR IS
6*LQ LDX 0 5 [IN ASUSN,FILENAME,ETC IN FIP,ETC.
6B6B ANDN 0 #2000 [J IF ADD.MODE *2000 ABSENT (IN
6BL2 BZE 0 NAD [ WHICH CASE *4000 IS NULL)
6C5L LDN 0 BSERL
6CK= ORS 0 EXMARK(1) [SET 'UNIT SPECIFIED' MARKER
6D4W SMO FX1
6DJG LDX 0 SIX7S
6F46 ANDX 0 ASUSN(1) [MASK SERIAL NR TO 18 BITS
6FHQ BZE 0 XINV [ERROR IF ZERO
6G3B STO 0 ASUSN(1)
6GH2 ANDN 5 #4000
6H2L BZE 5 NAD [J IF ADD.MODE *4000 ABSENT,
6HG= LDN 0 BSUPP
6H^W ORS 0 EXMARK(1) [ELSE SET 'SUPPRESS LOAD' BIT
6JFG NAD LDCH 0 FIP(1)
6J^6 SBN 0 #41 [CHECK FILE SPEC
6KDQ BNG 0 XINV [ERROR IF FIRST
6KYB SBN 0 #32 [CHAR OF NAME
6LD2 BPZ 0 XINV [NOT ALPHABETIC
6LXL [CHECK REST OF FILENAME
6MC= STO 1 AWORK1(2) [SAVE X1
6MWW LDN 7 11 [COUNT OF CHARS TO BE CHECKED
6NBG BCHX 1 NCH [POINT TO 2ND CHARACTER
6NW6 NCH LDCH 0 FIP(1) [NEXT CHARACTER
6P*Q SBN 0 10
6PTB BNG 0 XOKFN [OK IF NUMERIC
6Q*2 SBN 0 #23
6QSL BZE 0 XOKFN [OK IF A -
6R#= ADN 0 #15
6RRW BZE 0 XOKFN [OK IF A SPACE
6S?G SBN 0 #21
6SR6 BNG 0 XINV2 [ERROR IF < A
6T=Q SBN 0 #32
6TQB BPZ 0 XINV2 [ERROR IF > Z
6W=2 XOKFN BCHX 1 £
6WPL BCT 7 NCH
6X9= LDX 1 AWORK1(2) [RESTORE X1
6XNW BRN XCONT
6Y8G XINV2 LDX 1 AWORK1(2)
6YN6 BRN XINV
6^7Q XCONT
6^MB LDX 0 EOPMODE(3)
7272 SBN 0 #1200
72LL BZE 0 XCR [J IF CREATE
736= LDN 0 BOPEN
73KW ORS 0 EXMARK(1) [SET OPEN MARKER
745G LDX 0 FIP+4(1)
74K6 BPZ 0 NNEG [J IF GENERATION NR POSITIVE
754Q LDN 0 BHIGH
75JB BRN NEWG [ELSE SET HIGHEST GEN MARKER
7642 NNEG SMO FX1
76HL TXU 0 X4096
773= BCS NFNS [J UNLESS GENERATION NR=4096
77GW LDN 0 BANY
782G BRN NEWG [SET ANY GENERATION MARKER
78G6 NFNS SLL 0 12 [PUT GENERATION NR IN B0-11
78^Q STO 0 FIP+4(1)
79FB LDN 0 BSPEC [SET SPECIFIED GENERATION BIT
79^2 NEWG ORS 0 EXMARK(1)
7=DL LDX 0 FIP+6(1)
7=Y= STO 0 ENEWG(3) [SAVE NEW GENERATION NR
7?CW LDCT 0 #400
7?XG STO 0 ENEWRP(3) [AND
7#C6 LDX 0 FIP+5(1)
7#WQ ANDS 0 ENEWRP(3) [B0 AND B12-23 OF NEW RP
7*BB DSA 0 ENEWRP(3)
7*W2 BRN OFF [GO TO CPA AND OPEN
7B5S ...#
7B*L ...# CREATE MODE
7BKD ...#
7BT= XCR LDN 0 BCREATE+BSPEC
7C#W ORS 0 EXMARK(1) [SET CREATE AND SPECIFIED GEN BITS
7CSG LDCT 0 #600
7D#6 ANDX 0 FIP+5(1)
7DRQ BZE 0 XINV [OR INTEGRITY CODE=ZERO
7F?B STO 0 FIP+5(1) [SYFIL BIT/NR OF AREAS = 0
7FR2 LDX 0 FIP+8(1)
7G=L ANDN 0 #77 [CHECK BUCKET SIZE
7GQ= LDN 2 4
7H9W SNX LDN 4 16
7HPG SRL 4 0(2)
7J96 SBX 4 0
7JNQ BZE 4 SOK [J IF 1,2,4 OR 8
7K8B BCT 2 SNX
7KN2 BRN XINV [ELSE ERROR
7L7L SOK LDN 2 5
7LM= ZNX SMO 2 [CHECK THAT LAST 5 WORDS ARE ZERO
7M6W LDX 0 FIP+9(1)
7MLG BNZ 0 XINV [ERROR IF NOT
7N66 BCT 2 ZNX
7NKQ LDX 0 EDATE
7P5B STO 0 FIP+6(1) [INSERT DATE,
7PK2 LDN 0 1
7Q4L STO 0 FIP+10(1) [AND EOF=1
7QJ= [
7R3W OFF CAPCA EWDAS,GEXD,EWDAS,EXOF [GO TO CPA,TAKING DATA BLOCKS,
7R4X ...TFIN
7R5= ... MHUNTW 1,EWDAS,GEXD
7R5K ... LDCT 5 6 [*DA
7R5Y ... ADX 5 EXCHNL(1) [TYPE/UNIT NO
7R6? ... LDX 7 GIVEX(1) [X7 -VE IF COMMAND
7R6L ... HLSXONCH XBRK,5,XER1 [SEE IF OK WITH HLS TO CARRY ON
7R6P ... MHUNTW 1,EWDAS,EXOF
7R6S ... LDX 0 EXMARK(1)
7R6X ... ANDN 0 BCREATE
7R72 ... BNZ 0 WFIP
7R75 ... ACROSS EXOPEN,2
7R78 ...WFIP ACROSS WRITEFIP,2
7R7# ...[
7R7M ...[ HLS REJECTS OPEN
7R82 ...[
7R8* ...XBRK
7R8N ... NGNC 6 1
7R93 ...XER1
7R9B ... LDN 6 0 [X6=0 IF REJECT ;X6=1 IF BREAKIN
7R9P ... MFREEW EWDAS,EXOF
7R=4 ... MFREEW EWDAS,GEXD
7R=C ... BZE 6 XER2 [J IF REJECT
7R=Q ... BNG 7 VCOM [J IF COMMAND
7R?5 ... STEPBACK [PUT ONR BACK ONE
7R?D ... PROGBRKIN
7R?R ...VCOM
7R#6 ... COMBRKIN
7R#F ...[
7R#S ...[ REJECTION BY HLS
7R*7 ...[
7R*G ...XER2
7R*T ... BNG 7 VCOM1 [JIF COMMAND
7RB8 ... STEPBACK
7RBH ... MONOUT EWHLSRJ [OUTPUT HLS MESSAGE
7RBW ...XPAR
7RC9 ... OUTPACK 5,1,PERINAME,XPAR [*DA FAIL
7RCJ ... ILLEGAL PERFAIL
7RCX ...VCOM1
7RD= ... COMERR ERHLSONL
7RDK ...[
7RDY ...[
7S36 [
7SGQ RVIOL ILLEGAL NOCA [RESERVATION VIOLATION
7T2B [
7TG2 XINV FREECORE 1 [INVALID CONTROL AREA,
7T^L FREECORE 3 [FREE DATA BLOCKS AND
7WF= ILLEGAL INVAL [ILLEGAL
7WYW #
7XDG #
7XY6 #
7YCQ MENDAREA 30,K99SOUP
7YXB #END
^^^^ ...02572777000100000000