{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: SWAP865)}}
====== SWAP865 ======
(George Source)
**Macros used:** [[george:macro:BACKTRAN|BACKTRAN]], [[george:macro:BACKWAIT|BACKWAIT]], [[george:macro:BC|BC]], [[george:macro:BITMASK|BITMASK]], [[george:macro:BS|BS]], [[george:macro:BSOFF|BSOFF]], [[george:macro:BXE|BXE]], [[george:macro:CHAIN|CHAIN]], [[george:macro:COBJUSE|COBJUSE]], [[george:macro:COMPROLINK|COMPROLINK]], [[george:macro:COOR1|COOR1]], [[george:macro:COOR1X|COOR1X]], [[george:macro:ENDPAXES|ENDPAXES]], [[george:macro:FCAJO|FCAJO]], [[george:macro:FINDPUC|FINDPUC]], [[george:macro:FINDTP|FINDTP]], [[george:macro:FJOCA|FJOCA]], [[george:macro:FJOPCA|FJOPCA]], [[george:macro:FPCACA|FPCACA]], [[george:macro:FPCAJO|FPCAJO]], [[george:macro:FPUT|FPUT]], [[george:macro:FREEBUFF|FREEBUFF]], [[george:macro:FREEPROG|FREEPROG]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GETBACK|GETBACK]], [[george:macro:GSCAN|GSCAN]], [[george:macro:HUNT2|HUNT2]], [[george:macro:HUNTACTF|HUNTACTF]], [[george:macro:JBC|JBC]], [[george:macro:JBS|JBS]], [[george:macro:JBSC|JBSC]], [[george:macro:JMBAC|JMBAC]], [[george:macro:JMBS|JMBS]], [[george:macro:JOBLOCK|JOBLOCK]], [[george:macro:LINKSET|LINKSET]], [[george:macro:LOCKC|LOCKC]], [[george:macro:MBI|MBI]], [[george:macro:MBS|MBS]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:OFF|OFF]], [[george:macro:ON|ON]], [[george:macro:PAIR|PAIR]], [[george:macro:PCATEST|PCATEST]], [[george:macro:PROGAXES|PROGAXES]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SWAP|SWAP]], [[george:macro:SWAPTRAN|SWAPTRAN]], [[george:macro:SWAPWAIT|SWAPWAIT]], [[george:macro:TESTPUC|TESTPUC]], [[george:macro:TESTRCTP|TESTRCTP]], [[george:macro:TESTRT|TESTRT]], [[george:macro:TESTTP|TESTTP]], [[george:macro:TRACE|TRACE]], [[george:macro:UNLOCK|UNLOCK]], [[george:macro:UP|UP]]
22FL #LIS K0SWAP>K0ALLGEO>K0GREATGEO>K0EMS
22^= #SEG SWAP [RUTH PORTER
23DW 8HSWAP
23YG #
24D6 #
24XQ # VERSION FOR G3 MK8
25CB #
25X2 #
26BL #
26W= # THIS SEGMENT SWAPS OBJECT PROGRAMS IN AND OUT OF CORE
27*W #
27TG # ENTRY 1 PERFORMS A SWAP IN FOR THE PROCESS CONTROLLER
28*6 ...# ENTRY 2 PERFORMS A SWAP OUT FOR THE PROCESS CONTROLLER
28SQ # ENTRY 3 PERFORMS A SWAP OUT FOR A ROUTINE IN A COMMAND ACTIVITY
28^2 ...# ENTRY 4 PERFORMS A SWAP OUT FOR THE CORE UNJAMMER
295= ...# WHEN THE PROGRAM WAS PLUGGED IN OR STOPPED
299G ...# ENTRY 5 FROM TRUEDORM MACRO TO SWAP OUT A TRULY DORMANT PROGRAM
29*Q ...# ENTRY 7 FROM STRATEGY SEGMENT TO 'SWAP' A PROGRAM INTO ITS VALID
29G2 ...# FREE PROGRAM BLOCK IN CORE
29L= ...[
29QG ...[ DURING SEGMENT,X7 USED AS INDICATOR FOR TYPE OF SWAP
29WQ ...[ X7 = 0 FOR VALID FREE PROGRAM BLOCK
2=32 ...[ X7 = 1 FOR SWAP IN
2=7= ...[ X7 =-1 FOR SWAP OUT
2=?L #
2=R= # BECAUSE OF THE EXTRACOR MECHANISM THERE MAY BE AMBIGUITY BETWEEN ALOGL
2?=W # OF AOBJPROG AND ACORSZ OF SCB.THE SCB IS ALWAYS THE DEFINITIVE VERSION
2?QG # OF THE PROGRAM STATE
2#=6 SEGENTRY K1SWAP,XX1S
2#PQ SEGENTRY K2SWAP,XX2S
2*9B SEGENTRY K3SWAP,XX3S
2*P2 SEGENTRY K4SWAP,XX4S
2*W8 ... SEGENTRY K5SWAP,XX5S
2B3B ... SEGENTRY K7SWAP,XX7S
2B8L # CONSTANTS
2BN= #
2C7W ZBITS16MS #77777400
2CMG ZBIT9 #40000
2D76 ZBIT11 #10000
2DLQ ZBITS1012 #24000
2F6B ZBITS1112 #14000
2FL2 ZLINKPAIR PAIR SWAP,2
2FPX ...P12 COMPROLINK ['PROGBRKIN' TYPE LINK
2FTS ...SCHEDLINK
2F^P ... PAIR SCHEDIN,1
2G5L #
2GK= #
2H4W # LOCAL DEFINITIONS
2HJG #OPT ASHEETSIZE=BSSS
2J46 #DEF ZAC3=ACOMMUNE3
2JHQ #DEF ZAC4=ACOMMUNE4
2K3B #DEF ZAC5=ACOMMUNE5
2KH2 #DEF ZACOMMNUM=9
2L2L #DEF ZCLONGNUM=1
2LG= #
2L^W #
2MFG #
2M^6 # TABLE OF BLOCK TYPES TO CHECK AT SWAP-OUT TIME
2NDQ #
2NYB ZTAB
2PD2 #
2PXL # LIST OF NON CHAIN TERMINATING ACTIVITY BLOCK TYPES
2QC= #
2QWW #HAL AOLPT,Z2
2RBG #
2RW6 # LIST OF DATA BLOCK TYPES WHICH REQUIRE SPECIAL ACTION
2S*Q #
2STB #HAL BSTB+BQBLK,Z3
2T*2 #HAL 0,Z100 [DUMMY ENTRY
2TSL #DEF ZTOT=0?-ZTAB-1 [NUMBER OF ENTRIES LESS DUMMY
2W#= #
2WRW #
2X?G #
2XR6 #
2Y=Q #
2Y?B ...[
2Y#2 ...[ SUBROUTINE TO CLEAR BIGBIT MARKERS
2Y#L ...[
2Y*= ...#
2Y*W ...TCLEAR
2YBG ...#UNS ECS
2YC6 ...(
2YCQ ... LDX 0 BIGPROGCP
2YDB ... BZE 0 (6) [EXIT IF NO BIG PROG'S
2YF2 ... STOZ BIGPROGCP
2YFL ...)
2YG= ...#UNS ECS
2YGW ...#SKI
2YHG ...(
2YJ6 ... BSOFF BIGBIT,(6)
2YJQ ... OFF BIGBIT
2YKB ...)
2YL2 ... LDN 3 BJOBQ
2YLL ...NN LDX 3 FPTR(3)
2YM= ... BXE 3 CXJO,(6)
2YMW ... BC 3,JBBIG [REMOVE ANY BIG PROG MARKERS
2YNG ... BRN NN
2YP6 ...[
2YQB # ROUTINES TO DEAL WITH BLOCK TYPES CHECKED AGAINST ENTRIES IN ZTAB
2^=2 #
2^PL Z2 BRN N201 [J TO CONTINUE
329= Z3
32NW #SKI K6SWAP>199-199
338G TRACE 3,SWAPWAIT
33N6 SWAPWAIT N201 [AUTO TFR IN PROGRESS
347Q BRN N400 [TFR WAS OUT OF O/P-RESTART
34MB Z100 LDX 4 ATYPE(3) [DUMMY BLOCK TYPE
3572 TXL 4 CACT
35LL BCS N201 [J TO CONTINUE IF DATA BLOCK
366= BRN N205 [CHAIN TERMINATING ACTIVITY
36KW #
375G #
37K6 # PCA ROUTINES
384Q #
38JB PCAFINDC
3942 STO 1 GEN0
39HL LDX 2 FX2
3=3= JOBLOCK JOBNO(2),2
3=77 ... BPZ 2 PCAOK
3=?4 ... GEOERR 0,NOJOBBLK
3=B^ ...PCAOK
3=GW
3?2G JMBAC PFC,2,JBPISO,JBSTSO [J IF NOT SPECIAL SWAPOUT
3?G6 LDN 6 1 [ SET SPEC OUT MARKER.
3?^Q PFC
3#FB FPCAJO 2
3#^2 BRN (GEN0)
3*DL PCAFINDT
3*Y= SMO FX2
3BCW LDX 2 ZAC3
3BXG FINDTP 2,2
3CC6 EXIT 1 0
3CWQ PCAFINDP
3DBB SMO FX2
3DW2 LDX 2 ZAC3
3F*L FINDPUC 2,2
3FT= EXIT 1 0
3G#W PCAMSK BITMASK 0,1,18,19,20,21,22,23
3GSG PCACHADP [SET UP EXEC WORDS IN PUC PCA
3H#6 LDX 0 ADATUM(2) [ADATUM HAS BEEN RELATIVISED
3HRQ BRN PCAC1
3J?B PCACHADT [SET UP EXEC WORDS IN TP/NORMAL PCA
3JR2 LDN 0 0
3K=L PCAC1 SMO FX2
3KQ= ADX 0 ZAC4
3KTB ...#UNS CA1D
3KYG ... ADX 0 CA1D
3L3L ...#UNS CA1D
3L6Q ...#SKI
3L9W ADN 0 A1D
3LPG STO 0 ADATUM(2)
3M96 ADX 0 GEODATUM
3MNQ STO 0 ADTM(2)
3N8B LDX 0 ALMT(2)
3NN2 SMO FX1
3P7L ANDX 0 PCAMSK
3PM= ORX 0 ADTM(2)
3Q6W ADX 0 ALIMIT(2)
3QLG STO 0 ALMT(2)
3R66 LDN 0 CHAINADD(2)
3RKQ STO 0 AECA(2)
3S5B LDN 0 ASTOP(2)
3SK2 STO 0 APD1(2)
3T4L STO 0 APD2(2)
3TJ= STO 0 APD3(2)
3W3W STO 0 APD4(2)
3WHG EXIT 1 0
3X36 #
3XGQ XX1S
3Y2B # ENTRY IN THE ASWINT.ACC6 CONTAINS JOB NO.
3Y7J ... LDN 7 1 [READ MODE INDICATOR
3Y#Q ...#UNS ADPLLSKIP
3YFY ...(
3YM6 ... LDN 0 1 [- DATAPASS COUNT OF
3YS# ... SMO ADPSWPPTR [- SWAPINS
3Y^G ... ADS 0 3
3^6N ...)
3^?W ...XFPB MHUNTW 3,AOBJPROG
3^F= STO 3 ZAC4(2)
3^P4 ... BZE 7 XFPB1 [J IF VALID FPB ENTRY
3^YW MHUNTW 3,ADATA,ASTRAT
42DG LDX 6 GPROG(3)
42Y6 ...XFPB1 STO 6 ACOMMUNE6(2)
43CQ STO 6 JOBNO(2)
43XB BRN N1
43Y5 ...[
43YS ...[ ENTRY FROM STRATEGY SEGMENT TO 'SWAP' A PROGRAM INTO ITS VALID
43^H ...[ FREE PROGRAM BLOCK(I.E. JUST LOCK PCA ETC.,AS NO SWAP FILE TRANSFE
442= ...[ NECESSARY).THE EXIT WILL BE BACK TO CORESHED AND WILL TAKE THE
442^ ...[ OK EXIT FROM THE STRATEGY MACRO WITH NO ADATA/ASTRAT BLOCK PRESENT
443N ...[ IMPLYING CORESHED CAN TAKE ITS NORMAL SUCCESSFUL END OF SWAP IN
444C ...[ ROUTINE.
4456 ...[
445T ...XX7S
446J ...#UNS ADPLLSKIP
447? ...(
4482 ... LDN 0 1 [- DATAPASS COUNT OF
448P ... SMO ADPSWPPTR [- RE-USED FPB'S
449D ... ADS 0 4
44=7 ...)
44=W ... LDN 7 0 [VALID FPB INDICATOR
44?K ... LDX 6 ACOMMUNE4(2) [LOAD JOB NUMBER
44## ... BRN XFPB
44*3 ...[
44*Q ...[
44C2 XX4S
44WL N400 FJOPCA 3,2
45B= TESTRCTP 3,N401
45TW BRN N200
46*G N401
46T6 TESTTP ,N200 [J IF APET/ATP
47#Q FINDTP ,3
47SB BRN N201
48#2 N200 LDX 3 FX2 [START AT PCA
48RL N201 LDX 3 FPTR(3) [NEXT BLOCK
49?= LDN 5 ZTOT [COUNT OF BLOCK TYPES
49QW N203 LDX 4 ATYPE(3)
4==G ERX 4 ZTAB(1)
4=Q6 ANDX 4 HALFTOP
4?9Q BZE 4 N202 [J IF MATCH
4?PB ADN 1 1
4#92 BCT 5 N203 [DROP THROUGH IF DUMMY MATCH
4#NL N202 LDX 4 ZTAB(1)
4*8= ANDN 4 #7777
4*MW ADX 4 FX1 [SET UP BRANCHING POINT
4B7G LDX 1 FX1
4BM6 #SKI K6SWAP>199-199
4C6Q TRACE ATYPE(3),SWAPCHEK
4CLB EXIT 4 0 [J TO TAKE APPROPRIATE ACTION
4D62 XX2S
4D89 ...#UNS ADPLLSKIP
4D=D ...(
4D#M ... LDX 1 ADPSWPSW [- DATAPASS COUNTS
4DBW ... LDN 0 1 [- DECIDE IF THIS SWAPOUT
4DF5 ... SMO ADPSWPPTR [- DUE TO LLS
4DH# ... ADS 0 0(1) [- OR UNJAMMER
4DKH ...)
4DMQ ...N205 NGN 7 1 [WRITE MODE
4DP^ ...#UNS FREEBUFF
4DS8 ...(
4DWC ... FREEBUFF AOLPT,APET [ FREE FURBS & FUWBS OF AOLPTS
4DYL ...)
4F2T ...#
4F5= #
4FJW # THIS PIECE OF GARBAGE LOCKS PCA'S ETC.
4G4G #
4GJ6 N1
4H3Q LDN 6 0
4HHB CALL 1 PCAFINDC [ FIND CURRENT.
4J32 PCATEST 2, , ,XPUC
4JGL [
4K2= [ NORMAL/TP.
4KFW [
4K^G BNZ 6 X0 [ J IF SPECOUT
4LF6 LOCKC 2,PCAFINDC
4LYQ CALL 1 PCAFINDC [ LOCK AND REFIND.
4MDB X0
4MY2 SMO FX2
4NCL STO 2 ZAC3 [ DUMP PTR.
4NX= ... BNG 7 START [ J IF S/O
4PBW CALL 1 PCACHADT
4PWG TESTTP 2,X1
4QB6 BRN START [ J IF NORMAL.
4QTQ X1
4R*B CALL 1 PCAFINDP
4RT2 BNZ 6 X2
4S#L LOCKC 2,PCAFINDP
4SS= CALL 1 PCAFINDP
4T?W X2 CALL 1 PCACHADP
4TRG BRN START
4W?6 [
4WQQ [ PUC
4X=B [
4XQ2 ...XPUC BNG 7 XP1 [ J IF SWAPOUT.
4Y9L BNZ 6 XP0 [ J IF SPECOUT.
4YP= LOCKC 2,PCAFINDC
4^8W CALL 1 PCAFINDC
4^NG XP0 CALL 1 PCACHADP
5286 XP1
52MQ SMO FX2
537B STO 2 ZAC3
53M2 CALL 1 PCAFINDT
546L BNZ 6 XP2
54L= LOCKC 2,PCAFINDT
555W CALL 1 PCAFINDT
55KG ...XP2 BNG 7 XP3
5656 CALL 1 PCACHADT
56JQ XP3
574B SMO FX2
57J2 STO 2 ZAC3
583L START LDX 1 FX1
58H= LDX 2 FX2
592W # ADDR OF APET OR APET/ATP IN ACOMMUNE3 OF ACTIVITY CONTROLLING SWAP
59GG HUNT2 3,BSTB,BSCB,ZAC3(2)
5=26 ... BNG 7 N27 [J IF SWAP OUT
5=FQ CHAIN ZAC4(2),3 [ ELSE CHAIN PROGRAM BLOCK AFTER SCB
5=PJ ... BZE 7 N10 [J IF VALID FPB AS NO SWAP REQ'D
5=^B ... STOZ AQMODE(3) [READ MODE 0
5?98 ... BRN N27A
5?F2 ...N27 NGS 7 AQMODE(3) [MODE WORD 1
5?NS ...N27A LDX 4 ASHEET(3)
5?YL BZE 4 N26 [J IF S/I FOR LOAD
5#D= SBN 4 1 [COUNT OF TFRS TO BE ATTEMPTED
5#XW LDX 5 ASHEETSIZE [ AUTONOMOUSLY
5*CG STO 5 AWORK2(2) [LENGTH OF AUTO TFR
5*X6 LDX 5 AOBJLF(3) [NO OF LOG. FILE CONTAINING PROGRAM
5BBQ STO 5 AWORK3(2)
5BWB N2 LDN 5 0 [SCB PTR
5CB2 LDN 6 0 [O/P PTR
5CTL BZE 4 N15 [J IF ONLY 1 TFR
5D*= N6 HUNT2 3,BSTB,BSCB,ZAC3(2)
5DSW SMO 5
5F#G LDX 1 AOBJST(3) [SHEET HOME
5FS6 STO 1 AWORK4(2)
5G?Q # AN ATTEMPT IS MADE TO QUEUE AN AUTONOMOUS TFR
5GRB ...N20 SWAPTRAN AQMODE(3),AWORK2(2),AWORK3(2),,EX6,ZAC3(2),N21
5H?2 N7 SBN 4 1 [STEP COUNT OF TFRS
5HQL ADN 5 1 [STEP SCB PTR
5J== ADX 6 ASHEETSIZE [STEP O/P PTR
5JPW BZE 4 N4 [J IF LAST TFR
5K9G BPZ 4 N6 [J IF MORE TFRS TO QUEUE
5KP6 BACKWAIT N8 [WAIT FOR ALL AUTO TFRS TO FINISH
5L8Q HUNT2 3,BSTB,BSCB,ZAC3(2)
5LNB ... BPZ 7 N10 [J IF SWAP-IN
5M82 LDX 0 CLEANCT [ SPRING CLEAN COUNT.
5MML STO 0 ASTIME(3) [TIME AT SWAP-OUT
5N7= HUNTACTF AOBJPROG,3
5NLW TESTTP ,N40
5P6G TESTPUC ,N41
5PL6 BRN N42 [J IF APET/0
5Q5Q N40 FINDPUC ,2
5Q7N ...#UNS CA1D
5Q9L ...(
5Q?J ...N41 LDX 0 3
5Q*G ... ADX 0 CA1D
5QCD ...)
5QFB ...#UNS CA1D
5QH# ...#SKI
5QKB N41 LDN 0 A1D(3)
5R52 SBS 0 ADATUM(2) [RELATIVISE PUC DATUM
5RJL LDX 2 FX2
5S4= N42
5SHW ... LDX 1 3 [SET X1 = AOBJPROG
5T3G ... FJOPCA 3,2 [FIND JOB BLOCK
5TH6 ... FREEPROG 1,3 [SET AOBJPROG AS FPB
5XFL JMBS N18,3,JBPISO,JBSTSO [J IF SPECIAL
5X^= UNLOCK ZAC3(2) [UNLOCK APET OR APET/ATP
5YDW TESTRCTP 3,N17A [J IF RCTP
5YYG BRN N17
5^D6 N17A
5^XQ FINDPUC ZAC3(2),3
62CB UNLOCK 3 [UNLOCK APET/APUC
62G7 ...#
62JY ...# SWAP OUT FINISHED
62MP ...#
62QG ...N17
62T? ... GSCAN JOBNO(2),SWAPOUTF
62Y4 ... OFF CSWAPAB [CLEAR THE 'ABORT FOR SWAPOUT' MARKER
632T ... CALL 6 TCLEAR
635L ... FJOPCA 3,2
638C ... ENDPAXES 3
63?8 ... JBSC SOMAC,3,JBSOMAC [J UNLESS S/O MACRO & CLEAR OTHERWISE
63*^ ... OFF BSTRAT [CLEAR 'STRATEGY IN PROGRESS' MARKER
63DQ ... BC ,ASWOUTING [MARK NO SWAPOUT GOING ON
63HH ...SOMAC
63L# ... BC 3,JBBEING
63P5 ... BS 3,JBSO [MARK S/O
63RW ... FCAJO 2,3
63WM ... JBSC WAITCPA,3,JBCPASO
63^D ... JMBS R5,3,JBDORM,JBPCACA [J IF DORMANT OR WAITING IN PCACA
6449 ... BC 3,JBSTOP
6472 ... BS 3,JBSUSP [ENSURE MARED SUSPENDED
649R ... JBC R5,3,JBBIN [J IF NO BREAK IN
64#J ... MBI 3,JBSUSP,JBDORM [SUSPENDED TO DORMANT
64C* ... LINKSET 2,P12(1) [FORCE PROGBRKIN EXIT
64G6 ...WAITCPA
64JX ... FPUT
64MN ...R5 KICKASWI SCHEDLINK(1)
64QF ...RCOOR COOR1X
653R ...N18
65*6 #SKI K6COREJAM>499-499
65SQ TRACE JOBNO(2),SPECOUTF
66#B LDN 4 1
66S2 ERS 4 INOUTPC [INDICATR SWAPOUT FINISHED
67?L LDX 4 ZBITS1112(1)
67R= ERS 4 JMISC(3) [INDICATE SWAPPED OUT
68=W ENDPAXES 3 [CLEAR 'BEING ACCESSED' MARKER
68QG LDN 4 CJACCLINK
69=6 LDN 5 ACC3(2) [RESTORE ORIGINAL INFORMATION
69PQ MOVE 4 ALINK [TO PROGRAM CONTROL ACTIVITY
6=9B ADN 4 ALINK
6=P2 LDN 5 ACOMMUNE1(2)
6?8L MOVE 4 ZACOMMNUM
6?N= ADN 4 ZACOMMNUM
6#7W LDN 5 CLONG1(2)
6#MG MOVE 4 ZCLONGNUM
6*76 COOR1X [REMOVE FROM LIST
6*LQ N10 LDX 0 CLEANCT [ CURRENT TIME
6B6B SBX 0 ASTIME(3)
6BL2 ADS 0 ATOTIME(3) [TIME SPENT ON BACKING STORE
6BTS ... BZE 7 N26A [J AS COBJUSE ALREADY UPDATED FOR FPB
6C5L N26
6CK= HUNTACTF AOBJPROG,3
6D4W LDX 6 ALOGLEN(3) [CORE SIZE OF PROG
6DJG ADS 6 COBJUSE
6F46 ...N26A UP
6FHQ #
6G3B # IN THE CASE OF BSTS REPORTING AN O/P RESERVATION, SWAP WILL
6GH2 # HAVE LOST ITS PLACE. HENCE:-
6H2L N9 GEOERR 1,SWAPVIOL
6HG= #
6H^W # THIS SECTION DEALS WITH BACKING STORE READ FAILURES
6JFG N11 GEOERR 1,READFAIL
6J^6 #
6KDQ # THIS SECTION IS ENTERED IF THERE ARE NO SHEETS AVAILABLE FROM
6KYB # EITHER THE MAIN OR RESERVE LISTS.
6LD2 N12 GEOERR 1,NO SHEET
6LXL #
6MC= # AN ATTEMPT IS MADE TO PERFORM A NON-AUTONOMOUS TFR
6MWW N21
6NBG N22
6NNX ...N5 BACKTRAN AQMODE(3),BOBJ+BSET+ASWAP,AWORK2(2),N13,AWORK3(2),,EX6,Z-
6P3# ...AC3(2)
6P*Q BRN N7
6PTB #
6Q*2 # THIS SECTION IS ENTERED WHEN A FAILURE ON AN AUTONOMOUS TFR
6QSL # IS DETECTED
6R#= ...N8 BPZ 7 N11 [J IF READ FAILURE
6RRW LDX 1 BA4(2) [O/P ADDR
6S?G LDX 6 1
6SR6 DVS 0 ASHEETSIZE
6T=Q LDX 5 1 [PROGRAM NO. OF FAILED SHEET
6TQB LDX 1 FX1
6W=2 LDX 0 BA3(2) [UNDATUMIZED ADDR OF SHEET TO FLAW
6WPL STO 0 AWORK4(2)
6X9= LDX 0 BA2(2)
6XNW ANDX 0 ZBITS16MS(1) [TFR LENGTH
6Y8G SRL 0 8
6YN6 STO 0 AWORK2(2)
6^7Q BRN N14
6^MB #
7272 # THIS SECTION IS ENTERED WHEN A FAILURE ON A
72LL # NON-AUTONOMOUS TFR IS DETECTED
736= N13 BRN N14
73KW #
745G # AT THIS POINT THE PATHS FOR DEALING WITH THE TWO SORTS OF FAILED
74K6 # TFRS MERGE. X5 CONTAINS RELATIVE POINTER TO SHEET HOME TABLE IN
754Q # SCB. X6 CONTAINS ADDR OF START OF TFR RELATIVE TO O/P DATUM
75JB N14
7642 # NEXT LINE NOT REQUIRED FOR MK4
76HL # BADSHEET AWORK4(2) [FLAW THE SHEET
773= ... BPZ 7 N11 [J IF FAIL WAS ON A READ TFR
77GW # THIS SECTION CONTINUES TO DEAL WITH WRITE FAILS BY FIRST
782G # ATTEMPTING TO OBTAIN A SHEET NORMALLY.IF THIS IS UNSUCCESSFUL
78G6 # THE BACKING STORE ALLOCATOR WILL TRY TO OBTAIN A SHEET FROM
78^Q # THE RESERVE
79FB GETBACK AWORK3(2),PRIV
79^2 HUNT2 3,BSTB,BSCB,ZAC3(2)
7=DL LDX 0 EXEC1(2) [SHEETHOME
7=Y= STO 0 AWORK4(2)
7?CW SMO 5
7?XG STO 0 AOBJST(3) [UPDATE SCB TABLE
7#C6 BRN N21 [REPEAT TFR NON AUTONOMOUSLY
7#WQ #
7*BB # THIS SECTION IS ENTERED IF THE O/P IS SMALLER THAN 1 SHEET
7*W2 N15 HUNT2 3,BSTB,BSCB,ZAC3(2)
7B*L LDX 0 AOBJST(3) [UNDATUMISED SHEET ADDR
7BT= STO 0 AWORK4(2)
7C#W BRN N16
7CSG #
7D#6 # THIS SECTION PREPARES TO EXECUTE THE LAST TFR NON AUTONOMOUSLY
7DRQ N4 HUNT2 3,BSTB,BSCB,ZAC3(2)
7F?B SMO 5
7FR2 LDX 0 AOBJST(3) [UMDATUMISED BS ADDR
7G=L STO 0 AWORK4(2) [FOR FINAL TFR
7GQ= N16 LDX 0 AWRDNUM(3) [LENGTH OF FINAL TFR
7H9W STO 0 AWORK2(2)
7HPG BRN N21 [J TO EXECUTE
7J96 #
7JNQ #
7K8B # ENTRY FROM SWAP-OUT MACRO VIA DOWN
7KN2 XX3S
7L7L #SKI K6PROCONT>99-99
7LM= (
7M6W TRACE JOBNO(2),SWAPOUTS
7MLG TRACE JOBNO(2),FROM CPA
7N66 )
7NKQ LDCH 7 ATYPE(2)
7P5B SBN 7 CPAT/64
7PK2 BZE 7 N100 [CHECK ISSUED FROM CPA
7Q4L GEOERR 1,NOT CPA
7QJ= N100 FJOCA 3,2 [POINTER TO JOB BLOCK
7R3W
7RHG JBC N102,3,JBNSW [ERROR IF
7S36 GEOERR 1,NSWAPABL [NOT SWAPPABLE
7SGQ
7T2B N102 JMBS NUP,3,JBSO,JBREEF [J IF SWAPPED OUT OR REALTIME
7WYW JBS N106,3,JBBEING [ IF BEING SWAPPED
7X4R ... PROGAXES 3,N100 [IF CANT ACCESS PROG,WAIT & J TO N100
7X8N ... ON CSWAPAB [SET S/O ABORT FLAG FOR STARTSTRAT
7X#K ...
7XDG # NO,THEREFORE S/I AND SWAPPABLE
7XY6 TESTRT NUP,3 [LEAVE SWAPPED IN IF REALTIME
7YCQ
7YXB MBS 3,JBSOMAC,JBCPASO
7^C2 MBI 3,JBBEING,JBSI
7^WL FPCACA 2,2 [FIND PCA
82B= LINKSET 2,ZLINKPAIR(1) [LINK TO K2SWAP
82TW FPUT [PCA ON LIST
83*G N103 COOR1 [WAIT FOR SWAP TO BE COMPLETED
83T6 #SKI K6SWAP>199-199
84#Q TRACE JOBNO(2),S/OWAITA
84SB FJOCA 3,2
85#2 ENDPAXES 3 [SIGNAL END OF PROGRAM ACCESS
85RL NUP UP [WOKEN HERE BY PROCESS CONTROLLER
86?=
86QW N106 BS 3,JBCPASO [MARK CPA WAITING
86W7 ... COOR1 [WAIT FOR SWAP TO BE COMPLETED
86^D ... BRN NUP
874P ...[ ENTRY (IN PCA) FROM TRUEDORM MACRO TO SWAP OUT A TRULY
8782 ...[ DORMANT PROGRAM
87?? ...[
87BJ ...XX5S
87FT ...#SKI K6SWAP>99-99
87K6 ... TRACE JOBNO(2),TRUEDORM
87NC ... FJOPCA 3,2 [FIND JOB BLOCK
87RN ... PROGAXES 3,XX5S [J IF BEING ACCESSED
87W^ ... ON CSWAPAB
882= ...#UNS ADPLLSKIP
885H ...(
888S ... LDN 0 1 [- DATAPASS COUNT OF
88#5 ... SMO ADPSWPPTR [- TRUDORM SWAPOUTS
88CB ... ADS 0 0
88GM ...)
88KY ... BRN N205
88PB MENDAREA 15,K200SWAP
8992 #END
^^^^ ...61533204000300000000