{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: VCLASTWO867)}}
====== VCLASTWO867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:BICE|BICE]], [[george:macro:BRUSEN|BRUSEN]], [[george:macro:COMERR|COMERR]], [[george:macro:COMERRX|COMERRX]], [[george:macro:DOWN|DOWN]], [[george:macro:FJOCA|FJOCA]], [[george:macro:FSHCODE|FSHCODE]], [[george:macro:HLSINFORM|HLSINFORM]], [[george:macro:JBCC|JBCC]], [[george:macro:LINK|LINK]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:TESTHOOK|TESTHOOK]], [[george:macro:TRACE|TRACE]], [[george:macro:WRONG|WRONG]]
224^ ... SEG VCLASTWO,,CENT(COMMAND PROCESSOR),,G400
227Y ...[
22=X ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
22*W ...[ THIS EXCLUDES CODE UNDER #SKI G262
22DT ...[ AND UNDER #SKI G334
22HS ...[ AND UNDER #SKI G336
22LR ...[ AND UNDER #SKI G550
22PQ ...[
22SP ...#OPT G262 = 0
22XN ...#SKI G262&1
232M ...# WITH UGUG EDIT M262 (WHATGENS COMMAND)
235L ...#OPT G334 = 0
238K ...#SKI G334&1
23?J ...# WITH G3UG EDIT M334 (SHUTUP COMMAND)
23BH ...#OPT G336 = 0
23FG ...#SKI G336&1
23JF ...# WITH G3UG EDIT M336 (UNJAM COMMAND)
23MD ...#OPT G550 = 0
23QC ...#SKI G550&1
23TB ...# WITH G3UG EDIT M550 (LINE PRINTER OUTPUT DIRECT TO MAGNETIC TAPE)
23WC ...#UNS G400
23XD ...# THIS CHAPTER IS MODIFIED FOR G3PLUS-IH MK2
23YG [ THE ENTRY POINTS
24D6 [ THESE ENTRY POINTS MUST BE KEPT FIXED WITHIN THE SEGMENT
24XQ SEGENTRY K1VCLASTWO,QENTRY1
25CB SEGENTRY K9VCLASTWO,QENTRY9
25X2 [
26BL [
26W= [ CAUTION! IN THIS SEGMENT, K99 DOES NOT POINT TO THE MEND AREA
27*W [
27TG [ THIS SEGMENT IS ENTERED FROM ALASB.IT CLASSIFIES A COMMAND
28*6 [ VERB AND CHECKS THAT THE COMMAND IS BEING ISSUED IN THE CORRECT
28SQ [ CONTEXT
29#B [
29S2 [
2=?L [ THE FOLLOWING TABLE IS THE BUILT IN COMMAND DICTIONARY.IT
2=R= [ CONTAINS ALL THE BUILT IN COMMANDS KNOWN TO GEORGE.EACH
2?=W [ COMMAND HAS A SEPARATE ENTRY.EACH ENTRY CONTAINS THE
2?QG [ FOLLOWING INFORMATION-
2#=6 [ THE ABBREVIATED FORM OF THE VERB
2#PQ [ THE FULL FORM OF THE VERB
2*9B [ THE CONTEXT BITS FOR THE COMMAND
2*P2 [ THE LINK PAIR TO THE COMMAND CHAPTER
2B8L #DEF SIZEBICE=BICESIZE [ NO OF WORDS IN BICE MACRO EXPANSION
2BN= SEGENTRY K90VCLASTWO [ MARKS BEGINNING OF TABLE
2C7W TABLE
2CMG +SECN
2D76 +SECO
2DLQ +SECP
2F6B +SECQ
2FL2 +SECR
2G5L +SECS
2GK= +SECT
2H4W +SECU
2HJG +SECV
2J46 +SECW
2JHQ +SECX
2K3B +SECY
2KH2 +SECZ
2KL6 [********************************************************************
2KM? ...[ COMMANDS RESERVED FOR DATASKIL - GOOSE - PSS NETWORK FACILITIES
2KND ...[ NK,NETWORK PROJECT
2KPK ...[ NZ,NETLOG
2KQQ ...[ NA,NWACCOUNT
2KRX ...[ NC,NWCONTROL
2KT4 ...[ NT,NWTAG
2KW9 ...[ NU,NWUSER
2KXG [*********************************************************************
2L2L SECN BICE NP,NEWPASSWORD,#00006,NEWPASSW,1 [NEWPASSWORD
2LG= BICE NE,NEW,#00140,LIBCOM,1 [NEW
2L^W BICE NM,NAMEPRIV,#00002,NAMEPRIV,1 [NAMEPRIV
2MFG +0
2M^6 SECO BICE OL,ONLINE,#02402,ONLINEA,1 [ONLINE
2NDQ BICE OF,OFF,#00402,ONOFFALT,2 [OFF
2NYB BICE ON,ON,#00402,ONOFFALT,1 [ON
2PD2 BICE OB,OBEY,#00002,MACRALAS,2 [OBEY
2QC= BICE OP,OPERATOR,#00062,OPERATOR,1 [OPERATOR
2QWW +0
2R2R [*****************************************************************
2R4P ...[ COMMANDS RESERVED FOR DATASKIL - GOOSE - PSS NETWORK FACILITIES
2R6M ...[ PD,PAD PROJECT
2R8K ...[ PP,PADPROFILE
2R=K [**********************************************************************
2RBG SECP BICE PT,PRINT,#00402,PRINT,1 [PRINT
2RW6 BICE PA,PAGES,#00151,PAGES,1
2S*Q BICE PR,PROPERTY,#00351,PROPERTY,1 [PROPERTY
2T*2 BICE PL,PRINTLAST,#00264,PNTLAST,1
2WRW [ COMMAND RESERVED
2X?G [ BICE PG,PAGETURNS,#00402,PTTRACE,1
2XR6 SEGENTRY K99VCLASTWO
2^=2 SEGENTRY K97VCLASTWO [TO MEND IN & OUT PATCH
2^PL BICE ??,??,#10315,PATCH,1
329= +0
32NW SECQ BICE QN,QUESTION,#40002,QUESCOM,1 [QUESTION
338G BICE QU,QUIT,#20264,QUIT,1 [QUIT
33N6 BICE QT,QUOTA,#00402,QUOTA,1 [QUOTA
34MB BICE QI,QUIET,#00264,PNTLAST,2
3572 +0
35LL SECR BICE RV,RETRIEVE,#00100,RETRIEVE,1 [RETRIEVE
366= BICE RM,RESUME,#52002,PROSTART,5
36KW BICE RP,REPORT,#00364,REPORT,7 [REPORT
375G SEGENTRY K8VCLASTWO
384Q BICE RJ,RUNJOB,#00100,INITJOB,4
39HL BICE RT,RETURN,#00002,LIBCOM,3 [RETURN
3=3= BICE RE,REALTIME,#02402,REALTIME,1 [REALTIME
3=GW BICE RL,RELEASE,#00402,RELCOM,1 [RELEASE
3?2G BICE RN,RENAME,#00002,RENAME,1 [RENAME
3?G6 BICE RD,RENAMEDIR,#00002,LIBCOM,5 [RENAMEDIR
3?^Q BICE RO,REDON,#00051,REDON,1 [REDON
3#FB BICE RI,RIGHT,#00151,RIGHT,2 [RIGHT
3#^2 BICE RS,RESTORE,#52002,LDSTART,1 [RESTORE
3*DL BICE RX,RESET,#00064,RESET,1 [RESET
3BCW BICE RR,REPERTOIRE,#00351,REPERT,1
3CC6 BICE RG,REGENERATE,#00255,REGEN,1 [REGENERATE
3CWQ +0
3DBB SECS BICE SP,SETPARAM,#00100,SETPARAM,1 [SETPARAM
3F*L BICE SC,SCHEDULE,#00255,SCHEDULE,1 [SCHEDULE
3FT= BICE SV,SAVE,#02402,SAVE,1 [SAVE
3G#W BICE SE,SECURITY,#00002,SECURE,1 [SECURITY
3GSG BICE SJ,SJMESS,#00240,SJMESS,1
3H#6 BICE SZ,SIZE,#02402,CORE,1 [SIZE
3J66 BICE SL,STOPLIST,#00040,WLA,2
3J?B BICE SK,SPEAK,#00151,SPEAK,1 [SPEAK
3JFL BICE SO,SPOOL,#00151,SPOOL,1
3JHY BICE SD,SCREENEDIT,#00006,SCEDIT,1
3JJN BICE SX,SECUREX,#00002,SECUREX,1
3JJY BICE SH,SHOW,#00251,SHOWCOMM,1 [SHOW
3JKQ ... BICE SR,SHARE,#00351,SHARE,1
3JL? ... BICE SW,SWITCH,#00041,SWITCH,1
3JLT ...#UNS G400
3JM6 ... BICE SG,SETGLOBAL,#0,GLOBALS,1
3JMC SEGENTRY K80VCLASTWO
3JNJ BICE ??,??,2,FILESECU,1
3JPB ...#SKI G334&1
3JQ8 ... BICE SU,SHUTUP,#00351,RAECOMMS,5
3JR2 +0
3K=L SECT BICE TG,TRAPGO,#00002,TRAPGO,1 [TRAPGO
3KQ= BICE TI,TIME,#00402,TIME,1 [TIME
3L9W BICE TR,TRANSPORTS,#00351,TRANSPOT,1 [TRANSPORTS
3LPG BICE TC,TRAPCHECK,#00002,TRAPGO,5 [TRAPCHECK
3M3W BICE TL,TRAPLIST,#00002,TRAPLIST,1 [ TRAPLIST
3M96 BICE TS,TRAPSTOP,#00002,TRAPGO,2 [TRAPSTOP
3MB# ...#UNS G400
3MHG ...#SKI
3MNN ... BICE TA,TRACE,#00022,TRACE,1 [TRACE
3MTW ...#UNS G400
3N34 ... BICE TA,TRACE,#00020,TRACE,1
3N8B BICE TH,TAPERIGHT,#00300,LIBCOM,8 [TAPERIGHT
3NN2 BICE TW,TAPEWRONG,#00300,LIBCOM,7 [TAPEWRONG
3P7L BICE TE,TERMINATE,#00151,TERM,1 [TERMINATE
3QLG BICE TN,TWIN,#00351,TWINSET,3 [TWIN
3QYX BICE TD,TELELOAD,#00251,IPBINC,13
3R66 +0
3R*Y SECU BICE UR,URGENCY,#00002,JOBDATA,4 [URGENCY
3S5B BICE UL,UNLOAD,#00151,UNLOAD,1
3S=J ...#SKI G336&1
3SCQ ... BICE UJ,UNJAM,#00351,RAECOMMS,10
3SK2 +0
3SQ8 ...#UNS G400
3SXB ...#SKI
3T4L SECV +0
3T79 ...#UNS G400
3T9S ...(
3T#C ...SECV BICE VC,VDUCLEAR,#00002,DOMONOP,5
3TC2 ... +0
3TFK ...)
3TJ= SECW
3W3W BICE WE,WHENEVER,#00100,WHENEVER,1 [WHENEVER
3WHG BICE WT,WAIT,#00002,WAIT,1 [WAIT
3X36 BICE WJ,WHATJOBS,#0040,WHATJBS,1 [WHATJOBS
3XYL BICE WL,WHATLIST,#00040,WLA,1 [ WHATLIST
3Y2B BICE WP,WHATPER,#00351,WHATPER,1 [WHATPER
3Y=8 ... BICE WV,WHATRVS,#00151,WHATRVS,1
3YG2 BICE WS,WHATSTATE,#00040,WHTSTAT,1 [WHATSTATE
3Y^L BICE WF,WORKFILEMOVE,#00002,WFMOVE,1 [WORKFILEMOVE
3^F= BICE WR,WRONG,#00151,RIGHT,3 [WRONG
3^MG BICE WA,WHATPROPS,#00044,WA,1 [WHATPROPS
3^XS ...#SKI G262&1
4286 ... BICE WG,WHATGENS,#00000,WHATGENS,1
42DG +0
42Y6 SECX +0
43CQ SECY +0
43XB SECZ
43Y5 ... SEGENTRY K85VCLASTWO [MEND POINT OFR ZTSPECIAL
43YS ... BICE ??,??,#00351,DATECON,60
43^K SEGENTRY K86VCLASTWO [MEND POINT FOR DATAPASS
4463 BICE ZP,ZPERFORM,0,PERFPASS,1
44*D FSHCODE AORB
44B8 BICE *F,*F,#00002,FSHTRANM,1
44BD ...#SKI G550&1
44BN ... BICE ZF,ZOFFLINE,#200402,NETOFLNE,1
44C2 SEGENTRY K98VCLASTWO [ END OF TABLE
44WL #REP 8
45B= +0
45TW [
46*G [
46T6 QENTRY1
47#Q LDCH 3 AWORK2(2) [GET 1ST CHAR OF VERB
47SB SBN 3 #56
48#2 SMO FX1
48RL LDX 7 TABLE(3) [LOAD ADDRES_F APPROPRIATE PART
49?= [OF DICTIONARY
49QW M5 SMO 7
4==G LDX 6 0(1) [LOAD 1ST WORD
4=Q6 BZE 6 UNCLASVB [J IF NO SUCH VERB
4?9Q LDX 4 AWORK1(2) [GET COUNT OF CHARS IN VERB
4?PB TXL 4 THREE(1)
4#92 BCS M1 [J IF ABBREV. FORM OF VERB
4#NL LDN 0 0 [SET VERB MOD ZERO
4*8= M4 ADN 7 1 [SET TAB MOD TO FULL FORM OF VERB
4*MW SMO 7
4B7G LDX 6 0(1) [LOAD NEXT WORD
4BM6 SMO 0
4C6Q TXU 6 AWORK2(2) [COMPARE AGAINST VERB
4CLB BCS M2 [J IF UNEQUAL
4D62 TXU 0 TWO(1) [J IF CORRECT
4DKL BCC M3 [VERB HAS BEEN FOUND
4F5= ADN 0 1 [UPDATE VERB MOD.
4FJW BRN M4 [TRY NEXT PART OF VERB
4G4G M2 SBX 7 0 [ SET DICTIONARY MOD TO PT
4GJ6 ADN 7 SIZEBICE-1 [ TO NEXT ENTRY
4H3Q BRN M5
4HHB M1 ERX 6 AWORK2(2)
4J32 BZE 6 M7 [J IF SHORT FORM FOUND
4JGL ADN 7 SIZEBICE [ SET POINTER TO NEXT VERB
4K2= BRN M5
4KFW M7 ADN 7 3
4K^G M3 SMO 7
4LF6 LDX 5 1(1)
4LYQ LDX 6 CONTEXT(2)
4MDB ANDX 6 MASKCONT(1)
4MY2 ANDX 6 5
4NCL ADN 7 2(1) [UPDATE X7 TO PT TO LINK PAIR
4NMD LDN 0 EXT+4(2)
4PBW MOVE 7 HLINK [ MOVE LINK INTO CPAT ACTIVITY BLOCK
4PWG SBN 7 SIZEBICE-HLINK
4Q58 SMO 7
4Q?W LDX 0 0
4QGJ SRL 0 12
4QKW STO 0 EXT+3(2)
4QXY ANDX 5 MASKPRIV(1)
4R3= ORS 5 EXT+3(2)
4R*B LDN 7 2
4RT2 ANDX 7 CONTEXT(2)
4S#L BNZ 7 P1 [ JUMP IF NO-USER
4T?W ANDX 5 ICONTEXT
4TRG BZE 5 P1 [J IF PRIVILEGE NOT REQUIRED
4TYN ...#UNS G400
4W5W ... TESTHOOK P1 [DON'T CHECK PRIVS IN A HOOK
4W?6 FJOCA 3,2
4WQQ LDX 7 JPRIV(3)
4X=B ANDX 7 5
4XQ2 ERX 7 5
4Y9L BZE 7 P1 [J IF USER HAS REQUIRED PRIVILEGE
4YP= COMERR ANOPRIV
4^8W P1
4^NG BNZ 6 NOTC [J IF CONTEXT ERROR OR JOB NEEDS TO
5286 [BE F.STARTED
52*? TST JBCC TSTX,2,EXFULLY
52C2 BRUSEN TSTX,2
52DP DOWN HLSEVENT,2 [OUTPUT FULLY ST'ED MESSAGES
52GD TSTX ACROSS ALASB,2
537B UNCLASVB
53#J ...#UNS G400
53FQ ... TESTHOOK XHOOK [MACROS OK IN HOOK,MOP & NO-USER CONT
53M2 SMO FX2
546L LDX 0 CONTEXT
54L= ANDN 0 #12
555W ERN 0 #12
55KG BZE 0 WRONG [J IF MOP AND NO-USER BITS SET
55QN ...#UNS G400
55XW ...XHOOK
5656 ACROSS MACRALAS,1
56JQ WRONG
574B LDX 5 TJOBIC(1) [LOAD MESSAGE IDENTIFIER
57J2 NGN 4 1 [NO SUB MESSAGE
583L BRN PCOMP2
58H= [ THIS SECTION DETERMINES THE CONTEXTUAL ERROR THAT HAS
592W [ OCCURRED AND OUTPUTS THE APPROPRIATE ERROR MESSAGE
59GG NOTC
5=26 LDN 7 0 [ZEROISE X7
5=FQ LDN 3 15 [COUNT OF NO OF OF CONTEXT BITS.
5=^B PC SRL 67 1
5?F2 BNG 7 PCOMP [JUMP IF THIS BIT IN ERROR
5?YL TNT BCT 3 PC
5#6D HLSINFORM SAVEABLE,FSTART,JOBNO(2),EXT+3(2),,,XFSLINK(1)
5#8B BRN TST
5*==
5*CG PHIVE +5
5*X6 PCOMP TXU 3 PHIVE(1)
5BBQ BCC TNT
5BWB PCOMP1
5CB2 SMO 3
5CTL LDX 4 PCOMPLIS-1(1)
5D*= LDX 5 TJCONTINC(1)
5DSW PCOMP2
5F#G TRACE 4,CONTEXT
5FS6 MHUNTW 2,CLB
5G?Q STOZ CLBPTNECHA(2)
5GRB COMERRX 5,4 [COMMAND ERROR
5H?2 [ THE FOLLOWING TABLE IS A LIST OF THE UNIVERSAL IDENTIFIERS
5HQL [ LABELLING SUB-MESSAGES IN THE MONITORING FILE SEGMENTS WHICH
5J== [ ARE USED BY THE COMERR MACRO TO INDICATE THE TYPE OF CONTEXTUAL
5JPW [ ERROR THAT HAS OCCURRED
5K9G PCOMPLIS
5KP6 +JBREAK
5L8Q +JNOBREAK
5LNB +JPROGISH
5M82 +JFULL
5MML +JTENT
5N7= +JCOR
5NLW +JNOCOR
5P6G +JREM
5PL6 +JATT
5Q5Q +JPTCR
5QKB +JOPCON
5R52 +JMOPCON
5RJL +JJDF
5S4= +JDIR
5SHW +JCOM
5T3G TJOBIC +JOBIC ['ONLY BUILT-IN COMMANDS ALL.'-MESS
5TH6 TJCONTINC +JCONTINC
5W2Q TWO +2
5WGB THREE +3
5X22 MASKCONT #77777
5XFL MASKPRIV #700000
5XPC XFSLINK
5XS2 LINK ALASB,21
5YDW QENTRY9 COMERR INCDUMP
5YYG MENDAREA 30
5^D6 #END
^^^^ ...637232120006