{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: VERBCLAS867)}}
====== VERBCLAS867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:BICE|BICE]], [[george:macro:BRUSEN|BRUSEN]], [[george:macro:COMERR|COMERR]], [[george:macro:COMERRX|COMERRX]], [[george:macro:DOWN|DOWN]], [[george:macro:FJOCA|FJOCA]], [[george:macro:FSHCODE|FSHCODE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HLSINFORM|HLSINFORM]], [[george:macro:JBCC|JBCC]], [[george:macro:LINK|LINK]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:TESTHOOK|TESTHOOK]], [[george:macro:TRACE|TRACE]], [[george:macro:WRONG|WRONG]]
225? ... SEG VERBCLAS,,CENT(COMMAND PROCESSOR),,G400
228J ...[
22?T ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
22C6 ...[ THIS EXCLUDES CODE UNDER #SKI G253
22GC ...[ AND UNDER #SKI G263
22KN ...[ AND UNDER #SKI G268
22N^ ...[
22S= ...#OPT G253 = 0
22XH ...#SKI G253&1
232S ...# WITH UGUG EDIT M253 (LISTFILE IN NO-USER CONTEXT)
2365 ...#OPT G263 = 0
239B ...#SKI G263&1
23#M ...# WITH UGUG EDIT M263 (HOWBIG COMMAND)
23CY ...#OPT G268 = 0
23H9 ...#SKI G268&1
23LG ...# WITH UGUG EDIT M268 (CHUCKOFF COMMAND)
23PR ...#UNS G400
23T4 ...# THIS CHAPTER IS MODIFIED FOR G3PLUS-IH MK2
23YG [ THE ENTRY POINTS
24D6 [ THESE ENTRY POINTS MUST BE KEPT FIXED WITHIN THE SEGMENT
24XQ SEGENTRY K1VERBCLAS,QENTRY1
25CB SEGENTRY K2VERBCLAS,QENTRY2
25X2 [
26BL [
26W= [ THIS SEGMENT IS ENTERED FROM ALASB.IT CLASSIFIES A COMMAND
27*W [ VERB AND CHECKS THAT THE COMMAND IS BEING ISSUED IN THE CORRECT
27TG [ CONTEXT
28*6 [
28SQ [
29#B [ THE FOLLOWING TABLE IS THE BUILT IN COMMAND DICTIONARY.IT
29S2 [ CONTAINS ALL THE BUILT IN COMMANDS KNOWN TO GEORGE.EACH
2=?L [ COMMAND HAS A SEPARATE ENTRY.EACH ENTRY CONTAINS THE
2=R= [ FOLLOWING INFORMATION-
2?=W [ THE ABBREVIATED FORM OF THE VERB
2?QG [ THE FULL FORM OF THE VERB
2#=6 [ THE CONTEXT BITS FOR THE COMMAND
2#PQ [ THE LINK PAIR TO THE COMMAND CHAPTER
2*9B #DEF SIZEBICE=BICESIZE [ NO OF WORDS IN BICE MACRO EXPANSION
2*P2 SEGENTRY K90VERBCLAS [ MARKS BEGINNING OF TABLE
2B8L TABLE +SECA
2BN= +SECB
2C7W +SECC
2CMG +SECD
2D76 +SECE
2DLQ +SECF
2F6B +SECG
2FL2 +SECH
2G5L +SECI
2GK= +SECJ
2H4W +SECK
2HJG +SECL
2J46 +SECM
2JHQ SECA BICE AS,ASSIGN,#02402,ASSIGN,1 [ASSIGN
2K3B BICE AL,ALTER,#00402,ONOFFALT,3 [ALTER
2K?8 BICE AB,ABANDON,#00140,ABANDONA,1
2L2L BICE AW,ALLOWANCE,#00002,ALLOW,1 [ALLOWANCE
2LG= BICE AN,ANSWER,#10104,ANSCOM,1
2L^W BICE AO,ALLOCATE,#00340,ALLOCATE,1 [ALLOCAG
2MFG BICE AC,ACCESS,#00402,ACCESS,1 [ACCESS
2M^6 BICE AH,ATTACH,#40144,ATTACHA,1 [ATTACH
2N*W BICE AU,ATTRIBUTE,#00140,ATTRIBUT,1
2NG6 BICE AE,ASSOCIATE,#00340,ASSOC,1
2PD2 BICE AR,ARCHIVE,#00002,ARCHIVE,1 [ARCHIVE
2PMR SEGENTRY K80VERBCLAS
2PQB BICE ??,??,2,FILESECU,2
2PW? BICE 1*,1LLOWMIDN,#0255,DATECON,52
2PXL +0
2QC= SECB BICE BT,BUDGET,#00002,BUDGET,1 [BUDGET
2QWW BICE BQ,BUDGETQUERY,#00002,BQUERY,1 [BUDGETQUERY
2RBG BICE BR,BRACKETS,#00300,GOTO,4 [BRACKETS
2RW6 BICE BC,BROADCAST,#00351,BCAST,1 [BROADCAST
2S*Q +0
2T*2 SECC BICE CY,COPY,#00002,COPYA,1 [COPY
2WRW BICE CE,CREATE,#02002,CREATE,1 [CREATE
2X?G BICE CU,CONTINUE,#20264,CONTINUE,1 [CONTINUE
2XR6 BICE CO,CORE,#12402,CORE,1 [CORE
2Y=Q BICE CN,CONNECT,#41364,CONNECT,1 [CONNECT
2YQB BICE CD,CANTDO,#00151,CANTDO,1 [CANTDO
2^=2 BICE CC,CANCEL,#00100,CANCOM,1 [CANCEL
32HL BICE CH,CHANGELIST,#00040,WLA,3
32NW BICE CL,CONCEPTUAL,#00351,CONCEPT,1 [CONCEPTUAL
338G BICE CG,CARTRIDGE,#00151,MOVCART,1 [CARTRIDGE
33N6 ...#SKI G268&1
347Q ... BICE CK,CHUCKOFF,#00002,ARCHIVE,3
366= +0
36?D ...#UNS G400
36DL ...#SKI
36KW SECD BICE DP,DISPLAY,#00002,DISPCOM,1 [DISPLAY
36R4 ...#UNS G400
36Y= ...SECD BICE DP,DISPLAY,#00000,DISPCOM,1
375G BICE DM,DOCU,#00331,DOC,1 [DOCUMENT
37K6 BICE DM,DOCUMENT,#00331,DOC,1 [DOCUMENT
384Q BICE DG,DISENGAGE,#00131,ENGAGE,30 [DISENGAGE
38JB BICE DL,DELETE,#10402,DELCOM,1 [DELETE
3942 BICE DY,DIRECTORY,#00002,LISTDIR,3 [DIRECTORY
39HL BICE DD,DEAD,#00100,LIBCOM,4 [DEAD
3=GW BICE DC,DISCONNECT,#20006,DSCNCT,1
3?^Q BICE DU,DUMP,#00351,DUMP,1 [DUMP
3#FB BICE DH,DETACH,#00402,DETACH,1
3#^2 #SKI ADEVELOP
3*DL BICE DV,DEVICELIST,#00012,LISTDEV,1
3*Y= +0
3BCW SECE BICE ER,ERASE,#00002,ERASE,1 [ERASE
3BXG BICE EN,ENTER,#52402,PROSTART,2 [ENTER
3CC6 BICE EJ,END,#10012,LOGOUT,2 [ENDJOB
3CWQ BICE EJ,ENDJOB,#10012,LOGOUT,2 [ENDJOB
3DBB BICE ED,EDIT,#00002,EDIT,1 [EDIT
3DJ9 ...#UNS G400
3DQ4 ...(
3DXX ... BICE EC,EXTRACODE,#00000,DOXCODE,1 [EXTRACODE
3F5Q ... BICE EX,EXIT,#00000,GOTO,30 [EXIT (G3PLUS-IH)
3F?K ...)
3FFD ...#UNS G400
3FM? ...#SKI
3FT= BICE EX,EXIT,#00000,GOTO,3 [EXIT
3G#W BICE EP,EXPRESS,#355,EXPRESS,1
3GSG BICE ET,ENTRUST,#00402,ENTRUST,1 [ENTRUST
3H#6 +0
3HRQ SECF BICE FA,FAIL,#10402,FAIL,1 [FAIL
3J?B BICE FN,FINISH,#00351,FINISH,1 [FINISH
3JH8 BICE FP,FORCEPAGE,#351,SHOWCOMM,5 [FORCE PAGE
3JKR #UNS AV7900R
3JNB BICE FR,FREE,#40044,VIPBFREE,1 [FREE - V7900
3JR2 BICE FT,FULLTRACE,#00022,TRACE,2 [FULLTRACE
3K5B BICE FZ,FREEZE,2,FREEZE,1
3L9W +0
3LPG SECG BICE GO,GOTO,#00000,GOTO,1 [GOTO
3M96 BICE GE,GET,#00002,LIBCOM,2 [GET
3MNQ BICE GL,GETONLINE,#00402,GETON,1 [GETONLINE
3P7L #SKI JDIAG1
3PM= BICE GD,GEDIT,#002,EDIT,2 [ GEDIT
3Q6W +0
3QLG SECH BICE HT,HALT,#10402,HALT,1 [HALT
3R66 BICE HW,HARDWARE,#00351,HARDWARA,1 [HARDWARE
3RDG BICE HO,HOLD,#00351,HOLDCOM,1 [HOLD
3RG= ...#SKI G263&1
3RJ2 ... BICE HB,HOWBIG,#00000,HOWBIG,1
3RKQ +0
3S5B SECI
3SK2 BICE IF,IF,#00100,IFEXPAN,1 [IF
3T4L BICE IN,INPUT,#00120,PREPREAD,1 [INPUT
3TJ= BICE IP,INSTPARA,#00311,INSTPARA,1 [INSTPARA
3W3W BICE ID,INCDUMP,#00002,INCOM,1 [INCDUMP
3W?N ... BICE IJ,IPBJOURN,#00151,IPBJOURN,1
3WHG +0
3X36 SECJ
3XGQ SEGENTRY K7VERBCLAS
3YG2 BICE JB,JOB,#40121,INITJOB,3
3^YW BICE JD,JOBDATA,#00002,JOBDATA,1 [JOBDATA
42DG BICE JT,JOBTIME,#00002,JOBDATA,2 [JOBTIME
42Y6 +0
43CQ SECK +0
43XB SECL
44C2 BICE LO,LOAD,#52002,LDSTART,1 [LOAD
44J8 #UNS ADMELI
44PB BICE LC,LINECONTROL,#00351,LINECTRL,1
44R6 ...#UNS G253
44SW ...#SKI
44WL BICE LF,LISTFILE,#00002,LISTFILE,1 [LISTFILE
4593 ...#UNS G253
45HD ... BICE LF,LISTFILE,#00000,LISTFILE,1
45TW BICE LN,LOGIN,#40361,INITJOB,2
47#Q BICE LT,LOGOUT,#50006,LOGOUT,1 [LOGOUT
47SB BICE LD,LISTDIR,#00002,LISTDIR,1 [LISTDIR
48#2 BICE LI,LISTIDF,#00012,LISTSTAR,1 [LISTIDF
48RL BICE LE,LOADENTER,#52002,LDSTART,2 [LOADENTER
49?= BICE LB,LABEL,#00351,LABEL,1 [LABEL
49KM BICE LA,LOGACCESS,#00002,LOGCOM,1 [LOGACCESS
49MB FSHCODE AORB
49P5 BICE LK,LINK,#00351,FSHTRANB,1 [LINK
49PN ...#SKI G253&1
49Q? ... BICE LL,LIST,0,LIST,1
49QW +0
4==G SECM BICE MD,MACDEF,#00002,MACDEF,1 [MACDEF
4=G# BICE MI,MILL,#00351,CMEMILL,1
4=Q6 BICE MZ,MAXSIZE,#00002,CORE,2
4?9Q BICE MK,MAKEDIR,#00002,MAKEDIR,1 [MAKEDIR
4?PB BICE MN,MONITOR,#00402,MONITOR,1 [MONITOR
4#92 BICE MP,MOP,#00351,MOPCOM,1 [MOP
4#NL BICE MO,MODE,#00300,MODE,1 [MODE
4*8= BICE MR,MONRESUME,#52402,MONRESUM,1 [MONRESUME
4B7G BICE MQ,MAXQUOTA,#00002,CORE,3
4BM6 #UNS AV7900S
4C6Q BICE MV,MAKEVCC,#00351,MAKEVCC,1 [MAKEVCC
4CW7 SEGENTRY K81VERBCLAS
4CYQ BICE ??,??,2,PNTLAST,6
4D62 +0
4DKL [
4F5= [
4FJW QENTRY1
4G4G LDCH 3 AWORK2(2) [GET 1ST CHAR OF VERB
4GJ6 SBN 3 #41
4H3Q SMO FX1
4HHB LDX 7 TABLE(3) [LOAD ADDRES_F APPROPRIATE PART
4J32 [OF DICTIONARY
4JGL M5 SMO 7
4K2= LDX 6 0(1) [LOAD 1ST WORD
4KFW BZE 6 UNCLASVB [J IF NO SUCH VERB
4K^G LDX 4 AWORK1(2) [GET COUNT OF CHARS IN VERB
4LF6 TXL 4 THREE(1)
4LYQ BCS M1 [J IF ABBREV. FORM OF VERB
4MDB LDN 0 0 [SET VERB MOD ZERO
4MY2 M4 ADN 7 1 [SET TAB MOD TO FULL FORM OF VERB
4NCL SMO 7
4NX= LDX 6 0(1) [LOAD NEXT WORD
4PBW SMO 0
4PWG TXU 6 AWORK2(2) [COMPARE AGAINST VERB
4QB6 BCS M2 [J IF UNEQUAL
4QTQ TXU 0 TWO(1) [J IF CORRECT
4R*B BCC M3 [VERB HAS BEEN FOUND
4RT2 ADN 0 1 [UPDATE VERB MOD.
4S#L BRN M4 [TRY NEXT PART OF VERB
4SS= M2 SBX 7 0 [ SET DICTIONARY MOD TO PT
4T?W ADN 7 SIZEBICE-1 [ TO NEXT ENTRY
4TRG BRN M5
4W?6 M1 ERX 6 AWORK2(2)
4WQQ BZE 6 M7 [J IF SHORT FORM FOUND
4X=B ADN 7 SIZEBICE [ SET POINTER TO NEXT VERB
4XQ2 BRN M5
4Y9L M7 ADN 7 3
4YP= M3 SMO 7
4^8W LDX 5 1(1) [GET CONTEXT BITS FROM VERB DICT.
4^NG LDX 6 CONTEXT(2)
5286 ANDX 6 MASKCONT(1) [ISOLATE 15 CONTEXT BITS
52MQ ANDX 6 5
537B ADN 7 2(1) [UPDATE X7 TO PT TO LINK PAIR
53C8 LDN 0 EXT+4(2)
546L MOVE 7 HLINK [ MOVE LINK INTO CPAT ACTIVITY BLOCK
54L= SBN 7 SIZEBICE-HLINK
54SY SMO 7
553L LDX 0 0
55=# SRL 0 12
55*L STO 0 EXT+3(2)
55MN ANDX 5 MASKPRIV(1) [ISOLATE PRIV BITS
55R2 ORS 5 EXT+3(2)
5656 LDN 7 2
56JQ ANDX 7 CONTEXT(2)
574B BNZ 7 P1 [ JUMP IF NO-USER
583L ANDX 5 ICONTEXT
58H= BZE 5 P1 [J IF PRIVILEGE NOT REQUIRED
58ND ...#UNS G400
58TL ... TESTHOOK P1 [DON'T CHECK PRIVS IN A HOOK
592W FJOCA 3,2 [FIND CURRENT JOBBLOCK
59GG LDX 7 JPRIV(3)
5=26 ANDX 7 5
5=FQ ERX 7 5
5=^B BZE 7 P1 [J IF USER HAS REQUIRED PRIVILEGE
5?F2 COMERR ANOPRIV
5?YL P1
5#D= BNZ 6 NOTC [J IF CONTEXT ERROR OR JOB NEEDS TO
5#XW [BE F.STARTED
5*53 TST JBCC TSTX,2,EXFULLY
5*6Q BRUSEN TSTX,2
5*8F DOWN HLSEVENT,2 [OUTPUT FULLY ST'ED MESSAGES
5*=8 TSTX ACROSS ALASB,2
5*X6 UNCLASVB
5B4# ...#UNS G400
5B9G ... TESTHOOK XHOOK [MACROS OK IN HOOK,MOP & NO-USER CONT
5BBQ SMO FX2
5BWB LDX 0 CONTEXT
5CB2 ANDN 0 #12
5CTL ERN 0 #12
5D*= BZE 0 WRONG [J IF MOP AND NO-USER BITS SET
5DGD ...#UNS G400
5DML ...XHOOK
5DSW ACROSS MACRALAS,1
5F#G WRONG
5FS6 LDX 5 TJOBIC(1) [LOAD MESSAGE IDENTIFIER
5G?Q NGN 4 1 [NO SUB-MESSAGE
5GRB BRN PCOMP2
5H?2 [ THIS SECTION DETERMINES THE CONTEXTUAL ERROR THAT HAS
5HQL [ OCCURRED AND OUTPUTS THE APPROPRIATE ERROR MESSAGE
5J== NOTC
5JPW LDN 7 0 [ZEROISE X7
5K9G LDN 3 15 [COUNT OF NO OF OF CONTEXT BITS.
5KP6 PC SRL 67 1
5L8Q BNG 7 PCOMP [JUMP IF THIS BIT IN ERROR
5LNB TNT BCT 3 PC
5LRY SEGENTRY K82VERBCLAS
5LT6 LDN 0 0
5LW# ANDN 0 #10
5LXG BZE 0 XFULL
5LY4 LDX 0 EXT+3(2)
5L^W ANDN 0 #7777
5M34 ERN 0 #4345
5M4= BZE 0 TST
5M5D XFULL
5M75 HLSINFORM SAVEABLE,FSTART,JOBNO(2),EXT+3(2),,,XFSLINK(1)
5M7= BRN TST
5M7C )
5N22 )
5N7= PHIVE +5
5NLW PCOMP TXU 3 PHIVE(1)
5P6G BCC TNT
5PL6 PCOMP1
5Q5Q SMO 3
5QKB LDX 4 PCOMPLIS-1(1)
5R52 LDX 5 TJCONTINC(1)
5RJL PCOMP2
5S4= TRACE 4,CONTEXT
5SHW MHUNTW 2,CLB
5T3G STOZ CLBPTNECHA(2)
5TH6 COMERRX 5,4 [COMMAND ERROR
5W2Q [ THE FOLLOWING TABLE IS A LIST OF THE UNIVERSAL IDENTIFIERS
5WGB [ LABELLING SUB-MESSAGES IN THE MONITORING FILE SEGMENTS WHICH
5X22 [ ARE USED BY THE COMERR MACRO TO INDICATE THE TYPE OF CONTEXTUAL
5XFL [ ERROR THAT HAS OCCURRED
5X^= PCOMPLIS
5YDW +JBREAK
5YYG +JNOBREAK
5^D6 +JPROGISH
5^XQ +JFULL
62CB +JTENT
62X2 +JCOR
63BL +JNOCOR
63W= +JREM
64*W +JATT
64TG +JPTCR
65*6 +JOPCON
65SQ +JMOPCON
66#B +JJDF
66S2 +JDIR
67?L +JCOM
67R= TJOBIC +JOBIC ['ONLY BUILT-IN COMMANDS ALL.'-MESS.
68=W TJCONTINC +JCONTINC
68QG TWO +2
69=6 THREE +3
69PQ MASKCONT #77777
6=9B MASKPRIV #700000
6=F7 XFSLINK
6=HQ LINK ALASB,21
6=P2 [
6?8L QENTRY2
6C5L GEOERR 1,ADEVELOP
6CK= MENDAREA 30,K99VERBCLAS
6D4W #END
^^^^ ...1066402700030000000