{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: SYSPROP867)}}
====== SYSPROP867 ======
(George Source)
**Macros used:** [[george:macro:APPEND|APPEND]], [[george:macro:BACKSPACE|BACKSPACE]], [[george:macro:BC|BC]], [[george:macro:BS|BS]], [[george:macro:CLOSE|CLOSE]], [[george:macro:DELETE|DELETE]], [[george:macro:FINDPEREC|FINDPEREC]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:INSERT|INSERT]], [[george:macro:LADDP|LADDP]], [[george:macro:LTYPE|LTYPE]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUT|MONOUT]], [[george:macro:NEW|NEW]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:OPENSYSX|OPENSYSX]], [[george:macro:REPLACE|REPLACE]], [[george:macro:RESET|RESET]], [[george:macro:REWIND|REWIND]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETMODE|SETMODE]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:STEP|STEP]], [[george:macro:STEPAGAIN|STEPAGAIN]], [[george:macro:STEPWRITE|STEPWRITE]], [[george:macro:TESTNAMX|TESTNAMX]], [[george:macro:TESTREP2|TESTREP2]], [[george:macro:TOPFCB|TOPFCB]], [[george:macro:TOPFCB2|TOPFCB2]], [[george:macro:TRACE|TRACE]], [[george:macro:UP|UP]], [[george:macro:UPPLUS|UPPLUS]]
22*P ... SEG SYSPROP,,LEN WAGSTAFF
22HJ ...# (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1983
22PD ...#OPT K0SYSPROP=0
2357 ...#LIS K0PROPERTY>K0PROPSYS>K0ALLGEO>K0SYSPROP
23DW #
23YG SEGENTRY K1SYSPROP,SYSPROPK1
24D6 # ENTERED AT E.M.S.
24XQ #
25CB SEGENTRY K2SYSPROP,SYSPROPK2
25X2 # ENTRY POINT TO OPEN :SYSTEM.PROPERTY
26BL #
26W= SEGENTRY K3SYSPROP,SYSPROPK3
27*W # ENTRY POINT TO IMPLEMENT PROPAE MACRO
27TG #
28*6 SEGENTRY K4SYSPROP,SYSPROPK4
28SQ # ENTRY POINT TO IMPLEMENT PROPCAE MACRO
29#B #
29BQ ...#
29F6 ...# SHARED FILESTORE ENTRY POINTS
29HG ...#
29KW ... FSHENTRY K5SYSPROP,SYSPROPK5,,SYSPROPK5
29N= ...# ENTRY POINT TO COLLECT PROPERTY INFORMATION FOR SWITCHABLE PERIPHERALS
29QL ...#
29T2 ... FSHENTRY K7SYSPROP,SYSPROPK7,,SYSPROPK7
29XB ...# ENTRY POINT FOR UNANTICIPATED CLOSEDOWN TO FREE IDFANDPROP SEMAPHORE
29^Q ...#
2=46 ... FSHENTRY K8SYSPROP,SYSPROPK8,,SYSPROPK8
2=6G ...# NORMAL ENTRY POINT TO FREE IDFANDPROP SEMAPHORE
2=8W ...#
2=?L #
2=R= PCENTRAL 12HCENTRAL
2?=W PCENTNO #20000001
2?QG TWOBITS #17777777
2#=6 PTAPE +1
2#PQ PCARDS +4
2*9B PRINTER +2
2*P2 PDRUM +9
2B8L PHDRUM +25
2BN= PIPC +28
2C7W ONEBIT #37777777
2CMG ONE #40000000
2D76 TWELVE #7777
2NDQ #
2NYB # SUBRNUTINE TO OPEN :SYSTEM.PROPERTY
2PD2 OPENSYS
2PXL SBX 7 FX1
2QC= ... OPENSYS ,PROPERTY,GENERAL,CAREFUL [GEOERR IF BREAK-IN OR ERROR
2Y=Q ADX 7 FX1
2YQB EXIT 7 0
2^=2 #
2^PL # SUBROUTINE TO FINDPROPERTY RECORD-EXIT POINTING TO
329= ...# SECOND WORD OF PAIR FOR SPECIFIC ASSOCIATION.AWORK1-COMMAND WORD
32NW ...# AWORK2-PROP.NO.,AWORK3-UNIT GEOG.NO.
338G #
33N6 UNIT
347Q SBX 7 FX1
34MB LDX 4 AWORK2(2)
3572 ANDX 4 TWOBITS(1)
35LL STEPU
366= STEP
36KW BZE 3 OUT
375G LDX 5 APROPNO(3)
37K6 ANDX 5 TWOBITS(1)
384Q TXU 5 4
38JB BCS STEPU
3942 LDX 4 AWORK3(2)
39HL ORX 4 ONE(1)
3=3= LDX 6 ATTCOUNT(3)
3=GW BZE 6 U4
3?2G U1
3?G6 TXU 4 APROPATT(3)
3?^Q BCC U2
3#FB ADN 3 1
3#^2 BCT 6 U1
3*DL BRN U4 [NO UNIT AE'D
3*Y= U2
3BCW ADN 3 1
3BXG LDX 5 APROPATT(3)
3CC6 ERX 5 AWORK1(2)
3CWQ SRL 5 12
3DBB BZE 5 U3
3DW2 ADN 3 1
3F*L SBN 6 1
3FT= BCT 6 U1
3G#W U4 ADX 7 FX1 [NOT AE'D
3GSG EXIT 7 1
3H#6 U3 ADX 7 FX1 [COMMAND WORS B0-B11 EQUAL
3HRQ EXIT 7 2
3J?B OUT ADX 7 FX1 [PROP.NO. UNKNOWN
3JR2 EXIT 7 0
3K=L #
3KQ= # SUBROUTINE TO DO THE STEPAGAIN,STEPWRITE&RESET X3
3L9W #
3LPG WRITE
3M96 SBX 7 FX1
3MNQ STEPAGAIN
3N8B STEPWRITE
3NN2 W1 TXU 4 APROPATT(3)
3P7L BCC W2
3PM= ADN 3 1
3Q6W BRN W1
3QLG W2 ADN 3 1
3R66 ADX 7 FX1
3RKQ EXIT 7 0
3S5B #
3SK2 #
3T4L # S/R TO PUT CENTRAL PROPERTY RECORD
3TJ= # IN EACH APERI/APIA OF TYPE GIVEN IN X5
3TPD ...# IF SYSPROP IS NOT OK THEN ALL OTHER PROPERTY ATTRIBUTIONS ARE REMOVED
3TWL ...# IF TYPE IS TR OR CR THEN ANY PROPERTY ASSOCIATIONS ARE REMOVED INSTEAD
3W3W #
3WHG PCENTSTO
3X36 SBX 7 FX1
3XGQ ... FINDPEREC 1,APFOTY,5,RETURN,,PSWOK,PSWOK
3Y2B ...PSWOK BNG 1 PEXIT
3YG2 LADDP 1,2
3YJK ... BZE 4 PSTOR [SYSPROP OK
3YM8 ... LDX 0 5
3YPR ... BZE 0 PBIP [TR:CLEAR ANY PROPERTY ASSOCIATIONS
3YSB ... SBN 0 3
3YW^ ... BZE 0 PBIP [CR:CLEAR ANY PROPERTY ASSOCIATIONS
3Y^J ...PSTOR STO 6 APERPROP(2) [STORE ATTRIBUTION FOR PROPERTY CENTR
3^47 ... BZE 4 RETURN [SYSPROP OK
3^6Q ... LDN 0 ATTMAX-1 [CLEAR ANYOTHER PROPERTY ATTRIBUTIONS
3^9* ...PSTOZ SMO 0
3^?Y ... STOZ APERPROP(2)
3^BH ... BCT 0 PSTOZ
3^F= BRN RETURN
3^HT ...PBIP LDN 0 ASSMAX*2
3^LD ...PCASS SMO 0
3^P3 ... STOZ APERPROP-1(2)
3^RL ... BCT 0 PCASS
3^W9 ... BRN RETURN
3^YW PEXIT LDX 1 FX1
42DG ADX 7 FX1
42Y6 EXIT 7 0
43CQ #
43XB #
44C2 # # # #
44WL # # # #
45B= # # # #
45TW # ## #
46*G # # # #
46T6 # # # #
47#Q # # # #
47SB #
48#2 #
48RL # THIS SECTION CHECKS THE FORMAT OF :SYSTEM.PROPERTY AT
49?= # RESTART TIME.IF THE PROPERTY'CENTRAL' DOES NOT EXIST,
49QW ...# OR THE RECORDS ARE NOT CORRECT FORMAT,A MESSAGE IS OUTPUT
4==G # TO THE OPERATOR AND ALL RECORDS ARE DELETED AND A RECORD
4=Q6 # FOR 'CENTRAL' IS SET UP.ATTRIBUTIONS AND ASSOCIATIONS
4?9Q # OF ALL 'TEMPORARY' PROPERTIES ARE CANCELLED;THOSE OF
4?PB ...# PERMANENT PROPERTIES ARE STORED IN THE APIA.'CENTRAL' IS
4#NL # ATTRIBUTED TO ALL SLOW OUTPUT DEVICES,DRUMS AND IPC
4*8= # LINKS.
4*=T ...# WE ALSO CHECK PROP.NOS NOT > 32K-1 (IE 15 BITS ONLY ALLOWED
4**D ...# FROM NOW ON); IF ANY FOUND >32K-1, ALL RECORDS EXCEPT 'CENTRAL
4*D3 ...# ARE DELETED AND OPERATOR INFORMED. RECORDS ARE ALSO SORTED INTO
4*GL ...# ASCENDING ORDER OF PROP.NO. SINCE PROPERTY WILL FROM NOW ON TAKE
4*K9 ...# THE LOWEST UNUSED NO. WHEN DEFINING A NEW PROPERTY.
4*MW #
4B7G SYSPROPK1
4BM6 ... OPENSYS ,PROPERTY,GENERAL,NOWAIT,QUERY,CAREFUL
4G4G TESTREP2 OK,OPENED
4GJ6 [IF DON'T HAVE TO RESTORE THE FILE -O
4H3Q [OTHERWISE SET THE MODES TO EMPTY IT
4HHB TRACE EXEC3(2),NOKPROP
4J32 SETMODE 4,GENERAL,EMPTY,CAREFUL
4JGL [IF FILE EXISTS GO & OPEN IT
4K2= [OTHERWISE SET THE MODES TO CREATE IT
4KFW TESTREP2 MAG,OPENOW
4K^G SETMODE 4,GENERAL,CREATE,CAREFUL
4LF6 [OPEN THE FILE
4LYQ OPENOW
4MDB ... OPENSYSX ,PROPERTY,4
4PBW OPENED
4PWG ... TOPFCB2 1 [CAUSE USAGE BLKS TO BE LEFT IN CORE
4QB6 ... BS 1,BFCORE
4QTQ STEP [STEP TO FIRST RECORD
4R*B BZE 3 NOCENT [NO RECORDS IN SYSPROP-BRANCH
4RT2 TESTNAMX 3,APROPNAME(3),PCENTRAL(1),NOTCENT
4S#L [IF'CENTRAL'NOT FIRST RECORD BRANCH
4SS= LDX 4 PCENTNO(1)
4T?W TXU 4 APROPNO(3)
4TRG BCS NOTCENT [IF NUMBER NOT 1 BRANCH
4W?6 ANDX 4 TWOBITS(1) [UNSET FIRST TWO BITS
4WQQ STO 4 AWORK1(2) [STORE NUMBER
4WXW ...#
4X52 ...# SORTING ALGORITHM. IF :SYS.PROP IN THIS FILESTORE HAS NOT
4X=6 ...# PREVIOUSLY BEEN SORTED, PROP NOS ARE LIKELY TO BE (A) WELL
4XC= ...# JUMBLED (B)ALL LOW NUMBERS. THE ALGORITHM WAS DESIGNED WITH
4XJB ...# THIS IN MIND. CONSIDER EXAMPLE:- 1 2 4 5 3 8 13 10 9
4XPG ...# WE STEP ON FROM 1ST RECORD (CENTRAL), REMEMBERING (IN X5) THAT
4XWL ...# 2 IS THE NEXT POSSIBLE PROPERTY NO. LO & BEHOLD THE PROP NO IS
4Y3Q ...# 2 SO WE UPDATE OUR COUNT OF FINALLY SORTED RECORDS (IN X6) TO 2
4Y8W ...# WE STEP ON LOOKING FOR 3, BUT FIND 4, IN THIS CASE, WE STEP ALL
4YB2 ...# THE WAY ALONG AND IF WE FIND 3, WE REMOVE IT, AND REPOSITION IT
4YH6 ...# AFTER OUR SET OF 'FINALLY SORTED' RECORDS. NOW HAVE:
4YN= ...# 1 2 3 4 5 8 13 10 9 WE CARRY ON LIKE THIS, BUT DONT
4YTB ...# FIND 6 AT ALL. IN THIS CASE WE UPDATE 'NEXT POSSIBLE NO' BY
4^2G ...# ONE (IN X5), AND REPOSITION OURSELVES AFTER THE SET OF 'FINALLY
4^7L ...# SORTED' AGAIN TO LOOK FOR 7. ETC ETC, IE:
4^#Q ...# 1 2 3 4 5 8 9 13 10 1 2 3 4 5 8 9 10 13
4^FW ...# X7=1 WHEN SEARCHING FOR A PROPNO NOT SO FAR FOUND, 0 OTHERWISE
4^H7 ... STOZ AWORK4(2) [SET NOT -VE TO ASSUME SYSPROP
4^JD ... [PREVIOUSLY SORTED
4^KP ...START
4^M2 ... LDN 5 1 [INITIAL VALUES-CURRENT PROPNO
4^S6 ... LDN 6 0 [ - NO OF FINALLY SORTED RECS
4^^= ... LDN 7 0 [FLAG
526B ...#
52?G ...OUTERLOOP
52DL ... ADN 6 1 [ANOTHER FINALLY SORTED REC
52KQ ...NEXTNUM
52QW ... ADN 5 1 [UPDATE NEXT POSSIBLE PROPNO
52Y2 ...#
5356 ...SMALLOOP
53== ... STEP
53CB ... BNZ 3 RECGOT [J ENDOFFILE NOT YET REACHED
53JG ... BZE 7 PLIST [J END REACHED & SORT COMPLETED
53PL ... LDN 7 0 [UNSET FLAG(SINCE PROPNO NOT FND
53WQ ... REWIND [THIS NUMBER MISSING- GET BACK
543W ... LDX 4 6 [TO WHERE WE WERE...
5492 ...STEPX STEP
54B6 ... BCT 4 STEPX
54H= ... BRN NEXTNUM [...AND TRY FOR NEXT NO.
54NB ...#
54TG ...RECGOT
552L ... LDX 4 FRH(3)
557Q ... SBN 4 7
55#W ... BNG 4 NOTFORM [J IF RECORD HAS WRONG FORMAT
55G2 ... LDX 4 APROPNO(3)
55M6 ... ANDX 4 BITS22LS
55S= ... LDCT 0 #777
55^B ... ANDX 0 4
566G ... BNZ 0 NOTFORM [PROP.NO TOO LARGE
566W ... LDX 0 AWORK4(2)
567= ... BNG 0 SORTING [SYSPROP BEING SORTED
567L ... LDX 0 4 [NO SORT REQ IF PROP NO. IS ASCENDING
5682 ... SBX 0 5
568B ... STO 4 5 [UPDATE X5 WITH THIS PROP NO.
568Q ... BPZ 0 OK1 [THIS PROP NO. IS ASCENDING
5696 ... STO 0 AWORK4(2) [INDICATE SYSPROP BEING SORTED
569G ... REWIND [RESTART BUT SORT THIS TIME
569W ... STEP [(REPOSITION ON PROPERTY CENTRAL)
56== ... LDCT 4 #400 [(INDICATE SYSPROP NOK+SORT REQUIRED)
56=L ... BRN RESETAPIA [AFTER CLEARING APIA OF AES AND AUS
56?2 ...SORTING
56?L ... LDX 0 5
56DQ ... SBX 0 4
56KW ... BPZ 0 THIS1 [J IF THIS IS ONE WE WANT
56R2 ... LDN 7 1 [ELSE J BACK TO KEEP SEARCHING
56Y6 ... BRN SMALLOOP
577S ...THIS1 BNZ 0 NOTFORM [NO. LOWER THAN CURRENT ONE FOUND
57CG ...#
57JL ...OK1 LDX 4 APROPNO(3)
57PQ ... SLL 4 1
57WW ... BPZ 4 TEMPPROP [J IF TEMPORARY PROP
5842 ...#
5896 ... LDX 0 FRH(3)
58B= ... STO 0 AWORK1(2)
58HB ... LDX 1 ATTCOUNT(3) [IF NO ATTRIBS OR ASSOCS, DONT..
58NG ... BZE 1 XFNAP [PUT ANYTHING IN APIA
58TL ... LDX 0 APROPNO(3)
592Q ... STO 0 AWORK3(2)
597W ... LDX 0 APROPGROUP(3)
59*2 ... STO 0 AWORK2(2)
59GG RECORD
5=26 LDX 4 APROPATT(3) [GET NEXT UNIT NUMBER
5=FQ BNG 4 PASSOC [IF ASSOCIATION BRANCH
5=N7 ... FINDPEREC 2,APGEOG,4,,,PSWOKB [FIND DEVICE LIST
5=WJ ...PSWOKB
5?53 ... BNG 2 NOPUT [IFNOT FOUND BRANCH
5?8N ... LTYPE 2,4
5?#* ... SBN 4 1
5?D2 ... BZE 4 OKTY1 [TP
5?HM ... SBN 4 1
5?M# ... BZE 4 OKTY1 [LP
5?Q^ ... SBN 4 2
5?WL ... BZE 4 OKTY1 [CP
5#2? ... SBN 4 5
5#5Y ... BZE 4 OKTY1 [DR
5#9K ... SBN 4 16
5#*= ... BZE 4 OKTY1 [DR
5#DX ... SBN 4 3
5#JJ ... BNZ 4 NOPUT [IPC
5#N9 ...OKTY1 LADDP 2,2
5#RW ...PP ADN 2 1 [ATTRIBUTION- START AT APERPROP+1
5#XW PERPROP
5*CG LDX 4 APERPROP(2) [FIND APERPROP WORD NOT
5*TS ... BNZ 4 PP [USED
5B#6 ... SMO FX2
5BQD ... LDX 0 AWORK3
5C8Q ...PLISTOK
5CM4 ... STO 0 APERPROP(2) [SET UP APIA ENTRY
5D5B ...NOPUT ADN 3 1
5DHN ... BCT 1 RECORD
5F22 ... BRN XFNAP [FINISHED WITH THIS RECORD
5FD# ...PASSOC
5FWL ... SMO FX1
5G#Y ... ANDX 4 ONEBIT [ZEROISE ASSOCIATION BIT
5GH^ ... FINDPEREC 2,APGEOG,4,,,PSWOKC [FIND DEVICE LIST
5GR2 ...PSWOKC
5H24 ... BNG 2 NOPUT [IF NOT FOUND BRANCH
5H8Q ... LTYPE 2,4
5HCD ... BZE 4 OKTY2 [TR
5HL6 ... SBN 4 3
5HSS ... BNZ 4 NOPUT [CR
5J3G ...OKTY2 LADDP 2,2
5J== PERPSOC
5JPW LDX 4 APERPROP(2) [FIND APERPROP WORD NOT
5K9G BZE 4 POKSOC [USED
5KP6 ADN 2 1
5L8Q BRN PERPSOC
5LNB POKSOC
5M82 LDX 4 APROPATT+1(3)
5MML STO 4 APERPROP(2) [STORE COMMAND WORD
5MTW ... SMO FX2
5N46 ... LDX 0 AWORK3
5N=B ... SMO FX1
5NDL ... ANDX 0 ONEBIT [ZEROISE EXCL BIT
5NLW SMO FX2
5P6G LDX 4 AWORK2 [LOAD APROPGROUP
5PL6 BPZ 4 NOCONSOC
5PYH ... SMO FX1
5Q=Y ... ERX 0 ONE [SET CONSOLE BIT
5QKB NOCONSOC
5R52 ADN 2 1
5RJL ADN 3 1
5S4= ... SBN 1 1
5SHW BRN PLISTOK
5SW6 ...#
5T8B ...XFNAP BZE 7 OUTERLOOP [J IF RECORD IS IN CORRECT POSN
5TGL ... SMO FX2
5TSW ... LDX 4 AWORK1 [RECORD LENGTH
5W76 ... BRN NEWREC
5WFB ...#
5WRL ...TEMPPROP
5X5W ... LDX 0 ATTCOUNT(3)
5XD6 ... BNZ 0 SOMAT [J IF ANY ATTRIBS OR ASSOCS
5XQB ... BZE 7 OUTERLOOP [J IF RECORD IS IN CORRECT POSN
5Y4L ...SOMAT LDN 4 7 [SINCE TEMP,RECORDLENGTH=7
5YBW ...NEWREC
5YP6 ... SETUPCORE 4,3,FILE,FWB [RECONSTRUCT RECORD IN FWB
5^3B ... STEPAGAIN
5^*L ... LDX 2 3
5^MW ... MHUNTW 3,FILE,FWB
6226 ... ADN 3 A1
62#B ... SMO 4
62LL ... MOVE 2 0
62YW ... SBN 4 7
63?6 ... BNZ 4 ZCTOK
63KB ... LDN 4 7
63XL ... STO 4 FRH(3)
649W ... STOZ ATTCOUNT(3) [TO BE SURE
64J6 ...ZCTOK DELETE
64WB ... REWIND [REPOSITION TO CORRECT PLACE
658L ... LDX 4 6 [TO INSERT REPLACED RECORD
65GW ... ADN 4 1
65T6 ...RESET STEP
667B ... BCT 4 RESET
66FL ... INSERT
66RW ... MHUNTW 1,FILE,FWB
6766 ... FREECORE 1
67DB ... BACKSPACE [JUST SO NEXT 'STEP' WORKS OK
67QL ... LDN 7 0 [RE-INITIALISE FLAG
684W ... BRN OUTERLOOP
68C6 ...#
68GX ...PLIST
68LN ... LDN 4 0 [INDICATE TO "PCENTSTO" SYSPROP OK
68QG PLIST1
69=6 LDX 6 PCENTNO(1) [CENTRAL NUMBER
6=9B LDX 5 PTAPE(1) [TAPE PUNCH
6=P2 CALL 7 PCENTSTO
6?8L LDX 5 PCARDS(1) [CARD PUNCH
6?N= CALL 7 PCENTSTO
6#7W LDX 5 PRINTER(1) [LINE PRINTER
6#MG CALL 7 PCENTSTO
6*76 LDX 5 PDRUM(1) [DRUM
6*LQ CALL 7 PCENTSTO
6B6B LDX 5 PHDRUM(1) [HS DRUM
6BL2 CALL 7 PCENTSTO
6C5L LDX 5 PIPC(1) [IPC
6CK= CALL 7 PCENTSTO
6CT4 ... BNG 4 START [SYSPROP TO BE SORTED
6D4W BRN PEND
6DJG #
6F46 NOCENT
6FHQ SETNCORE 7,3,FILE,FAPB [SET UP APPEND BLOCK
6G3B LDN 4 PCENTRAL(1)
6GH2 LDN 5 APROPNAME+A1(3) [STORE'CENTRAL'NAME
6H2L MOVE 4 3
6HG= LDN 4 7
6H^W STO 4 FRH+A1(3) [STORE RECORD HEADER
6JFG LDX 4 PCENTNO(1)
6J^6 STO 4 APROPNO+A1(3) [STORE NUMBER
6KDQ LDN 4 0
6KYB STO 4 APROPGROUP+A1(3) [ZEROIZE APROPGROUP
6LD2 STO 4 ATTCOUNT+A1(3) [SET COUNT OF ATTRIBUTIONS=0
6LXL APPEND [APPEND RECORD
6MC= BRN PMESS
6MWW NOTFORM
6NBG REWIND [GO BACK TO BEGINING OF SYSPROP
6NW6 STEP [STEP PAST'CENTRAL'RECORD
6P*Q NEXT
6PTB STEP [GET NEXT RECORD
6Q*2 BZE 3 PMESS [END OF FILE -BRANCH
6QSL DELETE [DELETE RECORD
6R#= BRN NEXT [TRY AGAIN
6RRW NEXT1
6S?G STEP [GET NEXT RECORD
6SR6 BZE 3 NOCENT [NON-EXISTENT-SO BRANCH
6T=Q NOTCENT
6TQB DELETE [DELETE RECORD
6W=2 BRN NEXT1 [TRY AGAIN
6WPL #
6X9= ...PMESS MONOUT JPROPMESS
6XNW ... LDN 4 1 [INDICATE TO "PCENTSTO" SYSPROP NOK
6Y8G ...RESETAPIA
6YN6 ... LDN 5 0 [TAPE READER
6^7Q ... CALL 7 PCENTSTO [CLEAR TR APIA ENTRIES OF ASSOCS
6^MB ... LDN 5 3 [CARD READER
7272 ... CALL 7 PCENTSTO [CLEAR CR APIA ENTRIES OF ASSOCS
745G BRN PLIST1
74K6 PEND
74Q# ... TOPFCB 1
74XG ... BC 1,BFCORE
754Q CLOSE
75JB UP
7642 #
76HL #
773= #
77GW # # # ###
782G # # # # #
78G6 # # # #
78^Q # ## #
79FB # # # #
79^2 # # # #
7=DL # # # #####
7=Y= #
7?CW #
7?XG # OPEN :SYSTEM.PROPERTY
7#C6 #
7#WQ SYSPROPK2
7*BB CALL 7 OPENSYS
7*W2 UP
7B*L #
7BT= #
7C#W #
7CSG # # # ###
7D#6 # # # # #
7DRQ # # # #
7F?B # ## ##
7FR2 # # # #
7G=L # # # # #
7GQ= # # # ###
7H9W #
7HPG #
7J96 # IMPLEMENT PROPAE MACRO WHICH SETS UP ASSOCIATIONS
7JNQ #
7K8B SYSPROPK3
7KN2 LDX 7 ACOMMUNE1(2)
7L7L STO 7 AWORK1(2)
7LM= LDX 7 ACOMMUNE2(2)
7M6W STO 7 AWORK2(2)
7MLG LDX 7 ACOMMUNE3(2)
7N66 STO 7 AWORK3(2)
7NKQ CALL 7 OPENSYS
7P5B CALL 7 UNIT
7PK2 BRN PENDA
7Q4L BRN NEW
7QJ= CALL 7 WRITE
7R3W LDX 5 AWORK1(2)
7RHG ORS 5 APROPATT(3)
7S36 BRN PCLOSE
7SGQ NEW
7T2B STEPAGAIN
7TG2 LDX 4 ATTCOUNT(3)
7T^L ADN 4 9
7W9D ... SETUPCORE 4,2,FILE,FWB
7WF= ... STEPAGAIN
7WP4 ... MHUNTW 2,FILE,FWB
7WYW LDX 1 ATTCOUNT(3)
7XDG ADN 1 6
7XY6 LDN 4 APROPNO(3)
7YCQ LDN 5 APROPNO+A1(2)
7YXB MOVE 4 0(1)
7^C2 ADN 1 3
7^WL STO 1 FRH+A1(2)
82B= ADX 2 ATTCOUNT+A1(2)
82TW SMO FX2
83*G LDX 4 AWORK3
83T6 LDX 1 FX1
84#Q ORX 4 ONE(1)
84SB STO 4 APROPATT+A1(2)
85#2 ADN 2 1
85RL SMO FX2
86?= LDX 4 AWORK1
86QW STO 4 APROPATT+A1(2)
87=G SBX 2 ATTCOUNT(3)
87Q6 SBN 2 1
889Q LDN 4 2
88PB ADS 4 ATTCOUNT+A1(2)
8992 BRN PDEL
89NL #
8=8= #
8=MW # # # #
8?7G # # # ##
8?M6 # # # # #
8#6Q # ## # #
8#LB # # # #######
8*62 # # # #
8*KL # # # #
8B5= #
8BJW #
8C4G # IMPLEMENT PROPCAE MACRO WHICH CANCELS ASSOCIATIONS
8CJ6 #
8D3Q SYSPROPK4
8DHB LDX 7 ACOMMUNE1(2)
8F32 STO 7 AWORK1(2)
8FGL LDX 7 ACOMMUNE2(2)
8G2= STO 7 AWORK2(2)
8GFW LDX 7 ACOMMUNE3(2)
8G^G STO 7 AWORK3(2)
8HF6 CALL 7 OPENSYS
8HYQ CALL 7 UNIT
8JDB BRN PENDA
8JY2 BRN PENDA
8KCL LDX 5 AWORK1(2)
8KX= ERX 5 APROPATT(3)
8LBW BZE 5 PBLOCK
8LWG CALL 7 WRITE
8MB6 LDX 5 AWORK1(2)
8MTQ ANDX 5 TWELVE(1)
8N*B ERS 5 APROPATT(3)
8NT2 BRN PCLOSE
8P#L PBLOCK
8PS= STEPAGAIN
8Q?W LDX 6 ATTCOUNT(3)
8QRG ADN 6 5
8R3# ... SETUPCORE 6,2,FILE,FWB
8R?6 ... STEPAGAIN
8RGY ... MHUNTW 2,FILE,FWB
8RQQ LDN 4 APROPNO(3)
8S=B LDN 5 APROPNO+A1(2)
8SQ2 MOVE 4 6
8T9L STO 6 FRH+A1(2)
8TP= SBN 6 7
8W8W STO 6 ATTCOUNT+A1(2)
8WNG BZE 6 PDEL
8X86 SMO FX2
8XMQ LDX 4 AWORK3
8Y7B ORX 4 ONE(1)
8YM2 XPRATT
8^6L TXU 4 APROPATT(3)
8^L= BCC UNITATT
925W LDX 5 APROPATT(3)
92KG STO 5 APROPATT+A1(2)
9356 ADN 3 1
93JQ ADN 2 1
944B BCT 6 XPRATT
94J2 BRN PDEL
953L UNITATT
95H= LDX 1 6
962W BZE 1 PDEL
96GG ADN 3 2
9726 LDN 4 APROPATT(3)
97FQ LDN 5 APROPATT+A1(2)
97^B MOVE 4 0(1)
98F2 PDEL
98YL ... REPLACE
99XW PCLOSE
9=CG CLOSE
9=X6 UPPLUS 1
9?BQ PENDA
9?WB UP
9#B2 #END
^^^^ ...33551046000100000000