{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: WHATPERB867)}}
====== WHATPERB867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:BITDEFS|BITDEFS]], [[george:macro:COMERRX|COMERRX]], [[george:macro:CONSERNO|CONSERNO]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FIELDDEF|FIELDDEF]], [[george:macro:FINDEXOF|FINDEXOF]], [[george:macro:FINDSU|FINDSU]], [[george:macro:FLENME1|FLENME1]], [[george:macro:FON|FON]], [[george:macro:HUNTW|HUNTW]], [[george:macro:JALLOC|JALLOC]], [[george:macro:JBC|JBC]], [[george:macro:JBS|JBS]], [[george:macro:JENG|JENG]], [[george:macro:JENVNOT|JENVNOT]], [[george:macro:JFAIL|JFAIL]], [[george:macro:JHOLD|JHOLD]], [[george:macro:JNCMESH|JNCMESH]], [[george:macro:JONL|JONL]], [[george:macro:JSWOUT|JSWOUT]], [[george:macro:JTWIN|JTWIN]], [[george:macro:JWRONG|JWRONG]], [[george:macro:LF|LF]], [[george:macro:LGEOG|LGEOG]], [[george:macro:LINECTRL|LINECTRL]], [[george:macro:LJOBNO|LJOBNO]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUT|MONOUT]], [[george:macro:MONOUTX|MONOUTX]], [[george:macro:MOPSTATE|MOPSTATE]], [[george:macro:OFF|OFF]], [[george:macro:ON|ON]], [[george:macro:OUTBLOCN|OUTBLOCN]], [[george:macro:OUTMESS|OUTMESS]], [[george:macro:OUTMESSX|OUTMESSX]], [[george:macro:OUTNULL|OUTNULL]], [[george:macro:OUTNUM|OUTNUM]], [[george:macro:OUTPARAM|OUTPARAM]], [[george:macro:OUTPARN|OUTPARN]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:VFREE|VFREE]]
22FL #LIS K0WHATPERB>K0ALLGEO>K0GREATGEO>K0COMMAND
22KH ... SEG WHATPERB,,,,G203
22PD ...[
22T* ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
22^= ...[ THIS EXCLUDES CODE UNDER #SKI G203
2357 ...[
2394 #OPT K0WHATPERB=0
23BX ...#OPT G203 = 0
23JQ ...#SKI G203&1
23QK ...# WITH UGUG EDIT M203 (ALLOW WHATPER FOR REMOTE DEVICES)
23YG SEGENTRY K1WHATPERB,QK1WHATPERB
24D6 SEGENTRY K2WHATPERB,QK2WHATPERB
24DB [
24DG STUC
24DL #HAL +EWDAS+ASTUC,0
24DQ XOF
24DW #HAL +EWDAS+EXOF,0
24F2 XFUSSY +FUSSY
24F6 XFSWO +JUNITSWO
24F= XWPMOP +AWPMOP
24FB +AWPMOPG
24FG XFRESUNEN +FRESUNEN
24FL XFRONG +FWRONG
24FQ XFIDLE +FIDLE
24FW XFONLINE +FONLINE
24G2 XFOLJOB +FOLJOB
24G6 XFFAIL +FFAIL
24G= # S/R TO CLOSE UP USER AND LOCAL NAMES
24GB # X3 -> USER NAME
24GG # X4 LINK
24GL UPCLOSE
24GQ SBX 4 FX1
24GW LDN 7 ACOMMUNE1(2)
24H2 FLENME1 0,3,5
24H6 SBN 7 ACOMMUNE1(2)
24H= SLC 7 2
24HB LDN 0 24
24HG SBX 0 7
24HL BPZ 0 NOT25 [J IF < 25 CHARS
24HQ HUNTW 3,ADATA,CSTORE
24HW BPZ 3 PHOUND1
24J2 SETNCORE 7,3,ADATA,CSTORE
24J6 PHOUND1
24J= ADN 2 ACOMMUNE1 [THIS NECESSARY AS
24JB ADN 3 A1
24JG MVCH 2 26 [OUTPARAM USES ACOMMUNE7
24JL OUTPARAM 7,A1,ADATA,CSTORE
24JQ BRN XIT
24JW NOT25
24K2 OUTPARAM 7,ACOMMUNE1
24K6 XIT
24K= ADX 4 FX1
24KB EXIT 4 0
24KG #
24KL XHTAWP
24KQ MHUNTW 3,ADATA,AWPER
24KW EXIT 7 0
24L2 #
24L6 [
24L= #UNS ADMELI
24LB (
24LG [
24LL [ MESSAGES FOR STATE OF DME MX LINES
24LQ [
24LW ZCND +9
24M2 9HCONNECTED
24M6 ZDCD +12
24M= 12HDISCONNECTED
24MB ZBECN +15
24MG 15HBEING CONNECTED
24ML ZBEDC +18
24MQ 18HBEING DISCONNECTED
24MW ZTOCN +15
24N2 15HTO BE CONNECTED
24N6 ZTODC +18
24N= 18HTO BE DISCONNECTED
24NB WIRE4 +6
24NG 6H4-WIRE
24NL WIRE2 +6
24NQ 6H2-WIRE
24NW ZFAST +4
24P2 4HFAST
24P6 ZSLOW +4
24P= 4HSLOW
24PB NORM +6
24PG 6HNORMAL
24PL STAND +7
24PQ 7HSTANDBY
24PW ZOP +8
24Q2 8HOPERABLE
24Q6 ZINOP +10
24Q= 10HINOPERABLE
24Q? ZSWOUT +14
24Q# 14H,SWITCHED OUT)
24Q* ZWTBSW +28
24QB 28H,WAITING TO BE SWITCHED OUT)
24QC ZNULL +1
24QD 1H)
24QF [
24QG [
24QL [ BITS IN STATE OF DME MX LINE
24QQ BITDEFS AWORK1,0,YFOUR,YSLOW,YNORMAL,YBEING,YCN,YOP
24QW BITDEFS AWORK1,19,TRANSBIT
24R4 BITDEFS AWORK2,0,PRCONT,NOCSC,YSWO,YWTBSW
24R= FIELDDEF PORT,6,AWORK1,17
24RB FIELDDEF SCOUPLER,6,AWORK1,11
24RG FIELDDEF PROT,6,AWORK1,23
24RL [
24RQ ZOUTPAR [SUB TO OUTPUT PARAMS FOR MX LINE STATE
24RW SBX 7 FX1
24S2 LDN 5 1(3) [ADDR OF PARAM
24S6 LDN 6 ACOMMUNE1(2)
24S= SMO 0(3)
24SB MVCH 5 0 [MOVE PARAM INTO ACOMM WDS.
24SG OUTPARAM 0(3),ACOMMUNE1
24SL ADX 7 FX1
24SQ EXIT 7 0
24SW )
24XQ QK1WHATPERB
24XS [
24XW STO 5 AWORK2(2) [SAVE PER TYPE
24XY CALL 7 XHTAWP
24Y2 LDX 2 3 [SAVE X3
24Y4 LDN 4 A1+5
24Y6 STO 4 A1(3) [INTERNAL POINTER
24Y8 ADN 3 A1+5 [INT PTR TO FIRST REC HDDR
24Y= BRN ST1
24Y# UPD LDX 2 FX2
24YB LDX 5 AWORK2(2) [RESTORE PER TYPE
24YD CALL 7 XHTAWP
24YG LDX 2 3 [SAVE X3
24YJ LDX 4 A1+1(3)
24YL SBN 4 1
24YN BZE 4 NOUGH [J IF NO MORE RECS IN BLK
24YQ STO 4 A1+1(3) [UPDATE COUNT OF RECS
24YS LDN 4 K54-K50+14 [LENGTH OF THIS RECORD
24YW ADS 4 A1(3) [POINTER SET TO NEXT RECORD
24YY ADX 3 A1(3) [ABSOLUTE POINTER TO NEXT RECORD
24^2 ST1
24^3 ... JENVNOT ST2,CME
24^4 JSWOUT 3,SWITOUT [J IF SWITCHED OUT
24^6 ...ST2 LGEOG 3,0
24^8 SMO FX2
24^= STO 0 AWORK3
24^# LDX 0 5
24^B SBN 0 6
24^D BZE 0 UDAS [J IF TYPE 6 (ED) TO UDAS
24^G SBN 0 1
24^J BZE 0 UDAS [J IF TYPE 7 (MCF) TO UDAS
24^L SBN 0 6
24^N BZE 0 UDAS [J IF TYPE 13 (FD) TO UDAS
24^Q SBN 0 13
24^S BZE 0 UDAS [J IF TYPE 26 (EDS30) TO UDAS
24^W JWRONG 3,WRONGED [J IF WRONGED
24^Y JONL 3,ONLINE [J IF ONLINE
2522 LDX 0 5
2524 SBN 0 10
2526 BZE 0 MULT [J IF UX
2528 SBN 0 1
252= BZE 0 MULT [MX
252# SBN 0 13
252B BZE 0 MULTB [OR IPB (TYPE 24)
252D JALLOC 3,OWNED
252G BRN XIDLE
252J MULT
252Q MOPSTATE 3,6
252Y BRN MXMS
2532 MULTB
2534 MOPSTATE 3,6,AMOP
2536 MXMS
2538 STOZ 4
253= ... BNG 6 INOP
253# BZE 6 ON
253* SBN 6 5
253B BZE 6 OFF
253C LDN 4 1
253D ADN 6 4
253G BZE 6 ON
253J SBN 6 1
253L BZE 6 OFF
253S CALL 7 OUTNUM
253W CALL 7 OUTMESS
253Y +JONOFF
2542 BRN MXMS1
2544 ON
2546 CALL 7 OUTNUM
2548 CALL 7 OUTMESS [IF ALLOCATED THEN MOP ON
254= +JON
254# BRN MXMS1
254B OFF CALL 7 OUTNUM
254D CALL 7 OUTMESS
254G +JOFF
254H ... BRN MXMS1
254J ...INOP
254K ... CALL 7 OUTNUM
254L ... CALL 7 OUTMESS
254M ... +G203INOP
254N ...MXMS1
254P ... SMO 4
254Q ... LDX 7 XWPMOP(1)
254R ... BRN MONOUTX
254S UDAS
254W LDX 6 K54-K50+8(3)
254Y JTWIN 3,NOTWIN
2552 NGN 6 1
2554 NOTWIN
2556 LDX 4 K54-K50+8(3)
2558 ANDN 4 #20
255= BNZ 4 USUDA [J IF IN USE BY SYSTEM
255# JENG 3,SET [J IF ENGAGED
255B CALL 7 OUTNUM
255D CALL 4 OUTWIN
255G LDX 7 XFIDLE(1)
255J BRN MONOUTX
255L USUDA CALL 7 OUTNUM
255N CALL 4 OUTWIN
255Q CALL 7 MONOUT
255S +FUSSY
255W BRN UDOUT
255Y SET JHOLD 3,SETH
2562 CALL 7 OUTNUM
2564 CALL 4 OUTWIN
2566 BRN UDENG
2568 SETH CALL 7 OUTNUM
256= CALL 7 OUTMESS
256# +FHSET
256B CALL 4 OUTWIN
256D UDENG CALL 7 MONOUT
256G +FENG
256J UDOUT
256L CALL 7 XHTAWP
256N ADX 3 A1(3)
256Q LGEOG 3,3
256S LDN 2 BCCB [SEARCH CCB CHAIN FOR ASTUC BLOCKS
256W ULOOP LDX 2 FPTR(2)
256Y TXU 2 CXCC
2572 BCC ZEND [J IF END
2574 LDX 0 ATYPE(2)
2576 TXU 0 STUC(1)
2578 BCS ZEND [J IF NOT RIGHT TYPE
257= TXU 3 GEOGU(2)
257# BCS ULOOP [J IF NOT RIGHT UNIT
257B LDXC 6 BACK1(2)
257D CALL 7 OUTOCT [O/P SERIAL NUMBER
257G CALL 7 MONOUT
257J +FSUSN
257L LDN 4 1 [SET HEADING NOT O/P MARKER
257N STO 4 AWORK4(2)
257Q LDN 2 BCCB
257S # THIS ROUTINE OUTPUTS NAMES OF FILES OPEN ON UNIT
257W ULOOP1
257Y LDX 2 BPTR(2)
2582 LDX 0 ATYPE(2)
2584 TXU 0 XOF(1)
2586 BCS REST
2588 TXU 6 ASUSN(2) [CHECK IF /EXOF BLOCK
258= BCC XOUT [IS FOR CORRECT S.U.
258# LDX 5 ALOGLEN(2)
258B SBN 5 FDCELLS-A1
258D BZE 5 ULOOP1
258G XCELL SBN 5 6
258J SMO 5
258L TXU 6 FDCELLS(2) [LOOK AT NEXT CELL IN BLOCK
258N BCC XOUT
258Q BNZ 5 XCELL
258S BRN ULOOP1
258W XOUT MHUNTW 1,ADATA,AWPER
258Y LDN 5 A1+2(1)
2592 LDN 4 FIP(2) [FILENAME IS
2594 MOVE 4 3 [MOVED TO ACTIVITY BLOCK
2596 LDX 5 BACK2(2) [X5 CONTAINS EXOFILE NO
2598 LDX 4 FIP+4(2)
259= SRL 4 12 [X4 CONTAINS F.G.N.
259# SMO FX2
259B LDX 0 AWORK4
259D BZE 0 XOUT1
259G CALL 7 MONOUT
259J +FFLOP1
259L CALL 7 MONOUT
259N +FFLOP2
259Q STOZ AWORK4(2) [UNSET HEADING NOT O/P MARKER
259S XOUT1 MHUNTW 1,ADATA,AWPER
259W LDX 0 A1+2(1)
259Y BNZ 0 XOUT2 [J IF NOT A SCRATCH FILE
25=2 CALL 7 MONOUT
25=4 +FSCR
25=6 BRN XOF1
25=8 XOUT2
25== OUTBLOCN 6
25=# OUTPARN 12,A1+2,ADATA,AWPER
25=B OUTNUM 4,0,1 [AND FGN
25=D CALL 7 MONOUT
25=G #SKI G3MARK>7-7
25=J +FUDAS
25=L #SKI G3MARK<8$8
25=N +JTIMD
25=Q XOF1 FINDEXOF 2,5,REST [FIND LAST RELEVANT /EXOF BLOCK
25=S BRN ULOOP1
25=W REST FINDSU 2,6,ZEND [FIND LAST RELEVANT BLOCK
25=Y BRN ULOOP
25?2 ZEND BRN UPD
25?4 SWITOUT
25?6 CALL 7 OUTNUM
25?8 LDX 7 XFSWO(1)
25?= BRN MONOUTX
25?# WRONGED
25?B CALL 7 OUTNUM [OUTPUT OPERATORS NO.
25?D LDX 7 XFRONG(1)
25?G BRN MONOUTX
25?J XIDLE
25?L CALL 7 OUTNUM [OUTPUT OPERATORS NO.
25?N LDX 7 XFIDLE(1)
25?Q BRN MONOUTX
25?S OWNED
25?W JENG 3,USSY [J IF NOT "RESERVED & UNENGAGED"
25?Y CALL 7 OUTNUM [OUTPUT OPERATORS NO.
25#2 LDX 7 XFRESUNEN(1)
25#4 BRN MONOUTX
25#6 # PERIPHERAL BEING USED BY SYSTEM
25#8 USSY
25#= CALL 7 OUTNUM [O/P GEOG NO
25## LDX 7 XFUSSY(1)
25#B BRN MONOUTX
25#D #
25#G # DEVICE ONLINE TO A JOB
25#J #
25#L ONLINE
25#N CALL 7 OUTNUM
25#Q LDX 7 XFONLINE(1)
25#S MONOUTX 7
25#W CALL 7 XHTAWP
25#Y ADX 3 A1(3)
25*2 LJOBNO 3,4
25*4 LDX 0 4
25*6 CALL 7 OUTNUM2 [OUTPUT JOB NO.
25*8 CALL 7 XHTAWP
25*= SMO A1(3)
25*# LDN 3 K54-K50+1(3)
25*B CALL 4 UPCLOSE
25*D CALL 7 XHTAWP
25*G LDX 7 XFOLJOB(1)
25*J ADX 3 A1(3) [X3 IS ABSOLUTE POINTER
25*L JFAIL 3,PHAIL
25*N BRN MONOUTX
25*Q PHAIL
25*S MONOUTX 7
25*W LDX 7 XFFAIL(1)
25*Y MONOUTX
25B2 MONOUTX 7
25B4 BRN UPD
25B6 NOUGH LDX 2 FX2
25B8 RONG1
25BL OFF AWHATBIT [GIVE THE ALL CLEAR
25BP ...#SKI G203&1
25BS ... ACROSS WHATPER,7
25BX ...#SKI G203&1$1
25C2 ... FON #114
25C8 TOENDCOM
25C= ENDCOM
25CB QK2WHATPERB
25CF [
25CJ MHUNTW 3,CPAR,JSCE
25CM LDX 4 JSCEB(3)
25CQ SRL 4 9
25CT ANDN 4 #77 [ISOLATE LINE NUM
25CY LDN 5 0
25D3 LDX 3 JSCEP(3)
25D6 LINECTRL 4,3 [ASK EXEC FOR STATE OF LINE
25D9 STO 4 AWORK1(2) [SAVE REPLY
25D# STO 5 AWORK2(2)
25DC OUTBLOCN 21
25DD ...#SKI G203&1
25DF ...(
25DG ... MHUNTW 3,CPAR,JSCE
25DH ... LDX 6 JSCEQ(3)
25DJ ... ANDN 6 #7777
25DK ... OUTPARAM 6,JSCER,CPAR,JSCE
25DL ...)
25DM ...#SKI G203&1$1
25DN ...(
25DP ... MHUNT 3,CPB,CUNI
25DQ ... LDX 6 ANUM(3)
25DR ... ANDN 6 #7777
25DS ... OUTPARAM 6,APARA,CPB,CUNI
25DT ...)
25DW BPZ 5 ZNPRC [J IF NOT UNDER PROG CTRL
25DX LDN 3 ZOP(1)
25DY JBS ZPOP,2,YOP
25D^ LDN 3 ZINOP(1)
25F2 ZPOP
25F3 CALL 7 ZOUTPAR
25F4 [
25F5 LDN 3 ZSWOUT(1)
25F6 JBS ZOUTSW,2,YSWO
25F7 LDN 3 ZWTBSW(1)
25F8 JBS ZOUTSW,2,YWTBSW
25F9 LDN 3 ZNULL(1)
25F= ZOUTSW
25F? CALL 7 ZOUTPAR
25F# MONOUT ALIPRSTAT
25F* BRN ZCOK
25FB ZNPRC
25FC [
25FD [ NOW OUTPUT PARAMS SHOWING STATE
25FF LDN 3 ZCND(1) [CONNECTED
25FH JBS ZBEING,2,YBEING [J IF CHANGE OF STATE IN PROGRESS
25FL JBS ZTOBE,2,NOCSC
25FP JBS ZOUTCN,2,YCN [J IF CONNECTED
25FS LDN 3 ZDCD(1) [DISCONNECTED
25FX BRN ZOUTCN
25G2 ZTOBE LDN 3 ZTOCN(1)
25G5 JBS ZOUTCN,2,YCN [J IF TO BE CONNECTED
25G8 LDN 3 ZTODC(1)
25G? BRN ZOUTCN [ELSE TO BE DISCONNECTED
25GB ZBEING
25GF LDN 3 ZBECN(1)
25GJ JBS ZOUTCN,2,YCN [J IF BEING CONNECTED
25GM LDN 3 ZBEDC(1) [BEING DISCONNECTED
25GQ ZOUTCN
25GT CALL 7 ZOUTPAR
25GY [ NOW OUTPUT NUMBER OF WIRES
25H3 LDN 3 WIRE4(1)
25H6 JBS ZOUTWIRE,2,YFOUR
25H9 LDN 3 WIRE2(1)
25H# ZOUTWIRE
25HC CALL 7 ZOUTPAR
25HG [ NOW OUTPUT SPEED
25HK LDN 3 ZFAST(1)
25HN JBC ZOUTSP,2,YSLOW
25HR LDN 3 ZSLOW(1)
25HW ZOUTSP
25H^ CALL 7 ZOUTPAR
25J4 [ NOW STATUS (NORMAL OR STANDBY)
25J7 LDN 3 NORM(1)
25J= JBS ZOUTSTAT,2,YNORMAL
25J* LDN 3 STAND(1)
25JD ZOUTSTAT
25JH CALL 7 ZOUTPAR
25JL [ NOW OPERABILITY
25JP LDN 3 ZOP(1)
25JS JBS ZOUTOP,2,YOP
25JX LDN 3 ZINOP(1)
25K2 ZOUTOP
25K5 CALL 7 ZOUTPAR
25K8 [
25K? MONOUT AMXLSTAT [OUTPUT STATE MESSAGE
25KB VFREE CPB,CUNI [FINISHED WITH CUNI
25KF LF 2,PORT,6
25KJ OUTNUM 6,0 [OUTPUT PORT PARAM
25KM LF 2,SCOUPLER,6
25KQ OUTNUM 6,0 [AND COUPLER
25KT JBC NTRAN,2,TRANSBIT
25KY OUTNULL [LET END OF MSG OUT IF TRANS
25L3 NTRAN MONOUT ALIPCTR
25L6 JBC ZCOK,2,NOCSC
25L9 MONOUT CSCNRUN
25L# ZCOK
25L* ...#SKI G203&1
25LB ... ACROSS WHATPER,7
25LC ...#SKI G203&1$1
25LG FON #114
25LK ENDCOM
25LN [
25LR # SUBROUTINES TO OUTPUT MESS IN LOCN FOLLOWING CALL
25LW MONOUT
25L^ LDX 1 7
25M4 SBX 7 FX1
25M7 MONOUTX 0(1)
25M= ADX 7 FX1
25M* EXIT 7 1
25MD OUTWIN
25MF ... SBX 4 FX1
25MH BNG 6 NTWIN
25MP SLL 6 16
25MS BNG 6 SHARED [B16 SET IS SHARED
25MX SLL 6 1
25N2 BNG 6 NDED [B17 SET IS DEDICATED
25N5 CALL 7 OUTMESS
25N8 +ENTIN32 [ELSE UNDEDICATED
25N? BRN NTWIN1
25NB SHARED
25NF CALL 7 OUTMESS
25NJ +ENTIN33
25NM BRN NTWIN1
25NQ NDED
25NT CALL 7 OUTMESS
25NY +ENTIN31
25N^ ... BRN NTWIN1
25P2 ...NTWIN
25P3 ... JENVNOT NTWIN1,CME
25P4 ... JNCMESH 3,NTWIN1
25P5 ... CALL 7 OUTMESS
25P6 ... +CMESHWP
25P7 ...NTWIN1
25P8 ... ADX 4 FX1
25P# EXIT 4 0
25PC OUTMESS
25PG LDX 1 7
25PK SBX 7 FX1
25PN OUTMESSX 0(1)
25PR ADX 7 FX1
25PW EXIT 7 1
25P^ # SUBROUTINE TO OUTPUT DECIMAL NO IN X0
25Q4 OUTNUM
25Q7 LGEOG 3,0 [GET OPS NO
25Q= OUTNUM2
25Q* SBX 7 FX1
25QD OUTNUM 0,0
25QH ADX 7 FX1
25QL EXIT 7 0
25QP #
25QS # SUBROUTINE TO OUTPUT AN OCTAL NO. IN X6
25QX #
25R2 OUTOCT
25R5 SBX 7 FX1
25R8 CONSERNO 6 [CONVERT SERIAL NUMBER
25R? MHUNTW 2,FLIB,FTSN
25RB OUTPARAM A1(2),A1+1,FLIB,FTSN
25RF ADX 7 FX1
25RJ EXIT 7 0
25RM MISTAKE
25RQ COMERRX 0(1)
25X2 #END
^^^^ ...002770370004