{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: WHATPROP865)}}
====== WHATPROP865 ======
(George Source)
**Macros used:** [[george:macro:ALTLEN|ALTLEN]], [[george:macro:AND|AND]], [[george:macro:APROPNAME|APROPNAME]], [[george:macro:CLOSE|CLOSE]], [[george:macro:DO|DO]], [[george:macro:ELSE|ELSE]], [[george:macro:ERROR|ERROR]], [[george:macro:FASTREWIND|FASTREWIND]], [[george:macro:FI|FI]], [[george:macro:HUNTW|HUNTW]], [[george:macro:IF|IF]], [[george:macro:INFORM|INFORM]], [[george:macro:MFREE|MFREE]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:ON|ON]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:OUTMESS|OUTMESS]], [[george:macro:OUTPARAM|OUTPARAM]], [[george:macro:OUTPER|OUTPER]], [[george:macro:OUTPERA|OUTPERA]], [[george:macro:REPEAT|REPEAT]], [[george:macro:REWIND|REWIND]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:STEP|STEP]], [[george:macro:STEPASET|STEPASET]], [[george:macro:THEN|THEN]], [[george:macro:UP|UP]], [[george:macro:UPPLUS|UPPLUS]], [[george:macro:WHILE|WHILE]]
22FL #OPT K0WHATPROP = 0
22^= #LIS K0WHATPROP
23DW #SEG WHATPROP
23YG 8HWHATPROP
24D6 SEGENTRY K1WHATPROP,Z1WHATPROP [ PROPASSOCS MACRO
24XQ SEGENTRY K2WHATPROP,Z2WHATPROP [ APROPNAME MACRO
25CB SEGENTRY K3WHATPROP,Z3WHATPROP [ MPROPCON MACRO
25X2 SEGENTRY K4WHATPROP,Z4WHATPROP [ ISPROPN MACRO
26BL SEGENTRY K5WHATPROP,Z5WHATPROP [ PROPNO MACRO
26W= SEGENTRY K7WHATPROP,Z7WHATPROP [ SPLPROPS MACRO
2764 ... SEGENTRY K8WHATPROP,Z8WHATPROP [ SPLCLPROPS MACRO
27*W [
27TG [************************************************************
28*6 [
28SQ [ PRESET DATA
29#B [
29S2 [************************************************************
2=?L [
2=R= [
2?=W PMISSING 12H!MISSING!!!!
2?*F ...PSEQDCS #76007631,#74607635,#76137460,#74610000
2?D4 ...PMESSA 28HPROPERTIES REQUIRED ON UNIT
2?GM ...PMESSB 2H:
2?K= ...PMESSC 4HNONE
2?MT ...PTERM #76137664
2?QG [
2#=6 [************************************************************
2#PQ [
2*9B SNUMBER
2*P2 [
2B8L [************************************************************
2BN= [
2C7W [
2CMG [ CONVERT PROPERTY NAME IN CPB/CUNI TO NUMBER
2D76 [
2DLQ [ ON ENTRY
2F6B [ AWORK4 = DEPTH OF :SYSTEM.PROPERTY
2FL2 [
2G5L [ ON EXIT
2GK= [ X4 - ZERO - NAME NOT FOUND
2H4W [ - B0 SET - CONSOLE PROPERTY
2HJG [ - B1 SET - PERMANENT PROPERTY
2J46 [
2JHQ [ LINK X7
2K3B [
2KH2 STOZ 4
2KQS ... STOZ 5
2L2L LDX 0 ACES
2LG= STO 0 AWORK1(2)
2L^W STO 0 AWORK2(2)
2MFG STO 0 AWORK3(2)
2M^6 MHUNT 3,CPB,CUNI
2NDQ LDN 1 APARA(3)
2NYB LDN 2 AWORK1(2)
2PD2 LDX 3 ANUM(3)
2PXL ANDN 3 #7777
2QC= SBN 3 13
2QWW BPZ 3 (7) [ EXIT IF NAME TOO LONG
2RBG ADN 3 13 [ PROPERTY NAME IN AWORK1 ->
2RW6 MVCH 1 0(3) [ SPACEFILLED TO 12 CHARS
2S*Q SBX 7 FX1
2STB LDX 2 FX2
2T*2 [
2TSL WHILE 4,ZE [ NOT FOUND NAME
2W#= SMO AWORK4(2)
2WRW STEP 0
2X?G AND 3,NZ [ NOT END OF :SYSTEM.PROPERTY
2XR6 DO
2Y=Q IF +AWORK1(2),E,APROPNAME(3) [ NAMES MATCH
2YQB AND +AWORK2(2),E,APROPNAME+1(3)
2^=2 AND +AWORK3(2),E,APROPNAME+2(3)
2^PL THEN
329= NGNC 4 1
32NW ANDX 4 APROPNO(3) [ PROPERTY NO. WITHOUT BIT 0
338G LDX 0 APROPGROUP(3)
33N6 ANDX 0 GSIGN
347Q ORS 0 4 [ SET BIT 0 IF CONSOLE PROP
34#Y ... LDX 5 CACT
34G6 ... ANDX 5 APROPNO(3)
34MB FI
3572 REPEAT
35LL ADX 7 FX1
366= EXIT 7 0
36KW [
375G [************************************************************
37K6 [
384Q SPRSPLIT
38JB [
3942 [************************************************************
39HL [
3=3= [
3=GW [ SPLIT PROERTY NAMES IN & FORMAT INTO APERI/APROPS FORMAT
3?2G [
3?G6 [
3?^Q [ X7 - LINK
3#FB [
3#^2 SBX 7 FX1
3*68 ... SLL 7 12
3*?B ... ADX 7 4
3*DL SETNCORE ATTMAX*4+2,1,APERI,APROPS
3*Y= LDX 2 1
3BCW LDN 5 ATTMAX
3BXG DO [ PRESET BLOCK
3CC6 STOZ A1+2(2)
3CWQ ADN 2 4
3DBB REPEAT CT 5
3DW2 MHUNT 3,APERI,APROPNOS
3F*L LDX 2 CHPERM(3)
3FT= ADX 3 ADPERM(3)
3G#W ADN 1 A1+2
3GSG STO 1 4 [ X4 - POSITION FOR LENGTH OF NAME
3H#6 ADN 1 1 [ X1 - FOR NEXT CHAR OF PROPERTY NAME
3HRQ LDN 5 0 [ X5 - LENGTH OF NAME
3J?B WHILE 2,NZ [ CHARACTER LEFT IN NAMES
3JR2 DO [ SPLIT AT &
3K=L LDCH 0 0(3)
3KQ= SBN 0 #26
3L9W IF 0,ZE [ &
3LPG THEN
3M96 LDX 1 4
3MNQ STO 5 0(1) [ LENGTH OF NAME
3N8B ADN 1 5 [ POSITION FOR NEXT NAME
3NN2 ADN 4 4
3P7L LDN 5 0
3PM= ELSE
3Q6W ADN 0 #26
3QLG DCH 0 0(1) [ COPY CHAR
3R66 BCHX 1 £
3RKQ ADN 5 1
3S5B FI
3SK2 SBN 2 1
3T4L BCHX 3 £
3TJ= REPEAT
3W3W SMO 4
3WHG STO 5 0 [ LENGTH OF LAST NAME
3WMC ... LDX 4 7
3WR# ... ANDN 4 #7777
3WX9 ... SRL 7 12
3X36 ADX 7 FX1
3XGQ EXIT 7 0
3XGW ...[
3XH2 ...[*************************************************************
3XH6 ...[
3XH= ...SPPROPS
3XHB ...[
3XHG ...[*************************************************************
3XHL ...[
3XHQ ...[
3XHW ...[PUT PERMANENT PROPERTIES INTO APERI,APROPS BLOCK
3XJ2 ...[
3XJ6 ...[
3XJ= ... SBX 7 FX1
3XJB ... LDX 4 7
3XJG ... LDX 7 BPROPCNT(3)
3XJL ... LDN 6 0
3XJQ ... LDX 1 3
3XJW ... WHILE +CPROPNO(3),U,BPROPS(1)
3XK2 ... DO
3XK6 ... LDX 0 BPROPS(1)
3XK= ... SLC 0 4
3XKB ... ANDN 0 4
3XKG ... ADX 6 0 [ADD 4 IF PERM PROP 0 IF NOT
3XKL ... ADN 1 1
3XKQ ... REPEAT CT 7
3XKW ... CALL 7 SPRSPLIT [SPLIT PERM PROP NAMES UP
3XL2 ... MHUNT 3,APERI,APROPS
3XL6 ... SMO 6
3XL= ... STOZ A1+2(3) [CLEAR LENGTH OF CONSOLE PROPERTY
3XLB ... LDX 7 4
3XLG ... ADX 7 FX1
3XLL ... EXIT 7 0
3XLQ ...[
3XLW ...[************************************************************
3XM2 ...[
3XM6 ...SMVPROPS
3XM= ...[
3XMB ...[************************************************************
3XMG ...[
3XML ...[
3XMQ ...[MOVE PROPERTY NAMES TO BLOCK IN X2 - FROM Z7 ADATA,CSTORE
3XMW ...[ FROM Z8 AMXOR,IOUT
3XN2 ...[
3XN6 ... LDN 6 ATTMAX
3XN= ... DO
3XNB ... IF +A1+2(3),NZ [USEFUL NAME
3XNG ... THEN
3XNL ... LDN 1 A1+3(3)
3XNQ ... SMO A1+2(3)
3XNW ... MVCH 1 0
3XP2 ... ADX 5 A1+2(3)
3XP6 ... LDN 0 #26
3XP= ... DCH 0 0(2)
3XPB ... BCHX 2 £
3XPG ... ADN 5 1
3XPL ... FI
3XPQ ... ADN 3 4
3XPW ... REPEAT CT 6
3XQ2 ... LDX 7 2
3XQ6 ... MFREE APERI,APROPS
3XQ= ... LDX 2 7
3XQB ... MHUNT 3,APERI,APROPNOS
3XQG ... IF +CHTEMP(3),NZ
3XQL ... THEN
3XQQ ... LDX 1 ADTEMP(3)
3XQW ... ADX 1 3
3XR2 ... SMO CHTEMP(3)
3XR6 ... MVCH 1 0
3XR= ... ADX 5 CHTEMP(3)
3XRB ... ELSE
3XRG ... SBN 5 1
3XRL ... FI
3XRQ ... EXIT 4 0
3XRW ...[
3XS2 ...[*************************************************************
3XS6 ...[
3XS= ...SMESSAGE
3XSB ...[
3XSG ...[*************************************************************
3XSL ...[
3XSQ ...[
3XSW ...[MOVE PAGE SEQUENCE, DEVICE CONTROL STRING & START OF CONSOLE
3XT2 ...[MESSAGE INTO AMXOR,IOUT BLOCK
3XT6 ...[
3XT= ...[
3XTB ... SBX 6 FX1
3XTG ... OUTPERA
3XTL ... MHUNTW 2,AMXOR,IOUT
3XTQ ... LDN 5 IDATA(2)
3XTW ... LDX 2 FX2
3XW2 ... LDN 4 PSEQDCS(1)
3XW6 ... MVCH 4 14
3XW= ... LDN 4 PMESSA(1)
3XWB ... MVCH 4 28
3XWG ... LDN 4 ACOMMUNE2(2)
3XWL ... SMO ACOMMUNE1(2)
3XWQ ... MVCH 4 0
3XWW ... LDN 4 PMESSB(1)
3XX2 ... MVCH 4 2
3XX6 ... LDX 4 ACOMMUNE1(2)
3XX= ... SBN 4 2
3XXB ... LDX 2 5
3XXG ... LDX 5 4
3XXL ... ADX 6 FX1
3XXQ ... EXIT 6 0
3Y2B [
3YG2 [
3Y^L [ WW WW W
3^F= [ WW WW WW
3^YW [ WW WW WWW
42DG [ WWWW WW
42Y6 [ WWWWW WW
43CQ [ WW WW WW
43XB [ WW WW WW
44C2 [ WW WW WW
44WL [
45B= Z1WHATPROP
45TW [
46*G [ PUT PROPERTY NAMES IN APERI/ASSOCS BLOCK
46T6 [
47#Q [ IF NUMBER NOT FOUND - COMMMAND TYPE = 0
47SB [ NAME INDETERMINATE
48#2 [
48RL OPENSYS ZBRKIN,PROPERTY,READ
49?= MHUNT 2,APERI,ASSOCS
49QW LDX 6 A1(2)
4==G LDX 1 2
4=Q6 DO [ PRESET BLOCK
4?9Q STOZ A1+3(1)
4?PB ADN 1 ASSOCSLEN
4#92 REPEAT CT 6
4#NL LDX 6 A1(2)
4*8= WHILE 6,NZ [ MORE PROPERTIES
4*MW STEP
4B7G AND 3,NZ [ NOT END OF :SYSTEM.PROPERTY
4BM6 DO
4C6Q MHUNT 2,APERI,ASSOCS
4CLB LDX 5 A1(2)
4D62 DO
4DKL LDX 0 A1+2(2)
4F5= ERX 0 APROPNO(3)
4FJW ANDX 0 BSP16
4G4G IF 0,ZE [ NUMBERS MATCH
4GJ6 THEN
4H3Q LDN 0 APROPNAME(3)
4HHB LDN 1 A1+3(2)
4J32 MOVE 0 3
4JGL SBN 6 1
4K2= FI
4KFW ADN 2 ASSOCSLEN
4K^G REPEAT CT 5
4LF6 REPEAT
4LYQ IF 3,ZE [ NOT FOUND ALL NUMBERS
4MDB THEN
4MY2 MHUNT 2,APERI,ASSOCS
4NCL LDX 6 A1(2)
4NX= DO
4PBW IF +A1+3(2),ZE [ NUMBER NOT FOUND
4PWG THEN
4QB6 STOZ A1+1(2) [ CLEAR COMMAND TYPE
4QTQ FI
4R*B ADN 2 ASSOCSLEN
4RT2 REPEAT CT 6
4S#L FI
4SS= CLOSE
4T?W UPPLUS 1
4TRG [
4W?6 [
4WQQ [ WW WW WWWWW
4X=B [ WW WW WW WW
4XQ2 [ WW WW WW
4Y9L [ WWWW WW
4YP= [ WWWWW WWWWW
4^8W [ WW WW WW
4^NG [ WW WW WW
5286 [ WW WW WWWWWWWW
52MQ [
537B Z2WHATPROP
53M2 [
546L [ CONVERT PROPERTY NO. IN ACOMMUNE1 TO NAME IN ACOMMUNE1-3
54L= [ EXCL / PERM BITS IN ACOMMUNE4
555W [ IF NOT FOUND - NAME = !MISSING!!!!
55KG [ - ACOMMUNE4 = 0
5656 [
56JQ LDX 0 ACOMMUNE1(2)
574B STO 0 AWORK1(2) [ PROPERTY NO.
57J2 LDX 0 ACOMMUNE2(2)
583L STO 0 AWORK4(2) [ FILE DEPTH OF PROPERTY
58H= SMO AWORK4(2)
592W REWIND 0
59GG WHILE TRUE
5=26 SMO AWORK4(2)
5=FQ STEP 0
5=^B AND 3,NZ [ NOT END OF :SYSTEM.PROPERTY
5?F2 LDX 0 APROPNO(3)
5?YL ERX 0 AWORK1(2)
5#D= ANDX 0 BSP16
5#XW AND 0,NZ [ NUMBERS NOT MATCH
5*CG DO
5*X6 REPEAT
5BBQ IF 3,NZ [ FOUND
5BWB THEN
5CB2 LDCT 0 #777
5CTL ANDX 0 APROPNO(3)
5D*= STO 0 ACOMMUNE4(2)
5DSW LDN 1 APROPNAME(3)
5F#G ELSE
5FS6 STOZ ACOMMUNE4(2)
5G?Q ADN 1 PMISSING
5GRB FI
5H?2 ADN 2 ACOMMUNE1
5HQL MOVE 1 3
5J== UP
5JPW [
5K9G [
5KP6 [ WW WW WWWWWWWW
5L8Q [ WW WW WW
5LNB [ WW WW WW
5M82 [ WWWW WWW
5MML [ WWWWW WW
5N7= [ WW WW WW WW
5NLW [ WW WW WW WW
5P6G [ WW WW WWWWWW
5PL6 [
5Q5Q Z3WHATPROP
5QKB [
5R52 [ CONVERT PROPERTY NUMBERS IN GMON/ASET
5RJL [ TO NAMES IN ADATA/GMONACC
5S4= [
5SHW OPENSYS (GEOERR),PROPERTY,READ
5T3G MHUNT 2,ADATA,GMONACC
5TH6 STOZ JPROPCON(2) [ POINTER TO NEXT FREE CELL
5W2Q WHILE TRUE
5WGB MHUNTW 1,GMON,ASET
5X22 STEPASET 1,PROPS,6
5XFL AND 3,PZ [ MORE PARAMETERS WITH PDC PROPS
5X^= DO
5YDW SBN 3 1(1)
5YYG SMO JPROPCON(2) [ SAVE POINTER TO PARAMETER
5^D6 STO 3 JPROPCON+1(2) [ RELATIVE TO START OF /ASET
5^XQ SMO JPROPCON(2)
62CB STOZ JPROPCON+2(2) [ LENGTH OF NAMES
62X2 SMO FX2
63BL STO 6 AWORK1 [ NO OF PROPERTIES IN PARAMETER
63W= SMO FX2
64*W STO 6 AWORK2
64TG [
65*6 [ INCREASE LENGTH OF ADATA/GMONACC
65SQ SLL 6 2 [ NAMES
66#B ADN 6 2+JPROPCON-A1+1 [ RESET OF CELL + FIXED PART OF BLOCK
66S2 ADX 6 JPROPCON(2) [ OTHER CELLS
67?L ALTLEN 2,6,ADATA,GMONACC
67R= [
68=W [ CONVERT NUMBERS TO NAMES
68QG FASTREWIND 1
69=6 LDX 5 3 [ /ASET DISPLACEMENT
69PQ WHILE +AWORK2(2),NZ [ MORE PROPERTIES TO BE FOUND
6=9B STEP
6=P2 AND 3,NZ [ NOT END OF :SYSTEM.PROPERTY
6?8L DO
6?N= MHUNT 1,GMON,ASET
6#7W ADX 1 5 [ X1 -> PARAMETER CELL
6#MG LDX 6 AWORK1(2) [ NO OF PROPERTIES IN CELL
6*76 DO
6*LQ LDX 0 1(1) [ PARA PROP NO.
6B6B ERX 0 APROPNO(3)
6BL2 ANDX 0 BSP16
6C5L IF 0,ZE [ NUMBERS MATCH
6CK= THEN
6D4W MHUNT 2,ADATA,GMONACC
6DJG ADX 2 JPROPCON(2) [ -> NAME CELL
6F46 STO 2 7
6FHQ LDX 4 JPROPCON+2(2) [ LENGTH ALREADY FOUND
6G3B SRC 4 2
6GH2 ADN 4 JPROPCON+3(2) [ -> DESTINATION FOR NAMES
6H2L ADN 3 APROPNAME
6HG= MVCH 3 12
6H^W SBN 3 APROPNAME+3
6JFG [
6J^6 [ REMOVE TRAILING SPACES
6KDQ LDX 2 4 [ END OF THIS NAME
6KYB LDN 4 12
6LD2 WHILE TRUE
6LXL SLC 2 2
6MC= SBN 2 1
6MWW SRC 2 2 [ BACK ONE CHAR. POS.
6NBG LDCH 0 0(2)
6NW6 SBN 0 #20
6P*Q AND 0,ZE [ SPACE
6PTB DO
6Q*2 REPEAT CT 4
6QSL [
6R#= [ ADD "&"
6RRW ADN 4 1
6S?G BCHX 2 £
6SR6 LDN 0 #26
6T=Q DCH 0 0(2)
6TQB SMO 7
6W=2 ADS 4 JPROPCON+2 [ UPDATE CHAR. COUNT
6WPL LDN 0 1
6X9= SMO FX2
6XNW SBS 0 AWORK2 [ FOUND A PROPERTY
6Y8G FI
6YN6 ADN 1 1
6^7Q REPEAT CT 6
6^MB LDX 2 FX2
7272 REPEAT
72LL MHUNT 2,ADATA,GMONACC
736= IF 3,ZE [ NOT FOUND ALL PROPERTIES
73KW THEN
745G LDX 3 2
74K6 ADX 3 JPROPCON(2) [ -> NAME CELL
754Q LDX 7 JPROPCON+2(3) [ CHAR. COUNT
75JB SRC 7 2
7642 ADN 7 JPROPCON+3(3) [ -> DESTINATION
76HL SMO FX1
773= LDN 6 PMISSING [ "!MISSING!!!!"
77GW MVCH 6 12
782G LDN 0 12
78G6 ADS 0 JPROPCON+2(3) [ UPDATE CHAR. COUNT
78^Q ELSE
79FB LDN 0 1
79^2 SMO JPROPCON(2)
7=DL SBS 0 JPROPCON+2(2) [ REMOVE TRAILING "&"
7=Y= FI
7=YW ... [
7=^G ... [ B8919 CORRECTION 30.06.82
7?26 ... [ IF PROPERTY NAMES STRING DOES NOT OCCUPY
7?2Q ... [ AN EXACT NO. OF WORDS, SPACEFILL LAST WORD
7?3B ... SMO JPROPCON(2)
7?42 ... LDX 4 JPROPCON+2(2)
7?4L ... LDX 1 4
7?5= ... ANDN 4 3
7?5W ... IF 4,NZ
7?6G ... THEN
7?76 ... LDN 0 4
7?7Q ... SBX 0 4
7?8B ... SRC 1 2
7?92 ... ADX 1 JPROPCON(2)
7?9L ... ADN 1 JPROPCON+3(2)
7?== ... LDN 4 #20
7?=W ... WHILE TRUE
7??G ... DCH 4 0(1)
7?#6 ... SBN 0 1
7?#Q ... AND 0,NZ
7?*B ... DO
7?B2 ... BCHX 1 £
7?BL ... REPEAT
7?C= ... FI
7?CW [
7?XG [ UPDATE FREE NAME CELL POINTER
7#C6 SMO JPROPCON(2)
7#WQ ... LDX 4 JPROPCON+2(2)
7*BB ADN 4 11
7*W2 SRL 4 2
7B*L ADS 4 JPROPCON(2)
7BT= REPEAT
7C#W CLOSE
7CSG UP
7D#6 [
7DRQ [
7F?B [ WW WW WW
7FR2 [ WW WW WW
7G=L [ WW WW WW
7GQ= [ WWWW WW WW
7H9W [ WWWWW WWWWWWWW
7HPG [ WW WW WW
7J96 [ WW WW WW
7JNQ [ WW WW WW
7K8B [
7KN2 [
7L7L Z4WHATPROP
7LM= [
7M6W [ CONVERT PROPERTY NAME TO NUMBER - OPENING PROPERTY
7MLG [
7N66 OPENSYS ZBRKIN,PROPERTY,READ
7NKQ STOZ AWORK4(2)
7P5B CALL 7 SNUMBER
7PK2 CLOSE
7Q4L IF 4,ZE [ NUMBER NOT FOUND
7QJ= THEN
7R3W ERROR JPROPUNK
7RHG STOZ ACOMMUNE1(2)
7S36 ELSE
7SGQ STO 4 ACOMMUNE1(2)
7T2B FI
7TG2 UPPLUS 1
7T^L [
7WF= [
7WYW [ WW WW WWWWWWWW
7XDG [ WW WW WW
7XY6 [ WW WW WWWWWW
7YCQ [ WWWW WW
7YXB [ WWWWW WW
7^C2 [ WW WW WW WW
7^WL [ WW WW WW WW
82B= [ WW WW WWWWW
82TW [
83*G [
83T6 Z5WHATPROP
84#Q [
84SB [ CONVERT PROPERTY NAME TO NUMBER - PROPERTY ALREADY OPEN
85#2 [
85RL LDX 1 ACOMMUNE1(2) [ DEPTH OF PROPERTY
86?= STO 1 AWORK4(2)
86QW REWIND 0(1)
87=G CALL 7 SNUMBER
87Q6 STO 4 ACOMMUNE1(2)
87^Y ... STO 5 ACOMMUNE2(2)
889Q UP
88PB [
8992 [
89NL [ WW WW WWWWWWWW
8=8= [ WW WW WW WW
8=MW [ WW WW WW
8?7G [ WWWW WW
8?M6 [ WWWWW WW
8#6Q [ WW WW WW
8#LB [ WW WW WW
8*62 [ WW WW WW
8*KL [
8B5= [
8BJW Z7WHATPROP
8C4G [
8CJ6 [ OUTPUT PROPERTIES REQUIRED MESSAGE FOR SPOOLED LINE PRINTERS
8D3Q [
8DHB HUNTW 3,APERI,APROPNOS
8F32 IF 3,PZ [ SPOOLING
8FGL THEN
8G2= OUTPER
8GFW SETNCORE ATTMAX*3+3,1,ADATA,CSTORE
8G^G MHUNTW 3,APERI,APROPNOS
8HF6 LDX 0 BPROPCNT(3)
8HYQ SBN 0 1
8JDB IF 0,NZ [ NON-CONSOLE PROPERTIES
8JY2 THEN
8KCL ... CALL 7 SPPROPS
8SQ2 MHUNT 2,ADATA,CSTORE
8T9L ADN 2 A1+1
8TP= LDN 5 0 [ CHARACTER COUNT
8W8W ... CALL 4 SMVPROPS
9?BQ OUTPARAM 5,A1+1,ADATA,CSTORE
9?WB ELSE
9#B2 OUTMESS JNONE
9#TL FI
9**= INFORM 0,JSPROPS,1
9*SW MFREEW ADATA,CSTORE
9B#G FI
9BS6 UP
9BS* ...[
9BSJ ...[
9BSR ...Z8WHATPROP
9BT2 ...[
9BT9 ...[ SET UP PROPERTIES REQUIRED MESSAGE FOR CLEAN COPY SPOOLING
9BTD ...[ LINE PRINTERS
9BTM ...[
9BTW ...[
9BTX ... HUNTW 3,APERI,APROPNOS
9BTY ... IF 3,PZ
9BT^ ... THEN
9BW5 ... SMO FX2
9BW# ... LDX 4 AWORK3 [NPU SIZE IN CHARS
9BWH ... LDX 5 4
9BWQ ... ADN 5 IDATA-A1*4+3 [ROUND UP
9BW^ ... SRL 5 2 [NO. OF WORDS IN OUTPUT
9BX8 ... SETUPCORE 5,2,AMXOR,IOUT,1
9BXC ... STOZ IMOPTY(2) [DONT WAKE UNLESS LAST BLOCK
9BXL ... LDN 0 1
9BXT ... MHUNTW 1,AMXOR,ADCB
9BY4 ... LDX 5 IDENTNO(1)
9BY? ... STO 5 IPBIDE(2)
9BYG ... ORX 4 GSIGN
9BYP ... STO 4 IPBIDE+1(2) [OUTPUT CHAR COUNT
9BYY ... STOZ IBSW(2) [BLOCK STATUS WORD
9B^7 ... MHUNTW 3,APERI,APROPNOS
9B^B ... LDX 0 BPROPCNT(3)
9B^K ... SBN 0 1
9B^S ... IF 0,NZ [NON-CONSOLE PROPERTIES
9C23 ... THEN
9C2= ... CALL 7 SPPROPS [GET PERM PROPS IN APERI-APROPS
9C2F ... CALL 6 SMESSAGE [START OF MESSAGE IN IOUT BLOCK
9C2N ... MHUNT 3,APERI,APROPS
9C2X ... CALL 4 SMVPROPS [MOVE PROPERTIES TO IOUT BLOCK
9C36 ... ELSE
9C3* ... CALL 6 SMESSAGE
9C3J ... SMO FX1
9C3R ... LDN 1 PMESSC
9C42 ... MVCH 1 4
9C49 ... LDN 5 4
9C4D ... FI
9C4M ... MHUNTW 3,AMXOR,IOUT
9C4W ... SBN 5 49
9C55 ... IF 5,PZ
9C5# ... THEN
9C5H ... LDN 1 IDATA+7(3)
9C5Q ... LDN 4 #27
9C5^ ... DCH 4 0(1)
9C68 ... LDX 2 1
9C6C ... BCHX 2 £
9C6L ... ADN 1 1
9C6T ... ADN 5 63
9C74 ... SMO 5
9C7? ... MVCH 1 0
9C7G ... FI
9C7P ... SMO FX1
9C7Y ... LDN 1 PTERM
9C87 ... MVCH 1 4
9C8B ... SBN 2 IDATA(3)
9C8K ... SLC 2 2
9C8S ... DSA 2 IPBIDE+1(3)
9C93 ... ADN 2 IDATA-A1*4+3
9C9= ... SRL 2 2
9C9F ... ALTLEN 3,2
9C9K ... FI
9C9P ... UP
9C9X ...[
9C?Q [
9CRB [************************************************************
9D?2 [
9DQL [ BREAKIN LABEL
9F== [
9FPW [************************************************************
9G9G [
9GP6 ZBRKIN
9H8Q UP
9HNB [
9J82 [
9JML #END
^^^^ ...051400520004