{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: TAPEWAIT65)}}
====== TAPEWAIT65 ======
(George Source)
**Macros used:** [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:COOR1|COOR1]], [[george:macro:DCA|DCA]], [[george:macro:DFCLEAR|DFCLEAR]], [[george:macro:DFJUMPS|DFJUMPS]], [[george:macro:DFSET|DFSET]], [[george:macro:FREEMT|FREEMT]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GPERI|GPERI]], [[george:macro:HUNT|HUNT]], [[george:macro:JDISENG|JDISENG]], [[george:macro:JWPR|JWPR]], [[george:macro:LCAP|LCAP]], [[george:macro:LGEOG|LGEOG]], [[george:macro:LMODEQ|LMODEQ]], [[george:macro:LOCKC|LOCKC]], [[george:macro:LONGLOCK|LONGLOCK]], [[george:macro:LONGSET|LONGSET]], [[george:macro:LONGSTOP|LONGSTOP]], [[george:macro:LOSELONG|LOSELONG]], [[george:macro:LPROP|LPROP]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREE|MFREE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MTINFORM|MTINFORM]], [[george:macro:OPENDIR|OPENDIR]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:OUTNUM|OUTNUM]], [[george:macro:PICKREP2|PICKREP2]], [[george:macro:PUTREP2|PUTREP2]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETMODEQ|SETMODEQ]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETREP|SETREP]], [[george:macro:SSEARCH|SSEARCH]], [[george:macro:SWITRACE|SWITRACE]], [[george:macro:UNLOCK|UNLOCK]], [[george:macro:UP|UP]]
22FL #LIS K0TAPEWAIT>K0LIBRARY>K0ALLGEO
22^= #SEG TAPEWAIT65 [N.R.BOULT
23DW 8HTAPEWAIT
23YG SEGENTRY K1TAPEWAIT,QK1TAPEWAIT
24D6 # THIS SEGMENT HANDLES WAITING FOR TAPES ON BEHALF
24XQ # OF THE REDON AND LABEL COMMANDS
25CB #
25X2 #
26BL # CONSTANTS
26W= #
27*W TDRH 1
27TG TFAIL 2
28*6 TAFB 4
28SQ TNOWPR 8
29#B TNMS #34
29S2 REMASK #777777
2=?L THDDR 4HHDDR
2=R= TEXCH #73
2?=W REELMAX 512
2?QG TMODE +9
2#=6 TPOOL 12HPOOL TAPE
2#PQ #
2*9B # ENTRY POINT 1
2*P2 QK1TAPEWAIT
2B8L LGEOG ,5
2BN= ANDN 5 #777
2C7W OUTNUM 5,0
2CMG MTINFORM HRES
2D76 # A WAIT FOR DECK TO BE ENGAGED
2DLQ PAP DFJUMPS ,UNL,PAQ
2F6B LONGSET #65,XWT,5
2FL2 LONGSTOP XBRKIN
2G5L #SKI K6TAPEWAIT>199-199
2GK= SWITRACE 5,TWTWOKEN
2H4W PA JDISENG ,PAP [JUMP IF NOT ENGAGED
2HJG DFSET ,LOAD [MARK MT LOADED IN APIA
2J46 # B TO BE UNLOADED ?
2JHQ DFJUMPS ,UNL,PAQ [TO-BE-UNLOADED
2K3B # C TEST WPR STATUS
2KH2 PD
2L2L #SKI K6TAPEWAIT>199-199
2LG= SWITRACE CPPTR(2),TWTREW1
2L^W LDN 0 7
2MFG DCA ,DLA,0,MODE
2MP# ... LONGLOCK 2 [LONGLOCK THE CPAT
2M^6 LOCKC 2,£
2NDQ GPERI ,2 [REWIND
2NYB COOR1
2PD2 UNLOCK 2
2PMS ... LOSELONG 2 [UN-LONGLOCK THE CPAT
2PXL # E CHECK REWIND REPLY
2QC= LDCH 0 CPRW1(2) [REPLY
2QWW BZE 0 PG [OK
2RBG # F SET FAILED REPLY
2RW6 PF
2S*Q SETREP FAILED
2STB BRN PAS
2T*2 # G 1971 DECK ?
2TSL PG LPROP ,0
2W#= ANDN 0 #372
2WRW BNZ 0 PK [NOT 1971
2X?G # H DONT READ HEADER SET ?
2XR6 #SKI K6TAPEWAIT>199-199
2Y=Q SWITRACE 0,TWT1971
2YQB LDX 0 AWORK2(2)
2^=2 ANDX 0 TDRH(1)
2^PL BZE 0 PK [READ HEADER
329= # INITIAL WRITE TO 1971S NOT YET ALLOWED
32NW SEGENTRY AMRR71
338G NULL
33N6 SETREP NOTAV
347Q BRN PAS
34MB # I SET NON-STANDARD REPLY
3572 SEGENTRY ANRR71
35LL # IN CORRECT STATE ?
366= LDX 0 AWORK2(2)
36KW #SKI K6TAPEWAIT>99-99
375G SWITRACE AWORK2(2),TWTRR71
37K6 LDX 1 FX1
384Q ANDX 0 TNOWPR(1)
38JB BZE 0 PI [DONT CARE
3942 JWPR ,PI [WPR OK
39HL SETREP NOWPR
3=3= BRN PAS
3=GW PI
3?2G SETREP NONS
3?G6 # J FINISH
3?^Q UP
3#FB # K SET FIRST ATTEMPT
3#^2 PK LDN 7 0
3*DL # L READ HEADER
3*Y= ...PL SETNCORE 27,3,FLIB,FMAGH,1 [BUFFER BLOCK
3BCW LDN 0 0
3BXG DCA ,DLA,0,MODE [MODE
3CC6 LDN 0 20
3CWQ DCA ,STO,0,COUNT [LENGTH
3DBB LOCKC 3,SERCHF
3DW2 MHUNT 3,FLIB,FMAGH
3F*L LDN 0 A1+1(3)
3FT= DCA ,STO,0,CTSA [ADDRESS
3G54 ... LONGLOCK 2 [LONGLOCK THE CPAT
3G#W LOCKC 2,£
3GSG GPERI ,2
3H#6 COOR1
3HRQ UNLOCK 3
3J?B UNLOCK 2
3JH8 ... LOSELONG 2 [UN-LONGLOCK THE CPAT
3JR2 # AA TEST WPR STATUS
3K=L LDX 0 AWORK2(2)
3KQ= LDX 1 FX1
3L9W ANDX 0 TNOWPR(1)
3LPG BZE 0 PU
3M96 JWPR ,PU [WPR OK
3MNQ SETREP NOWPR
3N8B BRN PAD
3NN2 PU
3P7L # Z SECOND ATTEMPT ?
3PM= BNZ 7 PAB [2ND ATTEMPT
3Q6W # M CHECK READ REPLY
3QLG #SKI K6TAPEWAIT>99-99
3R66 SWITRACE CPRW1(2),TWTREP1
3RKQ LDCH 0 CPRW1(2) [REPLY
3S5B ANDN 0 #47
3SK2 BZE 0 PN [OK?
3T4L #
3TJ= # AF TEST IF FAIL
3W3W ANDN 0 4
3WHG BNZ 0 PAI [FAIL
3X36 # AG TEST IF TAPE MARK
3XGQ LDCH 0 CPRW1(2)
3Y2B ANDN 0 2
3YG2 BNZ 0 PR [TAPE MARK
3Y^L # AH UNINTELLIGIBLE REPLY
3^F= GEOERR 1,XREP
3^YW # AI FAIL 0 ?
42DG PAI LDX 0 CPRW1(2)
42Y6 ANDN 0 #77
43CQ BZE 0 PAK [FAIL 0
43XB # AJ FAIL 2 ?
44C2 SBN 0 1 [FAIL 1
44WL BZE 0 PAM
45B= SBN 0 1
45TW BNZ 0 PAC [FAIL 3
46*G # AM FAIL ALLOWED
46T6 PAM LDX 0 AWORK2(2)
47#Q ANDX 0 TFAIL(1)
47SB BNZ 0 PR [FAIL NOT ALLOWED
48#2 # AC SET FAILED REPLY
48RL PAC SETREP FAILED
49?= # AD FREE BUFFER BLOCK
49QW PAD
4==G MFREE FLIB,FMAGH
4=Q6 # AE REWIND DECK
4?9Q PAE
4?PB BRN PAS [TO DEALLOCATE DECK
4#92 # AK DECK SWITCHABLE ?
4#NL PAK LCAP ,0
4*8= ANDN 0 #10
4*MW BZE 0 PAM [NOT SWITCHABLE
4B7G # AL IN NORMAL SETTING
4BM6 LMODEQ ,0
4C6Q STO 0 AWORK3(2)
4CLB TXU 0 TNMS(1)
4D62 BCC PAM [ALREADY IN NORMAL SETTING
4DKL # AN SWITCH DECK
4F5= #SKI K6TAPEWAIT>199-199
4FJW SWITRACE 0,TWTMODEQ
4G4G SETMODEQ ,TNMS(1)
4GJ6 # AO MARK FOR 2ND ATTEMPT
4H3Q LDN 7 1 [MARKER
4HHB BRN PL [READ ATTEMPT
4J32 # AB SWITCH DECK BACK TO FORMER SETTING
4JGL PAB SETMODEQ ,AWORK3(2)
4K2= #SKI K6TAPEWAIT>99-99
4KFW SWITRACE CPRW1(2),TWTREP2
4K^G LDCH 0 CPRW1(2) [CHECK REPLY
4LF6 ANDN 0 #57
4LYQ BNZ 0 PAM [FAIL
4MDB # N STANDARD FORMAT HEADER
4MY2 PN MHUNT 3,FLIB,FMAGH
4NCL LDX 0 CPRW1(2)
4NX= ANDX 0 REMASK(1)
4PBW DCA ,SBX,0,CTSA
4PWG ANDX 0 REMASK(1) [NR OF WORDS
4QB6 SBN 0 9
4QTQ BNG 0 PR [TOO SHORT
4R*B LDX 0 A1+1(3) [FIRST WORD
4RT2 TXU 0 THDDR(1)
4S#L BCS PR
4SS= LDX 5 A1+2(3) [TSN :-
4T?W BNG 5 PR [NEG
4TRG BZE 5 PR [ZERO
4W?6 LDN 7 12 [NAME :-
4WQQ LDX 2 3
4X=B PN1 LDCH 0 A1+3(2)
4XQ2 TXL 0 TEXCH(1)
4Y9L BCC PR [DISALLOWED CHARACTER
4YP= BCHX 2 £
4^8W BCT 7 PN1
4^NG LDX 2 FX2 [RESET X2
5286 LDX 0 A1+6(3) [REEL
52MQ TXL 0 REELMAX(1)
537B BCC PR [>512
53M2 # O KNOWN IN :SYSTEM.SERIAL
546L #SKI K6TAPEWAIT>199-199
54L= SWITRACE 5,TWTTSN
555W LDN 7 0 [NOT YET KNOWN
55KG OPENSYS XBRKIN,SERIAL,READ
5656 SSEARCH PX3,5 [LOOK FOR ENTRY IN :SYSTEM.SERIAL
56JQ LDX 0 5(3) [STATUS WORD
574B #SKI K6TAPEWAIT>199-199
57J2 SWITRACE 0,TWTSS5
583L SLC 0 1
58*2 ... BPZ 0 PNW
58LB ... LDN 7 1 [WORK TAPE
58XQ ... BRN PX3
5996 ...PNW LDX 0 2(3)
59GG BNZ 0 PO2 [TAPE IN USE
5=26 MHUNT 3,FLIB,FMAGH
5=FQ LDX 0 TPOOL(1) [OTHERWISE POOLTAPE
5=^B LDX 2 TPOOL+2(1)
5?F2 LDX 1 TPOOL+1(1)
5?YL TXU 0 A1+3(3)
5#D= TXU 1 A1+4(3)
5#XW TXU 2 A1+5(3)
5*CG BCS PX3 [NO-OK
5*X6 LDN 7 1 [KNOWN AS A POOL TAPE
5BBQ #SKI K6TAPEWAIT>199-199
5BWB SWITRACE 7,TWTPOOL
5CB2 BRN PX3
5CTL PO2 STO 0 ACOMMUNE1(2)
5D*= LDX 0 3(3)
5DSW STO 0 ACOMMUNE2(2)
5F#G LDX 0 4(3)
5FS6 STO 0 ACOMMUNE3(2)
5G?Q # V LOOK IN DIRECTORY
5GRB SETNCORE 12,3,FILE,FABSNB
5H?2 LDN 0 10
5HQL STO 0 A1(3) [RECORD HEADER
5J== LDN 0 #2001
5JPW ORS 0 ATYPE(3) [MT TYPE
5K9G LDX 0 ACOMMUNE1(2) [USER NAME
5KP6 STO 0 A1+1(3)
5L8Q LDX 0 ACOMMUNE2(2)
5LNB STO 0 A1+2(3)
5M82 LDX 0 ACOMMUNE3(2)
5MML STO 0 A1+3(3)
5N7= STOZ A1+4(3) [LOCAL NAME & DETAILS ..
5NLW LDN 0 A1+4(3) [SET ZERO
5P6G LDN 1 A1+5(3)
5PL6 MOVE 0 5 [ZEROISED
5Q5Q NGN 0 1
5QKB STO 0 A1+10(3) [RETENTION PERIOD
5R52 STO 5 A1+11(3) [TSN
5RJL OPENDIR XBRKIN,READ,ERASING
5S4= MFREE FILE,FABSNB
5SHW MHUNT 3,FILE,ENT
5T3G MHUNT 2,FLIB,FMAGH
5TH6 # W NEW TAPE ?
5W2Q LDX 0 ELOC1(3)
5WGB BZE 0 PX1 [IF SO,CANNOT DISPROVE
5X22 # X IDENTICAL NAME
5XFL LDN 1 4
5X^= PX2 SMO 1
5YDW LDX 0 A1+3(2)
5YYG SMO 1
5^D6 TXU 0 ELOC1(3)
5^XQ BCS PX1
62CB SBN 1 1
62X2 BPZ 1 PX2
636S ... LDN 7 1
63BL PX1 CLOSETOP [DIRECTORY
64*W PX3 CLOSETOP [SERIAL
64TG BZE 7 PP [NOT SECURE
65*6 # Y SET SECURE REPLY
65SQ SETREP SECURE
66#B BRN PAD
66S2 # P REWIND REQUIRED
67?L PP SETREP OK
67R= LDX 0 AWORK2(2)
68=W ANDX 0 TAFB(1)
68QG BZE 0 PT
69=6 # Q FINISH
69PQ PQ UP
6=9B # R SET NONSTANDARD REPLY
6=P2 PR SETREP NONS
6?8L # S FREE BUFFER BLOCK
6?N= PS MFREE FLIB,FMAGH
6#7W # T REWIND DECK
6#MG PT LDN 0 7
6*76 DCA ,DLA,0,MODE
6*BY ... LONGLOCK 2 [LONGLOCK THE CPAT
6*LQ LOCKC 2,£
6B6B GPERI ,2 [REWIND
6BL2 COOR1
6C5L UNLOCK 2
6C*D ... LOSELONG 2 [UN-LONGLOCK THE CPAT
6CK= # U CHECK REWIND REPLY
6D4W #SKI K6TAPEWAIT>199-199
6DJG SWITRACE CPRW1(2),TWTRWREP
6F46 LDCH 0 CPRW1(2)
6FHQ BNZ 0 PF
6G3B BRN PQ
6GH2 # AQ REMOVE TO-BE-UNLOADED
6H2L PAQ
6HG= #SKI K6TAPEWAIT>199-199
6H^W SWITRACE CPPTR(2),TWTUNL
6JFG DFCLEAR ,UNL
6J^6 # AR SET UNLOADED REPLY
6KDQ SETREP UNLOADED
6KYB # AS DE-ALLOCATE DECK
6LD2 PAS
6LXL LDX 1 FX1
6MC= LDX 2 FX2
6MM4 ... PICKREP2 6
6MWW LDX 0 TMODE(1) [SET UP MODE
6NBG DCA ,DLA,0,MODE
6NL# ... LONGLOCK 2 [LONGLOCK THE CPAT
6NW6 LOCKC 2,£
6P*Q GPERI ,2
6PTB COOR1
6Q*2 UNLOCK 2
6QJS ... LOSELONG 2 [UN-LONGLOCK THE CPAT
6QSL DFCLEAR ,LOAD [CLEAR TAPE UP BIT
6R#= FREEMT
6RRW # AT TERMINATE
6S3N ... PUTREP2 6
6S?G UP
6SR6 SERCHF
6T=Q HUNT 2,FLIB,FMAGH
6TQB EXIT 1 0
6W=2 #
6WPL # GEOERRS
6X9= #
6XNW XBRKIN GEOERR 1,XBRKIN
6Y8G #
6YN6 XLIB GEOERR 1,XLIB
6^7Q XWT GEOERR 1,XWT
6^MB #
7272 MENDAREA 50,K99TAPEWAIT
72LL #END
^^^^ ...51263352001100000000