{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: WHATJBS867)}}
====== WHATJBS867 ======
(George Source)
**Macros used:** [[george:macro:ABANDCOM|ABANDCOM]], [[george:macro:BRUSEN|BRUSEN]], [[george:macro:COMERR|COMERR]], [[george:macro:DOWN|DOWN]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:HUNTMISB|HUNTMISB]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUT|MONOUT]], [[george:macro:OUTBLOCN|OUTBLOCN]], [[george:macro:OUTMESS|OUTMESS]], [[george:macro:OUTMESSX|OUTMESSX]], [[george:macro:OUTNUM|OUTNUM]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:TESTRACE|TESTRACE]]
22^= #LIS K0WHATJBS>K0ALLGEO>K0GREATGEO>K0COMMAND
23DW ... SEG WHATJBS,867,SECTION CENT
23YG [
244C ...[
248# ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
24#9 ...[
24D6 [ THIS SEGMENT OUTPUTS THE COUNTS OF
24XQ [ BACKGROUND AND MOP JOBS IN THE SYSTEM
25CB [
25X2 SEGENTRY K1WHATJBS,Q1ENTRY
2648 FSHENTRY K2WHATJBS,Q2ENTRY,,Q2ENTRY
269B FSHENTRY K3WHATJBS,Q3ENTRY,,Q3ENTRY
26BL [ DEFINES THE CQPRINT/CQ1 BLOCK
26W= #DEF ZGA = A1 [GROUP A INDICATORS
27*W #DEF ZGB = ZGA+1 [GROUP B INDICATORS
27TG #DEF ZGC = ZGB+1 [GROUP C INDICATORS
28*6 #DEF ZGD = ZGC+1 [GROUP D INDICATORS
28SQ #DEF ZGE = ZGD+1 [GROUP E INDICATORS
29#B #DEF ZGF = ZGE+1 [GROUP F INDICATORS
29S2 #DEF ZGG = ZGF+1 [GROUP G INDICATORS
2=?L #DEF ZJCOUNT = ZGG [ JOB COUNTS FROM WSJOBS
2=R= #DEF ZNAME = ZJCOUNT+2 [JOB NAME
2?=W #DEF ZUSER = ZNAME+3 [USER NAME
2?QG #DEF ZPROP = ZUSER+3 [PROPERTY NUMBER
2#=6 #DEF ZLCOUNT= ZPROP+1 [COUNT OF JOB NOS. STORED
2#PQ #DEF ZLJOB = ZLCOUNT+1 [JOB NUMBER
2*9B [
2*P2 WJJOBC +AWJMOP
2B8L +AWJBACK
2BN= SYSIND #03000400 [SYS IND SET UP BY WSPARAM
2C7W SELDF #20000000 [DEFAULT=STARTED JOB
2CMG XALL #60000200
2D76 Q1ENTRY
2DLQ MHUNT 3,CPB,CALAS
2F6B LDX 0 APARAFIR(3)
2FL2 ADN 0 1
2G5L BNZ 0 PARA [J IF PARAMETERS PRESENT
2GK= LDX 4 SELDF(1) [GROUP B INDICATOR (ST)
2H4W STO 4 AWORK1(2) [NO PARAMETER INDICATOR
2HJG LDN 5 0 [GROUP C
2J46 LDN 6 0 [GROUP E
2JHQ BRN QUIK [J TO EXAMINE JWELL
2K3B PARA
2KH2 [ GET SELECTION PARAMETERS
2L2L LDX 0 GSIGN [SET 'WJ' MARKER
2LG= STO 0 ACOMMUNE1(2)
2L^W DOWN WSPARAM,1 [SET UP CQPRINT-CQ1
2MFG BRN OUT9
2M^6 BRN XBRK [BREAK IN
2NDQ MHUNTW 3,CQPRINT,CQ1
2NYB LDX 4 ZGA(3) [GROUP SELECTION INDICATORS
2PD2 SLL 4 1
2PXL STO 4 AWORK1(2) [PARAMETER INDICATORS
2QC= LDX 0 ZGF(3)
2QWW BNZ 0 SLOW [J IF INFO. NOT IN JWELL
2RBG LDX 0 ZGD(3)
2RW6 BNZ 0 SLOW [J IF INFO. NOT IN JWELL
2S*Q LDX 0 ZGC(3)
2STB BNZ 0 SLOW [IF ANY GROUP C PRESENT JWELL MAY
2T*2 [NOT BE UP TO DATE 'COS OF USER ATTRIBUTIONS
2TSL LDX 4 ZGB(3)
2W#= SLL 4 7 [GROUP B
2WRW LDX 6 ZGE(3)
2X?G SLL 6 10 [GROUP E
2XR6 LDX 0 ZPROP(3)
2Y=Q STO 0 AWORK2(2) [PR PARAMETER
2YQB QUIK
2^=2 [ LOOK AT THIRD/NEXT ENTRY IN JWELL
2^PL [ IE. START OF MUTUAL EXCL. JOB TYPES
329= HUNTMISB 3,JWELL
32NW STOZ ACOMMUNE1(2) [MOP COUNT
338G STOZ ACOMMUNE2(2) [BACK COUNT
33N6 LDN 3 JOBENTS+JWENTRY(3) [X3 FIRST ENTRY IN JWELL
347Q QUIK2 ADN 3 JWENTRY [X3 NEXT ENTRY IN JWELL
34MB QUIK4 LDX 0 JOBTYPE(3)
3572 BNG 0 OUT [J IF NO MORE ENTRIES
35LL TOT
366= [ ACCUMULATE JOB COUNTS
36KW BZE 6 TOT3 [J IF MOP&BACK INCLUDED
375G LDN 0 JWMOPB
37K6 ANDX 0 JOBTYPE(3)
384Q BPZ 6 TOT2 [J IF NO MOP CHECK REQ'D
38JB BZE 0 QUIK2 [J IF NOT MOP
3942 BRN TOT3
39HL TOT2 BNZ 0 QUIK2 [J IF NOT BACK
3=3= TOT3 LDN 7 0
3GSG LDCT 0 #200
3H#6 ANDX 0 4
3HRQ BZE 0 TOT6 [J IF LIVE JOBS NOT INCLUDED
3J?B LDEX 7 JOBCTS(3) [SUBCOUNT=LIVE JOBS
3JR2 TOT6 BPZ 4 TOT65 [J IF WELL JOBS NOT INCLUDED
3K=L LDX 0 JOBCTS(3)
3KQ= SRL 0 9
3L9W ADX 7 0 [ADD WELL JOBS TO SUBCOUNT
3LPG TOT65 LDN 0 #200
3M96 ANDX 0 4
3MNQ BZE 0 TOT7 [J IF DEGEN JOBS NOT INCL.
3N8B ADX 7 JWDEG(3) [COUNT OF DEGEN. JOBS
3NN2 TOT7 LDN 0 JWMOPB
3P7L ANDX 0 JOBTYPE(3)
3PM= BZE 0 TOT8 [J IF BACKGROUND JOB
3Q6W ADS 7 ACOMMUNE1(2) [UPDATE MOP COUNT
3QLG BRN QUIK2
3R66 TOT8 ADS 7 ACOMMUNE2(2) [UPDATE BACK COUNT
3RKQ BRN QUIK2
3S5B SLOW
3SK2 [ GET JOB COUNTS FROM JOBQ/HLSQ/JOBLIST
3T4L LDX 0 GSIGN
3TJ= STO 0 ACOMMUNE1(2)
3W3W DOWN WSJOBS,1 [ACOMMUNE1 HOLDS MOP COUNT
3WHG [ACOMMUNE2 HOLDS BACK COUNT
3X36 BRN OUT9 [ERROR
3XGQ BRN XBRK [BREAK IN
3Y2B MHUNTW 3,CQPRINT,CQ1
3YG2 LDN 6 ZJCOUNT(3)
3Y^L LDN 7 ACOMMUNE1(2)
3^F= MOVE 6 2 [GET COUNTS
3^LD OUT BRUSEN NOUSER
3^RL LDN 4 #40
3^YS TESTRACE 4,NOUTPUT
4262 NOUSER
42?8 LDX 0 ACOMMUNE1(2) [MOP COUNT
42DG ADX 0 ACOMMUNE2(2) [BACK COUNT
42Y6 BZE 0 OUT10 [J IF COUNTS ARE ZERO
43CQ [ O/P COUNTS
43XB OUTBLOCN 28 [SET UP PARAMETER BLOCK
44C2 NGN 7 1
44WL OUT2 ADN 7 1
45B= SMO 7
45TW LDX 6 ACOMMUNE1(2)
46*G BZE 6 OUT3 [J IF ZERO COUNT
46T6 OUTNUM 6,0 [O/P COUNT(MOP/BACK)
47#Q ADX 1 7
47SB OUTMESSX WJJOBC(1) [O/P MOP JOBS/BACK JOBS
48#2 OUT3 BZE 7 OUT2 [J IF BACK CNT NOT YET O/P
48RL OUT4 LDX 6 AWORK1(2)
49?= SRL 6 1
49QW STO 6 ACOMMUNE6(2) [SELECTION DETAILS FOR WSPARAM
4==G DOWN WSPARAM,2 [OUTPARAM SELECTION DETAILS
4=BJ OUT8
4=YT MONOUT AWJCOUNT
4?2W OUT9
4?H6 ENDCOM
4?PB OUT10
4#92 [ O/P 'NO JOBS' MESSAGE
4#NL OUTMESS AWJNJOB2 [NO SUCH JOBS
4*8= BRN OUT4
4*#2 XBRK
4*R2 ABANDCOM
4*T4 NOUTPUT
4B2= COMERR JMTRACE
4B7G #END
^^^^ ...164147170001