{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: TESTMON)}}
====== TESTMON ======
(George Source)
**Macros used:** [[george:macro:BXU|BXU]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HUNT2|HUNT2]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:TESTMON|TESTMON]], [[george:macro:TRACE|TRACE]], [[george:macro:UP|UP]], [[george:macro:UPPLUS|UPPLUS]]
22FL #SEG TESTMON [ROGER TERRY
22^= #OPT K0TESTMON=K0ALLGEO>K0GREATGEO
23DW #LIS K0TESTMON
23YG #OPT K6TESTMON=K6ALLGEO>K6GREATGEO
24D6 #
24XQ 8HTESTMON
25CB #
25X2 # THIS SEGMENT HANDLES THE TESTMON MACRO WHEN AMON OF THE PCA INDICATES
26BL # THAT MONITORING OF A PARTICULAR TYPE MAY BE REQUIRED.ON ENTRY
26W= # ACOMMUNE5=TYPE OF MONITORING,ACOMMUNE6=TYPE/UNIT NO OF PERIPHERAL
27*W # AND (ENTRY POINT 1 ONLY) ACOMMUNE4=ADDRESS OF PCA
27TG #
28*6 # ENTRY POINTS
28SQ #
29#B SEGENTRY K1TESTMON,ZEP1 [ENTRY IF CURRENT ACT NOT PCA
29S2 SEGENTRY K2TESTMON,ZEP2 [ENTRY IF CURRENT ACT IS PCA
2=?L #
2=R= TYPEMSK #77000000
2?=W UNOMSK #00770000
2?QG TYP13 #15000000
2#=6 #
2#PQ ZEP1 [ENTRY IF CURRENT ACT NOT PCA
2*9B LDX 2 ACOMMUNE4(2)
2*P2 ZEP2 [ENTRY IF CURRENT ACT IS PCA
2B8L HUNT2 3,APED,AMONCAT,2
2BN= LDX 2 FX2
2C7W #SKI K6TESTMON>599-599
2CMG TRACE ACOMMUNE5(2),TMNTYPE
2D76 LDX 0 BPALL(3)
2DLQ ANDX 0 ACOMMUNE5(2)
2F6B BNZ 0 UPFND [ J IF MNTRG OF REQUD TYPE ON ALL PLS
2FL2 #SKI K6TESTMON>99-99 [REMOVE CHECK IN MK7
2G5L (
2GK= LDX 0 ACOMMUNE6(2)
2H4W ANDX 0 ZFORMAT(1)
2HJG BZE 0 ZFOK [J IF PERIPHERAL NAME IN N/I FORMAT
2J46 GEOERR 1,PRLFRMAT
2JHQ ...ZFORMAT #70077400
2K3B ZFOK
2KH2 )
2L2L LDCT 4 #777
2LG= ANDX 4 ACOMMUNE6(2)
2L^W SLL 4 3 [PRL TYPE TO B0-5
2MFG BXU 4 TYP13(1),NOT13 [REPLACE TYPE 13 BY TYPE 6
2M^6 LDCT 4 #060
2NDQ NOT13 NGN 5 1
2NYB LDX 6 ACOMMUNE5(2) [MNTRG TYPE WORD
2PD2 STO 3 AWORK1(2) [REMEMBER ADDR OF AMONCAT BLOCK
2PXL CALL 7 TEMON [J TO UPFND IF MNTRG OF REQUD TYPE ON
2QC= [ ALL UNIT NOS OF GIVEN PRL TYPE
2QWW LDX 3 AWORK1(2) [RESTORE ADDR OF AMONCAT BLOCK
2RBG LDX 0 ACOMMUNE6(2)
2RW6 SLL 0 12 [ISOLATE UNIT NO OF SPECD PERIPH
2S*Q ORX 4 0 [ AND INSERT IN X4
2STB LDN 5 1
2T*2 CALL 7 TEMON [J TO UPFND IF MNTRG OF REQUD TYPE ON
2TSL [ SPECD TYPE/UNIT NO OF PEREIPHERAL
2W#= #SKI K6TESTMON>599-599
2WRW TRACE ACOMMUNE6(2),MNOTREQD
2X?G UPPLUS 3 [ EXIT - MNTRG NOT REQUD
2XR6 UPFND
2Y=Q #SKI K6TESTMON>599-599
2YQB TRACE ACOMMUNE6(2),MREQUD
2^=2 UP [EXIT - MNTRG REQUD
2^PL #
329= # THIS SUBROUTINE CHECKS IF MONITORING OF SPECIFIED TYPE ON SPECIFIED
32NW # TYPE/UNIT NO OF PERIPH IS SET IN 1 OF THE TABLES OF THE AMONCAT BLOCK
338G # ON ENTRY X3->AMONCAT BLOCK;X4 B0-5 TYPE B6-11 UNIT NO B12-23 ZERO
33N6 # X5=+1 OR- 1 FOR TOP OR BOT TABLE ; X6=MNTRG TYPE WORD;X7 LIN
347Q # ON EXIT X3,X0 AND GEN6 DESTROYED. J TO UPFND IF MNTRG REQUD
34MB #
3572 TEMON
35LL STO 7 GEN6
366= BNG 5 TE1
36KW LDX 7 BTPOINT(3) [COUNT OF TABLE ENTRIES
375G ADN 3 BPTAB [PNTR TO BASE OF TABLE
37K6 BRN TE2
384Q TE1 LDX 7 ALOGLEN(3)
38JB SBN 7 BPTAB-A1+1
3942 SBX 7 BBPOINT(3) [COUNT OF TABLE ENTRIES
39HL ADX 3 ALOGLEN(3) [PNTR TO BASE OF TABLE
3=3= ADN 3 A1-1
3=GW TE2 BZE 7 TE3 [EXIT IF TABLE EMPTY
3?2G TE5 LDX 0 0(3)
3?G6 ANDX 0 HALFTOP
3?^Q BXU 0 4,TE4 [J IF TYPE/UNIT NOS NOT EQUAL
3#FB LDX 0 0(3)
3#^2 ANDX 0 6 [IF TYPE/UNIT NOS COINCIDE,
3*DL BNZ 0 UPFND [ J IF SPECIFIED MNTRG BIT SET
3*Y= TE4 ADX 3 5
3BCW BCT 7 TE5
3BXG TE3 BRN (GEN6)
3CC6 #
3CWQ MENDAREA 10
3DBB #END
^^^^ ...25362475000200000000