{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: SUICIDE864)}}
====== SUICIDE864 ======
(George Source)

**Macros used:** [[george:macro:BACKWAIT|BACKWAIT]], [[george:macro:BXGE|BXGE]], [[george:macro:CHANGEACT|CHANGEACT]], [[george:macro:COOR1X|COOR1X]], [[george:macro:DOWN|DOWN]], [[george:macro:FILECOUNT|FILECOUNT]], [[george:macro:FINDACTNO|FINDACTNO]], [[george:macro:FREECORD|FREECORD]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHCODE|FSHCODE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GSCAN|GSCAN]], [[george:macro:JBC|JBC]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:PHOTO|PHOTO]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SUICIDE|SUICIDE]], [[george:macro:TESTMOVE|TESTMOVE]], [[george:macro:TRACE|TRACE]], [[george:macro:UP|UP]]

<code - SUICIDE864.txt>22FL    #OPT  K0SUICIDE=0   
22^=    #OPT  K6SUICIDE=K6ALLGEO
23DW    #LIS  K0SUICIDE>K0ALLGEO>K0GREATGEO 
23YG    #SEG  SUICIDE                      [ROGER TERRY 
24D6                   8HSUICIDE
24XQ    [   
25CB    [     THIS  ROUTINE IS ENTERED INORDER TO TAKE  AN  ACTIVITY OFF THE
25X2    [     ACTIVITY CHAIN.  IT GIVES BACK TO FREE CORE ALL THE BLOCKS WHICH  
26BL    [     ARE ATTACHED TO THE ACTIVITY.  IF AN ACTIVITY WISHES TO DECHAIN   
26W=    [     ITSELF,ENTRY IS VIA THE SUICIDE MACRO . OTHERWISE THIS ROUTINE IS 
27*W    [     ENTERED VIA THE MURDER MACRO. 
27TG    [   
28*6    [     ENTRY POINTS  
28SQ    [   
29#B          SEGENTRY K1SUICIDE,ZEP1      [ENTRY POINT FOR SUICIDE 
29S2          SEGENTRY K2SUICIDE           [ENTRY POINT FOR MURDER  
2=?L          LDN   7  1                   [SWITCH FOR MURDER OR SUICIDE
2=R=          LDX   3  EXEC1(2)            [GET ADDRESS OF ACT BLK  
2?=W    #SKI K6SUICIDE>12-12
2?QG          GSCAN    ACTNUM(3),MURDER 
2#4X ...      PHOTO    6
2#C# ...      LDX   5  ACTNUM(2)           [SAVE ACT NO TO REFIND BLOCK IF REQD 
2#PQ          STO   2  4
2*9B          CHANGEACT 3                  [CHANGE TO VICTIM TO WAIT FOR END
2*P2          BRN      SUI                 [FAKE*A SUICIDE  
2B8L    ZEP1                               [SUICIDE 
2BN=    #SKI K6SUICIDE>12-12
2C7W          GSCAN    ATYPE(2),SUICIDE 
2CMG          LDN   7  0
2D76    SUI 
2D9* ...      FSHCODE  AORB 
2D?J ...(   
2D*R ...      JBC      NOTRUNNING,,FSHRUNNING   
2DD2 ...      DOWN     FSHTRANC,4          [DELETE ANY FSHMARKER TABLE ENTRY
2DG9 ...NOTRUNNING  
2DJD ...)   
2DLQ          BACKWAIT  
2F6B    #SKI  K6SUICIDE>12-12   
2FL2    (   
2G5L          FILECOUNT  0  
2GK=          BZE   0  NFLOPN   
2H4W          GEOERR   1,FILEOPEN   
2HJG    NFLOPN  
2J46    )   
2JHQ    SUI1
2K3B          LDX   1  FPTR(2)             [ADDRESS OF NEXT BLOCK   
2KH2          LDX   0  ATYPE(1) 
2L2L          BXGE  0  CACT,SUI2           [J IF ACT BLK. I.E. END OF CHAIN 
2LG=    #SKI  K6SUICIDE>699-699 
2L^W          TRACE    0,SUIFREE
2MFG          FREECORD 1                   [FREE IT 
2M^6          BRN      SUI1 
2NDQ    SUI2
2NYB          BNZ   7  SUI3                [J IF NOT SUICIDE
2PD2          FREECORE 2                   [FREE ACTIVITY BLOCK 
2PXL          COOR1X
2QC=    SUI3
2QWW          LDX   3  2                   [STO POINTER TO VICTIM   
2R22 ...      TESTMOVE 6,NOCOORD           [J IF NO COORDINATIONS   
2R56 ...      FINDACTNO 2,5,NOACT   
2R8= ...      STO   2  4
2R?B ...NOCOORD 
2RBG          CHANGEACT 4   
2S*Q          FREECORE 3                   [FREE THE VICTIM 
2STB          UP
2T2J ...NOACT   
2T7Q ...      GEOERR   1,ACTLOST
2T*2          MENDAREA 20   
2TSL    #END
^^^^ ...22577327000100000000
</code>