{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: WHTSTAT867)}}
====== WHTSTAT867 ======
(George Source)
**Macros used:** [[george:macro:ABANDCOM|ABANDCOM]], [[george:macro:BITDEFS|BITDEFS]], [[george:macro:BRUSEN|BRUSEN]], [[george:macro:BSOFF|BSOFF]], [[george:macro:CHARMOVE|CHARMOVE]], [[george:macro:CLOSE|CLOSE]], [[george:macro:COMERR|COMERR]], [[george:macro:COOR3|COOR3]], [[george:macro:CREATEB|CREATEB]], [[george:macro:DOWN|DOWN]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:ERASE|ERASE]], [[george:macro:ERASEWORK|ERASEWORK]], [[george:macro:FON|FON]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FRIGMONF|FRIGMONF]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:GEOERR|GEOERR]], [[george:macro:ISSUCOMB|ISSUCOMB]], [[george:macro:JBS|JBS]], [[george:macro:LOBSFILE|LOBSFILE]], [[george:macro:MFREE|MFREE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:OFF|OFF]], [[george:macro:ON|ON]], [[george:macro:OPSCON|OPSCON]], [[george:macro:OUTMON|OUTMON]], [[george:macro:PREP|PREP]], [[george:macro:READ|READ]], [[george:macro:REWIND|REWIND]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:SPARABEG|SPARABEG]], [[george:macro:TESTBRKIN|TESTBRKIN]], [[george:macro:TESTREP|TESTREP]], [[george:macro:TESTRPN2|TESTRPN2]], [[george:macro:USEROPEN|USEROPEN]]
22FL #LIS K0WHTSTAT>K0ALLGEO>K0GREATGEO>K0COMMAND
22^= ... SEG WHTSTAT,867,SECTION CENT
23YG [
244C ...[
248# ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
24#9 ...[
24D6 [ THIS SEGMENT IMPLEMENTS THE 'WS' COMMAND
24XQ [
25CB SEGENTRY K1WHTSTAT,Q1ENTRY
25F# ... FSHENTRY K2WHTSTAT,Q2ENTRY,,Q2ENTRY
25H= ... FSHENTRY K3WHTSTAT,,Q3ENTRY,Q3ENTRY
25K8 ... FSHENTRY K4WHTSTAT,,Q4ENTRY,Q4ENTRY
25L8 ... FSHENTRY K5WHTSTAT,Q5ENTRY,,Q5ENTRY
25LN ... FSHENTRY K7WHTSTAT,,Q7ENTRY,Q7ENTRY
25M8 ... BITDEFS ZGG,23,OPLIST
25X2 [ DEFINES THE CQPRINT/CQ1 BLOCK
26BL #DEF ZGA = A1 [GROUP A INDICATORS
26W= #DEF ZGB = ZGA+1 [GROUP B INDICATORS
27*W #DEF ZGC = ZGB+1 [GROUP C INDICATORS
27TG #DEF ZGD = ZGC+1 [GROUP D INDICATORS
28*6 #DEF ZGE = ZGD+1 [GROUP E INDICATORS
28SQ #DEF ZGF = ZGE+1 [GROUP F INDICATORS
29#B #DEF ZGG = ZGF+1 [GROUP G INDICATORS
29S2 #DEF ZGH = ZGG+1 [GROUP H INDICATORS
2=?L #DEF ZNAME = ZGH+1 [JOB NAME
2=R= #DEF ZUSER = ZNAME+3 [USER NAME
2?=W #DEF ZPROP = ZUSER+3 [PROPERTY NUMBER
2?QG #DEF ZLCOUNT= ZPROP+1 [COUNT OF JOB NOS. STORED
2#=6 #DEF ZLJOB = ZLCOUNT+1 [JOB NUMBER
2#PQ PRINTO 37HRJ WSLIST ,:OPERATORS,WSLISTJDF
2*9B PRINTU 22HLF !,*LP,PA,MONFILE#40
2*P2 PRINTP 7H,PARAM(
2B8L PRINTQ 3H,PR
2BN= WFILE +10
2C7W 12HOPERATORS
2CMG 12HWHATSTATE
2D76 1
2DLQ #20000001
2F6B 4HB1
2FL2 XSAVED #00227104
2G5L PARMBITS #00777777
2GK= N10000 +10000
2H4W Z5 +5
2HJG NJLSTAT #60000003
2J46 SLIST 4HLIST
2JHQ UJOBL +10
2K3B 12H
2KH2 12HJOBLIST
2L2L 1
2LG= 1
2L^W 4H****
2MFG XQEND +FLOWQ
2M^6 XK9 +K9
2NDQ [
2NYB [ S/R TO FON NEXT OP WHAT ACTIVITY IF NEC.
2PD2 WOFF SBX 6 FX1
2PXL LDN 0 #20
2QC= SMO FX2
2QWW ANDX 0 CONTEXT
2RBG BZE 0 WOFF9 [J IF NOT OP
2RHN ... MHUNTW 3,CQPRINT,CQ1 [PTR TO CQPRINT/CQ1 BLOCK
2RNW ... JBS WOFF9,3,OPLIST [J IF NOT O/P 'HERE'
2RW6 WOFF2 OFF AWHATBIT
2S*Q FON #114
2STB WOFF9 ADX 6 FX1
2T*2 EXIT 6 0
2TSL WSERASE
2W#= [ ERASE THE 'WS' FILE
2WRW SBX 6 FX1
2X?G SETNCORE 10,3,FILE,FABSNB
2XR6 LDN 0 10
2Y=Q STO 0 A1(3)
2YQB OPSCON WRAS5,WRAS3 [J IF O/P CONTEXT
2^=2 WRAS3
2^PL #SKI IFS
329= ADN 2 FUSER1-FCBRING
32NW #SKI IFS<1$1
338G LDX 2 BWORKRING(2)
33N6 ADN 2 FUSER1 [SET UP FABSNB.......
347Q ADN 3 A1+1 [WITH WORKFILE INFO......
34MB MOVE 2 9 [FOR ERASEWORK
3572 ERASEWORK [ERASE WORKFILE AT LEVEL0
35LL TESTREP OK,WRAS9
366= XGER GEOERR WSERASE,1
36KW WRAS5 LDN 2 WFILE +1(1)
375G LDN 3 A1+1(3) [SET UP FABSNB.........
37K6 MOVE 2 9 [WITH WHATSTATE ETC.
384Q SMO FX2
38JB LDX 0 AWORK4
3942 STO 0 7(3) [GEN. NO.
39HL ERASE [ERASE WHATSTATE
3=3= TESTREP NOFILE,XGER
3=GW WRAS9 ADX 6 FX1
3?2G EXIT 6 0
3?G6 STLP
3?^Q [ THIS S/R COPIES THE *LP PARAMETER TOADATA/CREADL
3#FB [ ON ENTRY, X6 POSN. TO WHICH PARAMETER IS COPIED
3#^2 [ X7 LINK ADDRESS
3*DL [ X4 NO. OF CHARS TO BE COPIED
3*Y= [ ON EXIT, X6 NEXT FREE POSN. IN ADATA/CREADL
3BCW MHUNT 2,CPB,CUNI
3BXG ANDN 4 #7777
3CC6 LDN 5 APARA(2)
3CWQ CHARMOVE 5,4
3DBB EXIT 7 0
3DW2 Q1ENTRY
3F*L [ CHECK SWITCH WORD:- IF ANOTHER OPERATOR COMMAND IN PROGRESS
3FT= [ WAIT UNTIL IT HAS FINISHED
3G#W ... OPSCON WSPC,WSPC
3GSG BRUSEN XER99 [J IF NO USER/NO OP
3H#6 ...WSPC
3LPG [ CHECK 'WS' PARAMETERS
3M96 STOZ ACOMMUNE1(2)
3MNQ DOWN WSPARAM,1
3MSM ... BRN XER95
3MYJ ... BRN XBRK95
3N4F ... OPSCON WSPC4,WSPC8 [WSPC4 IF OPERATOR
3N8B ... BRN WSPC8
3N#? ...WSPC4 MHUNTW 3,CQPRINT,CQ1
3ND8 ... JBS WSPC8,3,OPLIST [J IF NOT O/P 'HERE'
3NJ5 ...WSPC6 BSOFF AWHATBIT,WSPC7 [J IF ALL CLEAR TO GO AHEAD
3NN2 ... COOR3 #114 [WAIT TILL COMMAND FINISHES
3NRX ... BRN WSPC6
3NXS ...WSPC7 ON AWHATBIT [SET SWITCH
3P3P ...WSPC8
3P7L WSCREATE
3PM= [ CREATE AND OPEN 'WS' FILE
3Q6W CREATEB 3
3QLG OPSCON WSC10,WSC7 [J IF OPERATOR CONTEXT
3R66 WSC7 FRIGMONF XER9,1 [CREATE AND OPEN WORKFILE
3RKQ LOBSFILE
3S5B BRN WSC90
3SK2 WSC10 LDN 1 WFILE+1(1) [CREATION AND ERASURE....
3T4L LDN 2 CPREFIX(2) [REQUIRES OWNERSHIP .....
3TJ= MOVE 1 3 [SO INSERT 'OPERATORS'
3W3W SETNCORE 10,3,FILE,FABSNB
3WHG LDN 1 WFILE(1)
3X36 LDN 2 A1(3)
3XGQ MOVE 1 10
3XP2 ... USEROPEN XBRK9,APPEND,CREATE,LEAVE,FROZEN [OPEN WS FILE
3YG2 TESTRPN2 OK,XER9
3Y^L MHUNT 3,FILE,ENT
3^F= LDX 5 EGEN(3) [GET GENERATION NO.OF WS FILE
3^YW STO 5 AWORK4(2) [SAVE GEN. NO. OF 'WS' FILE
42DG FREECORE 3
42Y6 WSC90 MFREE FILE,FABSNB
43CQ [ PREPARE TO O/P 'WS' FILE
43XB PREP STOZ ACOMMUNE1(2) [O/P WELL INFO &...
44C2 DOWN WSJOBS,1 [...STORE LIVE JOB NOS.
44WL BRN XER
45B= BRN XBRK
45TW OPF
46*G [ O/P WS INFORMATION TO REQUIRED TERMINALS
46T6 MFREE CQPRINT,CQ11
47#Q MHUNTW 3,CQPRINT,CQ1
47SB ... JBS OPF4,3,OPLIST [J IF NOT O/P 'HERE'
49?= REWIND
49QW OPF2 READ [READ REC. OF WS FILE
4==G MHUNT 3,FILE,FRB
4=Q6 LDX 0 A1(3)
4?9Q BZE 0 OPF8 [J IF END OF FILE
4?PB TESTBRKIN XBRK [J IF B-IN OCCURRED
4?SG ...XFSHBRKA
4#5W ...XFSHBRKB
4#92 LDEX 6 A1+FRH(3)
4#NL SLL 6 2
4*8= SBN 6 8
4*MW OUTMON 6,A1+FRH+2,A1+FRH+1(3),FILE,FRB
4B7G MFREE FILE,FRB
4BM6 BRN OPF2
4C6Q OPF4 LDN 4 4
4CLB LDX 1 FX1
4D62 LDX 5 SLIST(1)
4DKL SPARABEG 1,4 [GET *LP PARAMETER
4F5= MHUNT 3,CPB,CUNI
4FJW LDX 4 ANUM(3)
4G4G BPZ 4 OPF5 [J IF PARAMETER EXISTS
4GJ6 LDN 4 0 [LENGTH OF PROPERTIES STRING
4H3Q OPF5 ANDN 4 #7777
4HHB LDX 7 4 [X7=MAX. NO. OF CHARS IN LF/RJ
4J32 ADN 7 CPDATA-A1*4+48
4JGL SRL 7 2 [X7REQ'D SIZE OF ADATA/CREADL
4K2= SETUPCORE 7,3,ADATA,CREADL
4KFW OPSCON OPF6,OPF55 [J IF OP CONTEXT
4K^G OPF55 LDN 5 PRINTU(1)
4LF6 LDN 6 CPDATA(3)
4LYQ MVCH 5 22 [MOVE IN BASIC PART OF COMMAND
4MDB BZE 4 OPF7 [J IF NO PROPERTIES
4MY2 LDN 5 PRINTQ(1) [COMMA PR
4NCL MVCH 5 3
4NX= CALL 7 STLP [COPY PROPERTY TOADATA/CREADL
4PBW BRN OPF7
4PWG OPF6 LDN 5 PRINTO(1)
4QB6 LDN 6 CPDATA(3)
4QTQ MVCH 5 37
4R*B BZE 4 OF1 [J IF NO PROPERTIES
4RT2 LDN 5 PRINTP(1)
4S#L MVCH 5 7 [MOVE IN PARAM ADATA/CREADL
4SS= CALL 7 STLP [MOVE IN PROPERTIES
4T?W LDCT 0 #310
4TRG LDN 5 0
4W?6 MVCH 5 1 [MOVE IN )
4WQQ OF1 LDX 0 6
4X2J ... LDX 2 FX2
4X=B LDX 5 AWORK4(2)
4XQ2 LDN 6 0
4Y9L DVR 5 N10000(1)
4YP= LDCT 7 #200
4^8W LDN 1 CPDATA+3(3)
4^NG LDN 4 4
5286 OF2 CBD 6 0(1) [PUT FILE GEN. NO....
52MQ BCHX 1 £ [...AT END OF FILENAME
537B BCT 4 OF2
53M2 LDX 6 0
546L OPF7 MFREE CPB,CUNI
54L= SBN 6 CPDATA(3)
555W SLC 6 2
55KG STO 6 A1(3)
5656 OPSCON OPF77,OPF75 [J IF 'RJ' TO BE ISSUED
566T ...OPF75
572* ... ISSUCOMB XER,XBRK [ISSUE LF COMMAND
574B BRN OPF78
57=L ...OPF77 LDX 6 GSIGN
57DW ... ORS 6 CONTEXT(2) [RJ MUST BE SYS. ISSUED
57M6 ... ISSUCOMB XERA,XBRKA [ISSUE RJ COMMAND
57TB ... ERS 6 CONTEXT(2)
57XM ...OPF78
586G ... OPSCON OPF9,OPF8 [J IF OP. CONTEXT
58H= OPF8 CALL 6 WSERASE [ERASE 'WS' FILE UNLESS 'RJ'
592W OPF9 CLOSE
59GG CALL 6 WOFF [SWITCH OFF AWHATBIT IF NEC.
5=26 ENDCOM
5=9Y ...XBRKA ERS 6 CONTEXT(2)
5=FQ XBRK CLOSE
5=^B CALL 6 WSERASE [ERASE 'WS' FILE IF NEC.
5?F2 XBRK9 CALL 6 WOFF
5?RC ...XBRK95 ABANDCOM
5#5S ...XERA ERS 6 CONTEXT(2)
5#D= XER CLOSE
5#XW CALL 6 WSERASE
5*CG XER9 CALL 6 WOFF
5*X6 ...XER95 ENDCOM
5BBQ XER99 COMERR JCONTINC,JNUNOP [NOT ALLOWED IN NO USER,NO OP
5BWB #END
^^^^ ...044073050001