{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: UNLOAD7)}}
====== UNLOAD7 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:BXE|BXE]], [[george:macro:BXL|BXL]], [[george:macro:BXU|BXU]], [[george:macro:CHAIN|CHAIN]], [[george:macro:COMERR|COMERR]], [[george:macro:CONSERNO|CONSERNO]], [[george:macro:DFJUMPN|DFJUMPN]], [[george:macro:DFJUMPS|DFJUMPS]], [[george:macro:DFLOAD|DFLOAD]], [[george:macro:DFSET|DFSET]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:ENTPROP|ENTPROP]], [[george:macro:ERROR|ERROR]], [[george:macro:ERRTEST|ERRTEST]], [[george:macro:FDTENT|FDTENT]], [[george:macro:FSHSKIP|FSHSKIP]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HUNT|HUNT]], [[george:macro:HUNT2OPT|HUNT2OPT]], [[george:macro:JALLOC|JALLOC]], [[george:macro:JONL|JONL]], [[george:macro:JWRONG|JWRONG]], [[george:macro:LGEOG|LGEOG]], [[george:macro:LJOBNO|LJOBNO]], [[george:macro:LONGON|LONGON]], [[george:macro:LPROP|LPROP]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREE|MFREE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MTCHAR|MTCHAR]], [[george:macro:MTEXPROP|MTEXPROP]], [[george:macro:MTINFORM|MTINFORM]], [[george:macro:NAMETOP|NAMETOP]], [[george:macro:OUTNUM|OUTNUM]], [[george:macro:OUTPARAM|OUTPARAM]], [[george:macro:PARAFREE|PARAFREE]], [[george:macro:PARALYSE|PARALYSE]], [[george:macro:PARSORTX|PARSORTX]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETALLOC|SETALLOC]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:SPARANOT|SPARANOT]], [[george:macro:SPARAPAS|SPARAPAS]], [[george:macro:SWITRACE|SWITRACE]], [[george:macro:TESTREP|TESTREP]], [[george:macro:TESTREP2|TESTREP2]], [[george:macro:UNLOAD|UNLOAD]], [[george:macro:VFREE|VFREE]]
22FL #LIS K0UNLOAD>K0LIBRARY>K0ALLGEO
22^= #SEG UNLOAD7 [N.R.BOULT
23DW 8HUNLOAD
23YG SEGENTRY K1UNLOAD,QK1UNLOAD
24D6 UNMAX +#1000
24XQ QMT #325564
25CB PENRZI #201
25X2 QK1UNLOAD
26BL LDN 7 0
26W= Q1
27*W SPARAPAS
27TG HUNT 3,CPB,CUNI
28*6 LDX 0 ANUM(3)
28SQ BZE 0 Q1 [BRANCH IF NULL PARAMETER
29#B BNG 0 Q2 [BRANCH IF NO MORE PARAMETERS
29S2 ADN 7 1
2=?L LDX 0 APARA(3)
2=R= SRL 0 6
2?=W BXE 0 QMT(1),Q3 [BRANCH IF *MT
2?QG LDX 3 JPARNUM(3) [PARAMETER NUMBER
2#=6 PARSORTX QBRKIN,3 [ANALYSE PERIPHERAL DESCRIPTION
2#PQ BRN Q1
2*9B QBRKIN
2*P2 GEOERR 1,XBRKIN
2B8L Q2
2BN= MFREE CPB,CUNI
2C7W BNZ 7 Q4 [BRANCH IF PARAMETER SPECIFIED
2CMG COMERR JPARMIS
2D76 # SET UP CPAR/JSCE BLOCK FOR *MT
2DLQ Q3
2F6B SMO ALOGLEN(3)
2FL2 LDN 4 JSCER-APARA
2G5L SETUPCORE 4,3,CPAR,JSCE [SET UP CPAR/JSCE BLOCK
2GK= MHUNT 2,CPB,CUNI
2H4W LDCT 0 #400
2HJG STO 0 JSCEP(3)
2J46 LDCT 0 #50
2JHQ STO 0 JSCEA(3)
2K3B LDX 0 JPARNUM(2)
2KH2 SLL 0 12
2L2L STO 0 JSCEQ(3)
2LG= LDX 0 ANUM(2)
2L^W DSA 0 JSCEQ(3) [NO OF CHARS IN PARAMETER
2MFG ADN 2 APARA
2M^6 ADN 3 JSCER
2NDQ ANDN 0 #7777
2NYB SMO 0
2PD2 MVCH 2 0 [COPY PARAMETER
2PXL MHUNT 2,CPB,CUNI
2QC= LDX 4 GSIGN [NO SPECIAL PROPERTIES
2QWW LDX 3 JPARNUM(2)
2RBG PARALYSE ,,3
2RHN ...#UNS ANSTOOMANY
2RNW ... TESTREP2 TOOMANY,Q3ERR2 [ CHECK FOR >24 PARAMETERS
2RW6 SPARANOT 2
2S*Q MHUNT 2,CPB,CUNI
2STB NGX 0 ANUM(2)
2T*2 BPZ 0 Q3A [BRANCH IF NO QUALIFIER
2TSL LDX 0 APARA(2)
2W#= SRL 0 6
2WRW ANDN 0 #7777
2X?G SBN 0 #6062
2XR6 BNZ 0 Q3A [BRANCH IF NOT PROPERTY QUALIFIER
2Y=Q MFREE CPB,CUNI
2YQB LDN 3 2
2^=2 PARALYSE ,,3 [REMOVE BRACKETS FROM PROP QUAL
2^C8 ...#UNS ANSTOOMANY
2^JB ... TESTREP2 TOOMANY,Q3ERR2 [ CHECK FOR >24 PARAMETERS
2^PL SPARANOT 1
329= ENTPROP
32NW TESTREP NAMEFORM,Q3ERR1,ILLCOMB,Q3ERR,ILLMODE,Q3ERR
338G MHUNT 2,FILE,FPROPS
33N6 NAMETOP 2,APERI,APROPS
347Q MTEXPROP DECK
34MB TESTREPN OK,Q3ERR
3572 MTCHAR ACOMMUNE1(2)
35LL LDX 4 ACOMMUNE1(2)
366= MFREE APERI,APROPS
36KW Q3A
375G MHUNT 2,CPAR,JSCE
37K6 STO 4 JSCEK(2)
384Q MFREE CPB,CUNI
38JB Q3A1
3942 PARAFREE
39HL MFREE CPB,CUNI
3=3= BRN Q1
3=GW Q3ERR
3?2G MFREE CPB,CUNI
3?G6 MFREE CPAR,JSCE
3?^Q ERRTEST 3,Q3A1,ILLCOMB,ILLMODE
3#FB GEOERR 1,PROPREP
3#^2 Q3ERR1
3*DL MFREE CPB,CUNI
3*Y= MFREE CPAR,JSCE
3BCW ERROR ILLQUAL
3BXG BRN Q3A1
3B^D ...#UNS ANSTOOMANY
3C3B ...(
3C5# ...Q3ERR2
3C7= ... MFREE CPAR,JSCE
3C98 ... ERROR JMAXPAR
3C?6 ... BRN Q3A1
3C*4 ...)
3CC6 # ALL PARAMETERS HAVE BEEN ANALYSED
3CWQ Q4
3DBB LDX 3 FX2
3DW2 Q4A
3F*L HUNT2OPT 3,CPAR,JSCE
3FT= BNG 3 Q4B [BRANCH IF ALL CPAR/JSCE BLOCKS EXAMI
3G#W LDCH 0 JSCEA(3)
3GJN ... BZE 0 Q4A [*TR
3GSG ... SBN 0 3
3H4# ... BZE 0 Q4A [*CR
3H#6 ... SBN 0 2
3HHY ... BNZ 0 Q4D [J IF NOT *MT
3HRQ CHAIN 3,FX2
3J?B LDX 4 JSCEA(3)
3JR2 ANDN 4 #777 [EXTRACT GEOGRAPHIC NO IF ANY
3K=L BNZ 4 Q7
3KQ= LDX 0 JSCEK(3)
3L9W SMO FX2
3LPG STO 0 AWORK1
3M96 BRN Q5
3MNQ Q4B
3N8B HUNT 3,CPAR,JSCE
3NN2 BNG 3 Q4C
3P7L ACROSS SPUNLOAD,1
3PM= Q4C
3Q6W ENDCOM
3Q=2 ...Q4D
3Q*6 ... CHAIN 3,FX2
3QD= ... CALL 6 SETCUNI
3QHB ... ERROR JWRONGTYPE
3QLG Q6
3R66 VFREE CPB,CUNI
3RKQ MFREE CPAR,JSCE
3S5B BRN Q4
3SK2 ...# SUBROUTINE TO SET UP A CPB/CUNI BLOCK
3T4L ...SETCUNI
3TJ= ... SBX 6 FX1
3W3W LDX 4 JSCEQ(3)
3WHG ANDN 4 #7777
3X36 SRA 4 1
3XGQ SRA 4 1
3Y2B ADN 4 2
3YG2 SETUPCORE 4,3,CPB,CUNI
3Y^L MHUNT 2,CPAR,JSCE
3^F= LDX 0 JSCEQ(2)
3^YW SRL 01 12
42DG SRL 1 12
42Y6 STO 1 ANUM(3) [NUMBER OF CHARACTERS
43CQ STO 0 JPARNUM(3)
43XB ADN 2 JSCER
44C2 ADN 3 APARA
44WL MVCH 2 0(1)
44Y8 ... ADX 6 FX1
44^Q ... EXIT 6 0
454W ...# UNLOAD A DECK WITH A GIVEN GEOGRAPHIC NUMBER
4582 ...Q7
45?6 ... CALL 6 SETCUNI
45B= MHUNT 2,CPAR,JSCE
45TW LDX 3 JSCEP(2)
46*G JWRONG 3,TWONG [JUMP IF DECK WRONGED
46T6 DFJUMPS 3,LOAD,Q9 [JUMP IF ENGAGED
47#Q JALLOC 3,Q10 [JUMP IF ALREADY ALLOCATED
47SB ERROR JNOTENGAGE
48#2 BRN Q6
48RL TWONG ERROR JWRONGED [OUTPUT ERROR MESSAGE
49?= BRN Q6
49QW Q10 DFSET 3,UNL [SET 'UNLOAD COMMAND GIVEN' BIT
4==G LGEOG 3,4
4=Q6 LONGON #65,4 [WAKE UP REDON OR LABEL
4?9Q BRN Q6
4?PB Q9 JONL 3,Q12 [JUMP IF TAPE ONLINE
4#92 JALLOC 3,Q12 [JUMP IF ALLOCATED
4#9T ... FSHSKIP B,Q9A [ OMIT CHEK FOR RV'S IN M/C B
4#=N ...(
4#?K ... DFJUMPS 3,NONS,Q9A
4#B8 ... DFLOAD 3,TSN,5
4#DR ... FDTENT 2,5,Q9A [DO NOT UNLOAD A TAPE FOR WHICH
4#HB ... BRN Q12 [THERE IS AN OUTSTANDING RV
4#JM ...)
4#K^ ...Q9A
4#NL SETALLOC 3
4*8= UNLOAD 3,,,UNL,AUT
4*MW BRN Q6
4B7G Q11 DFSET 3,UNL [SET 'UNLOAD COMMAND GIVEN' BIT
4BM6 Q12 DFLOAD 3,TSN,5
4C6Q LJOBNO 3,6
4CLB LDX 4 3 [KEEP FOR LATER USE
4D62 SETNCORE 5,3,AONBS,GROT
4DKL DFJUMPN 4,NONS,Q13
4F5= LDN 0 TNON(1)
4FJW LDN 1 A1+1(3)
4G4G MOVE 0 4 [NONSTANDARD TAPE
4GJ6 LDN 0 16
4H3Q STO 0 A1(3) [COUNT OF CHARACTERS
4HHB BRN Q14
4J32 Q13 LDN 2 3
4JGL BZE 5 Q30 [TSN NOT KNOWN
4K2= CONSERNO 5,ACOMMUNE1
4KFW MHUNT 3,AONBS,GROT
4K^G Q30 LDN 0 TMT(1) ['MT'
4LF6 LDN 1 A1+1(3)
4LYQ MVCH 0 3 ['MT '
4MDB BZE 5 Q31
4MY2 LDN 0 ACOMMUNE2(2)
4NCL LDX 2 ACOMMUNE1(2)
4NX= MVCH 0 0(2) [TSN
4PBW ADN 2 3
4PWG Q31 STO 2 A1(3) [CHARACTER COUNT
4QB6 Q14 OUTPARAM A1(3),A1+1,AONBS,GROT
4QTQ JONL 4,Q15 [JUMP IF DECK ONLINE
4R*B ERROR JUSSYS
4RT2 BRN Q6
4S#L Q15 OUTNUM 6,0
4SS= ERROR JUNOL
4T?W BRN Q6
4TRG # UNLOAD ALL DECKS WITH PROPERTY HELD IN AWORK1
4W?6 Q5
4WQQ SETNCORE 64,3,FLIB,FDECKS [FOR LIST OF DECKS
4X=B STOZ A1(3) [NR SO FAR
4XQ2 LDN 7 5
4Y9L FINDPERE 2,APFOTY,7,Q19 [FIND NEXT DECK
4YP= BNG 2 Q18 [BRANCH IF NO MORE
4^8W #SKI K6UNLOAD>299-299
4^NG SWITRACE 2,ULSERCH
5286 JWRONG 2,Q19 [JUMP IF DECK WRONGED
52MQ JALLOC 2,Q19 [JUMP IF ALLOCATED
537B DFJUMPN 2,LOAD,Q19 [JUMP IF DECK NOT LOADED
53M2 SMO FX2
546L LDX 0 AWORK1 [REQUIRED HARDWARE PROPERTY CODE
54L= BNG 0 Q5C [BRANCH IF NO PROPERTIES SPECIFIED
555W LPROP 2,6
55*N ... LDX 1 FX1
55KG BXL 0 PENRZI(1),Q5A [BRANCH UNLESS PE OR NRZI
5656 ANDN 6 #203
56JQ BRN Q5B
574B Q5A
57J2 ANDN 6 #200
583L Q5B
58H= SMO FX2
592W BXU 6 AWORK1,Q19
59GG Q5C
59H* ... FSHSKIP B,Q5D [OMIT CHEK FOR RV'S IN M/C B
59J8 ...(
59K5 ... DFJUMPS 2,NONS,Q5D
59MN ... DFLOAD 2,TSN,5 [DO NOT UNLOAD A TAPE FOR WHICH
59Q? ... FDTENT 1,5,Q5D [THERE IS AN OUTSTANDING RV
59SW ... BRN Q19
59W7 ...)
59XF ...Q5D
5=26 SETALLOC 2 [ALLOCATE DECK
5=FQ SMO A1(3)
5=^B STO 2 A1+1(3) [STORE DEVICE LIST POINTER
5?F2 #SKI K6UNLOAD>299-299
5?YL (
5#D= LGEOG 2,0
5#XW SWITRACE 0,ULDECK
5*CG )
5*X6 LDN 0 1
5BBQ ADS 0 A1(3)
5BWB BRN Q19
5CB2 Q18 LDX 6 A1(3) [NR TO BE UNLOADED
5CTL BNZ 6 Q21 [SOME DECKS UNLOADABLE
5D*= MTINFORM HUNLOAD
5DSW BRN Q29
5F#G Q21 LDN 7 0
5FS6 Q23 SMO 7
5G?Q LDX 5 A1+1(3)
5GRB UNLOAD 5,,,UNL,AUT [UNLOAD DECK
5H?2 ADN 7 1
5HQL TXU 7 6
5J== BCC Q22 [FINISHED UNLOADING
5JPW MHUNT 3,FLIB,FDECKS
5K9G BRN Q23 [NEXT
5KP6 Q22
5L8Q Q29 MFREE FLIB,FDECKS
5LNB BRN Q6
5M82 TMT 4HMT
5MML TMT1 4H*MT0
5N7= TEN +10
5NLW TNON 16HNONSTANDARD TAPE
5P6G MENDAREA 50,K99UNLOAD
5PL6 #END
^^^^ ...57647272000700000000