{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: WHATRVSA867)}}
====== WHATRVSA867 ======
(George Source)
**Macros used:** [[george:macro:ABANDCOM|ABANDCOM]], [[george:macro:AND|AND]], [[george:macro:APPEND|APPEND]], [[george:macro:ASSMESS|ASSMESS]], [[george:macro:BS|BS]], [[george:macro:BSON|BSON]], [[george:macro:BXE|BXE]], [[george:macro:BXGE|BXGE]], [[george:macro:BXL|BXL]], [[george:macro:BXU|BXU]], [[george:macro:CLOSE|CLOSE]], [[george:macro:CONSERNO|CONSERNO]], [[george:macro:COOR3|COOR3]], [[george:macro:DO|DO]], [[george:macro:ELSE|ELSE]], [[george:macro:ELSF|ELSF]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:ERASE|ERASE]], [[george:macro:ERASEWORK|ERASEWORK]], [[george:macro:FI|FI]], [[george:macro:FON|FON]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FRIGMONF|FRIGMONF]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HUNT|HUNT]], [[george:macro:HUNTACTJ|HUNTACTJ]], [[george:macro:IF|IF]], [[george:macro:INSERT|INSERT]], [[george:macro:ISSUCOMB|ISSUCOMB]], [[george:macro:JBC|JBC]], [[george:macro:JBS|JBS]], [[george:macro:JMBAS|JMBAS]], [[george:macro:JMBS|JMBS]], [[george:macro:JOBLOCK|JOBLOCK]], [[george:macro:LOBSFILE|LOBSFILE]], [[george:macro:MFREE|MFREE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUTX|MONOUTX]], [[george:macro:NAME|NAME]], [[george:macro:OFF|OFF]], [[george:macro:ON|ON]], [[george:macro:OR|OR]], [[george:macro:OUTMESS|OUTMESS]], [[george:macro:OUTMON|OUTMON]], [[george:macro:OUTNUM|OUTNUM]], [[george:macro:OUTPARAM|OUTPARAM]], [[george:macro:PROPERTY|PROPERTY]], [[george:macro:READ|READ]], [[george:macro:REPEAT|REPEAT]], [[george:macro:REWIND|REWIND]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:STEP|STEP]], [[george:macro:TESTBRKIN|TESTBRKIN]], [[george:macro:TESTREP2|TESTREP2]], [[george:macro:TESTRPN2|TESTRPN2]], [[george:macro:THEN|THEN]], [[george:macro:TRACE|TRACE]], [[george:macro:UNNORM|UNNORM]], [[george:macro:USEROPEN|USEROPEN]], [[george:macro:VFREE|VFREE]], [[george:macro:WHILE|WHILE]], [[george:macro:WSRV|WSRV]]
22FL SEG WHATRVSA,866,J.K.PROTHEROUGH
22^= [
23DW [ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
23YG [
24D6 SEGENTRY K1WHATRVSA,X1WHATRVSA
24XQ [
25CB [IMPLEMENTS THE WHATRVS COMMAND TO OBTAIN A LIST OF
25X2 [OUTSTANDING RETRIEVE REQUESTS
26BL [
26W= [
27*W [
27TG [MONITORING FILE MESSAGES
288M ...WVIMPL +JWVIMPL
28HS ...WVTITLE +JWVTITLE
28W^ ...WVJOB1 +JWVJOB1
29=6 ...WVJOB2 +JWVJOB2
29K? ...WVFIL +JWVFILE
29YD ...WVNJR +JWVNJR
2=?L WTERM +JWVTERM
2=R= WNOUT +JWVNOUT
2?=W WCOUNTMESS +JWVCOUNT
2?QG MAXSELEC +7
2#=6 SEGENTRY K90WHATRVSA
2#PQ WVOLIM +100
2*9B [DEFAULT LIMIT ON RV REQUESTS OUTPUT TO OPS CONSOLE
2*P2 [ALTERED BY RESTORE TIME MACRO WVOUTLIM
2B8L
2BN= MAGIC 7036875
2C7W SPACES #20202020
2CMG PSTRJOBNO 8HJOBNO
2D76 PSTRCOLON 4H:
2DLQ PSTRALL 8HALL
2F6B PSTRFULL 8HFULL
2FL2 PSTRUSER 8HUSER :
2G5L PSTRHERE 8HHERE
2GK= PSTRLIST 8HLIST
2H4W PROPERTY 8HPROPERTY
2HJG PRJBRAC 1H)
2J46 PRJPROP 9H,PARAM(PR
2JHQ PRUNJOB 36HRJ WVLIST0000,:OPERATORS,WVLISTJDF
2K3B PLF 17HLF !,*LP,PA,MO#60
2KH2 PLFPROP 3H,PR
2L2L P10000 +10000
2LG= PVAL2 +2
2L^W PVAL4 +4
2MFG PFILEDES 10
2M^6 POPERATORS 12HOPERATORS
2NDQ 12HWHATRVS
2NYB 1
2PD2 #20000001
2PXL 4HB1
2QC=
2QWW [
2RBG [
2RW6 [
2S*Q X1WHATRVSA
2SC^ ...[
2SG8 ...[ PICK UP OPS CONSOLE PRINT LIMIT
2SJC ...[
2SLL ... LDX 0 WVOLIM(1)
2SNT ... STO 0 AWORK2(2)
2SR4 ...[
2STB [SET UP AND OPEN OUTPUT FILE
2T*2 [
2TSL [
2W#= MHUNT 2,ADATA,AWHATRVS
2WRW IF BS,2,AWVBFULL
2X?G THEN
2XR6 IF BS,2,AWVBOPER [IF OPERATOR CONTEXT
2Y=Q THEN
2YQB LDN 1 POPERATORS(1) [CREATION OF FILE REQUIRES
2^=2 SMO FX2 [OWNERSHIP SO INSERT
2^PL LDN 2 CPREFIX [:OPERATORS IN CPAT
329= MOVE 1 3
32NW SETNCORE 10,3,FILE,FABSNB
338G LDN 1 PFILEDES(1)
33N6 LDN 2 A1(3)
347Q MOVE 1 10
34MB USEROPEN ZOUTFILEBRK,GENERAL,CREATE,LEAVE,FROZEN
3572 TESTRPN2 OK,ZERROW
35LL MHUNT 3,FILE,ENT
366= LDX 0 EGEN(3)
36KW STO 0 AWORK1(2) [RETAIN GEN.NO.
375G TRACE 0,WVGEN
37K6 FREECORE 3
384Q ELSE [OPEN WORKFILE
38JB FRIGMONF ZERROW,1 [FOR OPERATOR COMMAND
3942 LOBSFILE
39HL FI
3=3= MFREE FILE,FABSNB
3=DL ...[
3=W2 ...[ INSERT TITLE IN FILE
3??B ...[
3?NQ ... SMO FX1
3#66 ... LDX 6 WVTITLE
3#HG ... CALL 7 SAPPEND
3#^2 [
3*39 ... FI
3*5D ... LDX 2 BOLC [START OF OFFLINE CHAIN
3*7M ... LDN 0 BOLC
3*9W ... LDX 2 0(2)
3*#5 ... BXE 0 2,NENDED [JUMP IF EMPTY CHAIN
3*B# ...[
3*DL [
3*Y= [PROCESS OFFLINE CHAIN
3BCW [
3BXG [
3CC6 [OBTAIN JOBNO FROM :USERNAME.JOBNAME IF GIVEN
3CWQ [
3DBB LDX 2 BJOBQ [START OF JOB QUEUE
3DW2
3F*L MHUNT 3,ADATA,AWHATRVS
3FT= JMBAS NFRIG,3,AWVBHERE,AWVBOPER
3G#W LDN 0 4000 [VERY HIGH LIMIT ON OUTPUT
3GSG ... SMO FX2 [IF NOT OPS CONSOLE
3H#6 ... STO 0 AWORK2
3HRQ NFRIG
3J3J ... SMO FX2 [IMPLICIT RV INDIC
3J?B ... STOZ AWORK4
3JH8 ... JMBS NAROUND,3,AWVBALL,AWVBJOBNO,AWVBUSER
3JR2 NLOOK
3K=L STO 3 5
3KQ= STO 2 6
3L9W ADN 3 AWVUSERNAM
3LPG ADN 2 JUSER [LENGTH OF STRING TO BE COM ARED
3M96
3MNQ LDN 0 3
3N8B CALL 7 NAMESAME [COMPARE USERNAME IN JOB BLO
3NN2 NOTSAME
3P7L BRN NOMATCH
3PM= MATCH
3Q6W LDX 3 5
3R66 LDX 2 6
3RKQ ADN 3 AWVJOBNAM
3S5B ADN 2 JNAME
3SK2 LDN 0 3
3T4L CALL 7 NAMESAME [COMPARE JOB NAMES
3TJ= BRN NOMATCH
3W3W LDX 3 5
3WHG LDX 2 6
3X36 LDX 4 JOBNUM(2)
3XGQ TRACE 4,WVJOBNO
3Y2B STO 4 AWVJOBNO(3) [SAVE JOBNO IN ADATA AWHATRVS
3YG2 BS 3,AWVBJOBNO [SET JOBNO GIVEN BIT
3Y^L BRN NAROUND
3^F= NOMATCH
3^YW LDX 3 5
42DG LDX 2 6
42Y6 LDX 2 0(2) [NEXT JOB BLOCK
43CQ LDN 0 BJOBQ
43XB TRACE 2,WVNOJOB
44C2 BXU 0 2,NLOOK [CHECK NEXT BLOCK
44WL ... BRN NSUCHJ
45TW NAROUND
46*G STOZ 4
46T6 STOZ 5
47#Q STOZ 6 [X4,5,6 HOLD FREQ DETAILS
47SB [ZERO ON FIRST ENTRY
48#2 NEXTFREQ
48RL TRACE 4,WVINC
49?= CALL 7 NSEARCH [LOCATE NEXT FREQ
49QW ... BRN NDONE [ALL FREQS PROCESSED
4==G
4=Q6 NFLOC
4?9Q LDX 7 2 [SAVE FREQ POINTER
4?PB TRACE 7,WVFREE
4#92 VFREE FILE,FINTER
4#NL LDX 2 7
4*8= LDX 7 ALOGLEN(2) [X2 POINTS TO FREQ
4*MW SETUPCORE 7,3,FILE,FINTER
4B7G CALL 7 SEARCH [REFIND FREQ
4BM6 BRN NENDED [ALL FREQS PROCESSED
4BQK ... BRN NFLOC2 [DIFFERENT FREQ FOUND
4BW4 ... BRN NFOUND
4B^H ...NFLOC2
4C52 ... LDX 4 FDTINCNUM(2) [RESET X4,5,6 ON NEXT FREQ
4C8F ... LDX 5 FDTFILNUM(2)
4C?Y ... LDX 6 FDTFILSTR(2)
4CCC ... BRN NFLOC
4CGW ...NFOUND
4CLB LDX 1 ALOGLEN(2)
4D62 ADN 2 A1
4DKL ADN 3 A1
4F5= TRACE 4,WVJOBNO2
4FJW MOVE 2 0(1) [COPY FREQ TO FINTER
4G4G SBN 3 A1
4GJ6 LDX 2 3 [USE FINTER FOR REST OF ROCESS
4H3Q [
4HHB [FREQ BLOCK IS NOW COPIED TO FILE FINTER
4J32 [
4KFW MHUNTW 3,ADATA,AWHATRVS
4K^G JBS NALLSPEC,3,AWVBALL
4L9# ... JBS NUSER,3,AWVBUSER
4LF6 LDX 5 FREVCT(2) [COUNT OF JOBNOS
4LYQ BZE 5 NFREQ
4MDB NJOBNO2
4MY2 LDX 1 5
4NCL SMO 1
4NX= LDX 4 FREVCT(2) [PICK UP JOBNO LAST FIRST
4PBW SBN 1 1 [DECREMENT JOBNO OINTER
4PWG STO 1 FREVCT(2) [IN FINTER
4QB6 JBS NJOBNOS,3,AWVBJOBNO
4QTQ STO 4 AWVJOBNO(3)
4R*B ... BRN NALROP
4RT2 ...NUSER
4S#L ... LDN 0 3
4SS= ... ADN 2 FFUSER1
4T?W ... ADN 3 AWVUSERNAM
4TRG ... CALL 7 NAMESAME
4W?6 ... BRN NFREQ [ NO MATCH
4WQQ ... MHUNTW 3,ADATA,AWHATRVS [USERNAMES MATCH
4X=B ...NALLSPEC
54L= [
555W [OBTAIN TSN FOR GIVEN FILE
55KG [
5656 MHUNTW 2,FILE,FINTER
56JQ JBC NOTFULL,3,AWVBFULL
574B LDX 5 FDTFILSTR(2)
57J2 LDX 7 FDTINCNUM(2)
583L LDX 4 FDTFILNUM(2)
58?D ...NIMPLRV
58H= SETNCORE 20,3,ADATA,CREADL
592W STOZ A1(3)
59GG SETNCORE 10,3,FILE,FABSNB
5=26 LDN 6 10
5=FQ STO 6 A1(3)
5=^B WSRV 7,4,5,6,4,ZFREQLOST [X4-TSN,X6-FREQ FILENAME
5?F2 [
5?YL [ADD FILE :USERNAME.FILENAME TSN......TO THE FILE
5#D= [
5#XW LDX 2 6
5*CG ADN 3 A1+1
5*X6 TRACE 4,WVTSN
5BBQ MOVE 2 9
5BWB UNNORM TWO
5CB2 MHUNTW 3,ADATA,CREADL
5CCC ... LDN 1 A1+2(3) [REMOVE / FROM FILENAME
5CD* ... LDN 6 #37
5CF? ... LDX 0 A1(3)
5CG9 ... SBN 0 1
5CH7 ...NCV1
5CJ5 ... LDCH 2 0(1)
5CK3 ... BXE 2 6,NCV2
5CK^ ... BCHX 1 £
5CLX ... BCT 0 NCV1
5CMT ...NCV2
5CNR ... LDN 2 #31
5CPP ... DCH 2 0(1)
5CQM ... LDX 1 A1(3)
5CRK ... SBX 1 0
5CSH ... STO 1 A1(3)
5CTL OUTPARAM A1(3),CPDATA,ADATA,CREADL
5D*= MFREE ADATA,CREADL
5DSW MFREE FILE,FABSNB
5F#G SETNCORE 5,3,ADATA,CREADL
5FS6 CONSERNO 4
5G?Q [CONVERT TSN TO CHARS
5GRB MHUNTW 2,FLIB,FTSN
5H?2 MHUNTW 3,ADATA,CREADL
5HQL LDN 2 A1(2)
5J== LDN 3 A1(3)
5JPW MOVE 2 3
5K9G SBN 3 A1
5KP6 TRACE A1+1(3),WVCTSN
5L8Q OUTPARAM A1(3),A1+1,ADATA,CREADL
5LNB MFREE ADATA,CREADL
5M82 MFREE FLIB,FTSN
5MML ... LDX 6 WVFIL(1)
5N7= CALL 7 SAPPEND
5N#D ... LDX 7 AWORK4(2) [IMPL RV FOR JOB
5NFL ... BNZ 7 NDN2
5NLW NOTFULL
5P6G MHUNTW 2,ADATA,AWHATRVS
5PL6 LDN 7 1 [INCREMENT COUNT OF RVS FOUND
5Q5Q ADS 7 AWVCOUNT(2)
5QKB TRACE AWVCOUNT(2),WVCOUNT
5R52 JBC NFREQ,2,AWVBFULL
5RJL ... JMBS NFIRST,2,AWVBALL,AWVBUSER
5S4= JBS NFREQ,2,AWVBJOBNO
5SHW [
5T3G [ADD RV BY :USERNAME.JOBNAME LINE TO FILE
5TH6 [
5W2Q NALROP
5WGB SETNCORE 20,3,ADATA,CREADL
5X22 STOZ A1(3)
5XFL SETNCORE 10,3,FILE,FABSNB
5X^= LDN 7 10
5YDW STO 7 A1(3)
5YYG ADN 3 A1+1
5^D6 MHUNTW 2,ADATA,AWHATRVS
5^XQ LDX 4 AWVJOBNO(2)
62CB JOBLOCK 4,7
62X2 BNG 7 NJOBNOF
63BL TRACE 5,WVNALROP
63W= LDX 2 7
64*W ADN 2 JUSER
64TG MOVE 2 3
65*6 LDX 2 7
65SQ ADN 3 3
66#B ADN 2 JNAME
66S2 MOVE 2 3
67?L ADN 3 3
67R= SMO FX1
68=W LDX 2 SPACES
68QG ... STOZ 0(3)
69=6 ... STOZ 1(3)
69PQ STO 2 2(3)
6=9B UNNORM TWO
6=P2 MHUNTW 3,ADATA,CREADL
6=SX ... LDX 2 A1(3)
6=YS ... SBN 2 3
6?4P ... STO 2 A1(3)
6?8L OUTPARAM A1(3),CPDATA,ADATA,CREADL
6?N= MFREE ADATA,CREADL
6#7W MFREE FILE,FABSNB
6#MG ... LDX 6 WVJOB1(1)
6*76 CALL 7 SAPPEND
6*LQ BRN NJOBNO
6B6B [
6BL2 NJOBNOF
6C5L MFREE ADATA,CREADL
6CK= MFREE FILE,FABSNB
6CNB ...NJNUM
6CRG ... OUTNUM 4,0
6CWL ... LDX 6 WVJOB2(1)
6C^Q ... CALL 7 SAPPEND
6D4W NJOBNO
6DJG MHUNTW 2,FILE,FINTER [RESET ON CO Y OF FREQ
6F46 LDX 5 FREVCT(2) [COUNT OF JOBNOS LEFT TO ROCESS
6FHQ TRACE 5,WVJOBCT
6G3B BZE 5 NFREQ2
6G?8 ...NALLN
6GH2 MHUNTW 3,ADATA,AWHATRVS
6H2L BRN NJOBNO2
6H4* ...NFIRST
6H64 ... MHUNTW 2,FILE,FINTER
6H7R ... LDX 5 FREVCT(2)
6H9G ... BNZ 5 NALLN
6H?9 ...NIMP
6H#Y ... SMO FX1
6HBM ... LDX 6 WVIMPL
6HDB ... CALL 7 SAPPEND
6HG= NFREQ
6H^W MHUNTW 2,FILE,FINTER
6JFG NFREQ2
6J^6 LDX 4 FDTINCNUM(2) [INCREMENT
6KDQ LDX 5 FDTFILNUM(2) [FILNUMBER
6KYB LDX 6 FDTFILSTR(2) [FILESTORE NO
6LD2 TRACE 4,WVNINC
6LXL BRN NEXTFREQ
6MC= NJOBNOS
6MWW BXU 4 AWVJOBNO(3),NJOBNO
6NBG TRACE 4,WVJNUM
6NW6 BRN NALLSPEC
6P*Q [
6PTB [
6Q*2 [
6Q*M ...NDONE
6QB# ... MHUNTW 2,ADATA,AWHATRVS
6QB^ ... JBC NNJO,2,AWVBJOBNO
6QCL ... LDX 4 AWVJOBNO(2)
6QD? ... HUNTACTJ CPAT,4,3,NNJO [LOCATE JOB ACTY BLOCK
6QDY ... LDEX 5 ATYPE(3)
6QFK ... SBN 5 #24
6QG= ... BNZ 5 NNJO [WAITING FOR RV
6QGX ... LDN 7 1
6QHJ ... ADS 7 AWVCOUNT(2)
6QJ9 ... JBC NNJO,2,AWVBFULL
6QJW ... SMO FX2
6QKH ... STO 7 AWORK4 [SET IMPL RV INDIC
6QL8 ... LDX 7 ACC4(3) [INCREMENT
6QLT ... LDX 4 ACC5(3) [FILE NO
6QMG ... LDX 5 ACC6(3) [FILESTORE
6QN7 ... BRN NIMPLRV
6QNS ...NDN2
6QPF ... STOZ AWORK4(2)
6QQ6 ...NNJO
6QQR ...[
6QRD ...[
6QSL NENDED
6R#= [
6RRW [ ALL FREQS DEALT WITH
6S?G [
6SR6 [LIST OUTPUT FILE
6T=Q [
6TQB MHUNTW 2,ADATA,AWHATRVS
6W=2 IF +AWVCOUNT(2),NZ
6WPL THEN
6X9= OUTNUM AWVCOUNT(2),0
6XNW ELSE
6Y8G OUTMESS JWVNOUT [NO OUTSTANDING RVS
6YN6 FI
6^7Q LDX 6 WCOUNTMESS(1)
6^MB HUNT 2,ADATA,CREADL
7272 IF 2,PZ [SELECTION DETAILS
72LL THEN
736= OUTPARAM A1(2),A1+2,ADATA,CREADL
73KW MFREE ADATA,CREADL
745G FI
74K6 MHUNTW 2,ADATA,AWHATRVS
754Q IF +AWVCOUNT(2),ZE [NO OUTSTANDING RVS
75JB THEN
7642 MONOUTX 6
76HL ELSF BS,2,AWVBLIST [FULL LIST SPECIFIED
773= THEN
77GW REWIND
782G STEP
78G6 CALL 7 SINSERT [INSERT COUNT MESSAGE IN FILE
78^Q MHUNT 2,ADATA,AWHATRVS
79FB STOZ 7
79^2 IF BS,2,AWVBLISTPR [LIST(PR..)
7=DL THEN
7=Y= MHUNT 2,CPB,CUNI
7?CW LDEX 7 ANUM(2)
7?XG FI
7#C6 ADN 7 CPDATA-A1*4+51
7#WQ SRL 7 2
7*BB SETUPCORE 7,3,ADATA,CREADL
7*W2 MHUNTW 2,ADATA,AWHATRVS
7B*L IF BS,2,AWVBOPER
7BT= THEN [OPERATOR CONTEXT
7C#W LDN 5 PRUNJOB(1)
7CSG LDN 6 CPDATA(3)
7D#6 MVCH 5 36
7DRQ IF BS,2,AWVBLISTPR [PROPERTY GIVEN
7F?B THEN
7FR2 LDN 5 PRJPROP(1)
7G=L MVCH 5 9 [,PARAM(PR
7GQ= MHUNT 2,CPB,CUNI
7H9W LDN 5 APARA(2)
7HPG LDEX 2 ANUM(2)
7J96 MVCH 5 0(2) [PROPERTY STRING
7JNQ LDN 5 PRJBRAC(1)
7K8B MVCH 5 1
7KN2 FI
7L7L LDX 2 FX2
7LM= LDX 4 AWORK1(2) [GEN NO OF :OPERATORS.WHATRVS
7M6W LDN 5 0
7MLG DVR 4 P10000(1)
7N66 LDX 4 5
7NKQ LDCT 5 #200
7P5B LDN 1 CPDATA+2(3)
7PK2 BCHX 1 £
7Q4L LDN 0 4
7QJ= DO [CONVERT GENERATION NO
7R3W CBD 4 0(1) [INTO JOBNAME IN RJ
7RHG BCHX 1 £
7S36 REPEAT CT 0
7SGQ SBN 6 CPDATA(3)
7T2B SLC 6 2
7TG2 STO 6 A1(3)
7T^L LDX 5 GSIGN [FOR SYSTEM ISSUED CONTEXT
7WF= ORS 5 CONTEXT(2)
7WYW ISSUCOMB XCOMERRJ,XCOMERRJ
7XDG XCOMERRJ
7XY6 ERS 5 CONTEXT(2)
7YCQ ELSE [LIST WORKFILE
7YXB [OPERATOR COMMAND
7^C2 LDN 5 PLF(1)
7^WL LDN 6 CPDATA(3)
82B= MVCH 5 17
82TW IF BS,2,AWVBLISTPR [PROPERTY GIVEN
83*G THEN
83T6 LDN 5 PLFPROP(1)
84#Q MVCH 5 3
84SB MHUNT 2,CPB,CUNI
85#2 LDN 5 APARA(2)
85RL LDEX 2 ANUM(2)
86?= MVCH 5 0(2)
86QW FI
87=G SBN 6 CPDATA(3)
87Q6 SLC 6 2
889Q STO 6 A1(3)
88PB ISSUCOMB XCOMERLF,XCOMERLF
8992 XCOMERLF
89NL FI
8=8= ELSF BS,2,AWVBHERE [FULL HERE GIVEN
8=MW THEN
8?7G SMO FX2
8?M6 STO 6 AWORK3 [SAVE COUNT MESSAGE
8#6Q IF BS,2,AWVBOPER [IF OPERATOR CONTEXT
8#LB THEN
8*62 XLOCK
8*KL [IF CONSOLE FREE
8B5= BSON AWHATBIT,WAIT
8BJW [THEN LOCK OUT CONSOLE
8C4G ON AWHATBIT
8CJ6 BRN XLOCKED
8D3Q WAIT
8DHB COOR3 #114
8F32 BRN XLOCK
8FGL FI
8G2= XLOCKED
8GFW SMO FX2
8G^G LDX 6 AWORK3 [RESET X6 COUNTMESSAGE
8HF6 MONOUTX 6
8HYQ REWIND
8J8J ... STOZ 5
8JDB WHILE TRUE
8JY2 READ
8KCL MHUNT 3,FILE,FRB
8KX= LDX 0 ALOGLEN(3)
8LBW SBN 0 1
8LWG ORX 0 A1(3)
8MB6 AND 0,NZ [NOT END OF FILE
8MTQ DO
8N*B TESTBRKIN ZHEREBRK
8NT2 LDEX 6 A1+FRH(3)
8P#L SLL 6 2
8PS= SBN 6 8
8Q?W OUTMON 6,A1+FRH+2,A1+FRH+1(3),FILE,FRB
8QRG MFREE FILE,FRB
8R?6 ... ADN 5 1
8RQQ ... LDX 1 FX2
8S=B ... BXGE 5 AWORK2(1),NTERM
8SQ2 REPEAT
8T9L BRN NNTERM
8TP=
8W8W NTERM SMO FX1
8WNG LDX 6 WTERM
8X86 MONOUTX 6 [OUTPUT TERMINATED MESSAGE
8XMQ NNTERM
8Y7B MHUNT 2,ADATA,AWHATRVS
8YM2 IF BS,2,AWVBOPER
8^6L THEN
8^L= OFF AWHATBIT [RELEASE CONSOLE
925W FON #114
92KG FI
9356 ELSE [NOT FULL LIST
93JQ MONOUTX 6 [OUTPUT COUNT MESSAGE
944B FI
94J2 BRN XCLOSEF
953L NSUCHJ
95H= ... MHUNTW 2,ADATA,CREADL
962W ... OUTPARAM A1(2),A1+2,ADATA,CREADL [SELECTION DETAILS
96GG ... LDX 6 WVNJR(1)
9726 ... MONOUTX 6
97FQ ... BRN XCLOSEF
99D= XCLOSEF
99XW CALL 7 SCLOSE
9=X6 ENDCOM
9?BQ [
9?WB
9#B2 [
9#TL [
9**= [********************************************************************
9*SW [
9B#G [SUBROUTINE NSEARCH
9BS6 [
9C?Q [LOCATE NEXT FREQ BLOCK IN OFFLINE CHAIN
9CRB [
9D?2 NSEARCH
9DQL [
9F== LDX 1 7
9FPW CALL 7 SEARCH
9G9G BRN NENDCH [END OF OFFLINE CHAIN
9GP6 BRN NEXTF [POINTS TO NEXT FREQ
9H8Q LDN 0 BOLC
9HNB LDX 2 0(2)
9J82 BXE 2 0,NENDCH
9JML NEXTF
9K7= LDX 4 FDTINCNUM(2)
9KLW LDX 5 FDTFILNUM(2)
9L6G LDX 6 FDTFILSTR(2)
9LL6 LDX 7 1
9M5Q EXIT 7 1
9MKB NENDCH
9N52 LDX 7 1
9NJL EXIT 7 0
9P4= [
9PHW [
9Q3G [SUBROUTINE NAMESAME
9QH6 [
9R2Q [X0 CONTAINS LENGTH OF STRING TO BE COMPARED
9RGB [
9S22 NAMESAME
9SFL DO
9S^= LDX 4 0(2)
9TDW BXU 4 0(3),NAMEFAIL
9TYG ADN 2 1
9WD6 ADN 3 1
9WXQ REPEAT CT 0
9XCB EXIT 7 1
9XX2
9YBL NAMEFAIL
9YW= EXIT 7 0
9^*W [
9^TG [SUBROUTINE 'SINSERT'
=2*6 [ INSERTS A MESSAGE INTO THE OUTPUT FILE
=2SQ [ LINK X7, MESSAGE IDENT IN X6
=3#B [
=3S2 SINSERT
=4?L SBX 7 FX1
=4R= ASSMESS 6
=5=W MHUNT 3,GMON,AOUT
=5QG NAME 3,FILE,FWB
=6=6 LDEX 0 A1+FRH(3) [CONVERT MESSAGE
=6PQ ADN 0 11 [LENGTH IN CHARS
=79B SRL 0 2 [TO REC HEADER
=7P2 DEX 0 A1+FRH(3)
=88L INSERT
=8N= MFREE FILE,FWB
=97W ADX 7 FX1
=9MG EXIT 7 0
==76 [
==LQ [SUBROUTINE 'SAPPEND'
=?6B [ INSERTS A MESSAGE INTO THE OUTPUT FILE
=?L2 [ LINK X7, MESSAGE IDENT IN X6
=#5L [
=#K= SAPPEND
=*4W SBX 7 FX1
=*JG ASSMESS 6
=B46 MHUNT 3,GMON,AOUT
=BHQ NAME 3,FILE,FAPB
=C3B LDEX 0 A1+FRH(3) [CONVERT MESSAGE
=CH2 ADN 0 11 [LENGTH IN CHARS
=D2L SRL 0 2 [TO REC HEADER
=DG= DEX 0 A1+FRH(3)
=D^W APPEND ,ZAPPBRK
=FFG MFREE FILE,FAPB
=F^6 ADX 7 FX1
=GDQ EXIT 7 0
=GYB [
=HD2 [SUBROUTINE SEARCH
=HXL [RELOCATE FREQ BLOCK IN OFFLINE CHAIN
=JC= [
=JWW [ X4-INCREMENT
=KBG [X5-FILE NO X6-FILESTORE NO FROM PREVIOUS FREQ DEALT WITH, ZERO
=KW6 [ ON FIRST ENTRY
=L*Q [
=LTB SEARCH
=M*2 LDX 2 BOLC
=MSL LDN 0 BOLC
=N#= NS1
=NRW LDX 2 0(2)
=P?G BXE 2 0,NEND
=PR6 BXL 4 FDTINCNUM(2),NMISS [J IF INC NOT THERE
=Q=Q BXU 4 FDTINCNUM(2),NS1 [J IF INC NOT YET REACHED
=QQB BXL 6 FDTFILSTR(2),NMISS [J IF FILESTORE NOT THERE
=R=2 BXU 6 FDTFILSTR(2),NS1 [J IF FILESTORE NOT YET REACHED
=RPL
=S9= BXL 5 FDTFILNUM(2),NMISS [J IF FILE NOT THERE
=SNW BXU 5 FDTFILNUM(2),NS1 [J IF FILE NOT YET REACHED
=T8G [
=TN6 EXIT 7 2 [X2 POINTS TO FREQ
=W7Q NMISS
=WMB [X2 POINTS TO NEXT FREQ
=X72 EXIT 7 1 [X2 POINTS TO NEXT FREQ
=XLL
=Y6= NEND
=YKW [END OF OFFLINE CHAIN
=^5G EXIT 7 0
=^K6 [
?24Q [
?2JB [
?342 [SUBROUTINE 'SCLOSE'
?3HL [
?43= [CLOSE OUTPUT FILE
?4GW [
?52G SCLOSE
?5G6 SBX 7 FX1
?5^Q MHUNT 2,ADATA,AWHATRVS
?6FB IF MBS,2,AWVBLIST,AWVBHERE [OUTPUT FILE EXISTS
?6^2 THEN
?7DL IF BS,2,AWVBOPCOM [OPERATOR COMMAND
?7Y= THEN [ERASE WORKFILE
?8CW SETNCORE 10,3,FILE,FABSNB
?8XG LDN 0 10
?9C6 STO 0 A1(3)
?9WQ LDX 2 BWORKRING(2)
?=BB ADN 2 FUSER1
?=W2 ADN 3 A1+1
??*L MOVE 2 9
??T= ERASEWORK 1
?##W TESTREP2 NOFILE,ZERREOW
?#SG ELSE
?*#6 LDX 0 AWVCOUNT(2)
?*RQ IF EITHER,0,ZE [FILE EMPTY
?B?B OR BS,2,AWVBHERE [HERE
?BR2 THEN
?C=L SETNCORE 10,3,FILE,FABSNB
?CQ= LDN 1 PFILEDES(1)
?D9W LDN 2 A1(3)
?DPG MOVE 1 10
?F96 SMO FX2
?FNQ LDX 0 AWORK1
?G8B STO 0 A1+8(3) [GEN NO
?GN2 ERASE
?H7L TESTREP2 NOFILE,ZERREOW
?HM= FI
?J6W FI
?JLG CLOSE
?K66 FI
?KKQ ADX 7 FX1
?L5B EXIT 7 0
?LK2
?M4L
?MJ=
?N3W
?NHG
?P36
?PGQ [
?Q2B ZFREQLOST
?QG2 MFREE FILE,FABSNB
?Q^L MFREE ADATA,CREADL
?RF= BRN NFREQ
?RYW ZOUTFILEBRK
?SDG ABANDCOM
?SY6 ZERROW
?TCQ GEOERR 1,WVOPEN [ERROR OPENING OP FILE
?TXB ZERREOW
?WC2 GEOERR 1,WVERASE [ERROR ERASING OP FILE
?WWL [
?XB= [
?XTW ZHEREBRK [BREAKIN DURING HERE OP
?Y*G [
?YT6 OFF AWHATBIT [RELEASE CONSOLE
?^#Q FON #114
?^SB ZAPPBRK
#2#2 CALL 7 SCLOSE
#2RL ABANDCOM
#3?= #END
^^^^ ...332575240006