{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: WSJOBSA867)}}
====== WSJOBSA867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:BITDEFS|BITDEFS]], [[george:macro:BS|BS]], [[george:macro:BXE|BXE]], [[george:macro:BXGE|BXGE]], [[george:macro:BXL|BXL]], [[george:macro:BXU|BXU]], [[george:macro:DOWN|DOWN]], [[george:macro:FCAJO|FCAJO]], [[george:macro:FINDJOBQ|FINDJOBQ]], [[george:macro:FPCAJO|FPCAJO]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:HLSAV|HLSAV]], [[george:macro:HUNT2|HUNT2]], [[george:macro:JBC|JBC]], [[george:macro:JBS|JBS]], [[george:macro:JOBLOCK|JOBLOCK]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SHLSQ|SHLSQ]], [[george:macro:UP|UP]], [[george:macro:UPPLUS|UPPLUS]]
22#C ... SEG WSJOBSA,867,SECTION CENT
22LS ...[
22^= [
2357 ...[
2394 ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
23#^ ...[
23DW [ THIS SEGMENT IS THE OVERFLOW SEGMENT FOR WSJOBS
23YG [
243L [ VERSION 866 WAS PRODUCED FOR DS8221
246Q [ AN ENHANCEMENT TO PROVIDE DETAILS OF FILES
249W [ FOR WHICH JOBS ARE WAITING. 7.12.81
24*2 [
24D6 SEGENTRY K1WSJOBSA,Q1ENTRY [O/P LIVE JOB INFO. TO WS FILE
24XQ SEGENTRY K2WSJOBSA,Q2ENTRY
25CB SEGENTRY K3WSJOBSA,Q3ENTRY
25X2 SEGENTRY K4WSJOBSA,Q4ENTRY
26BL FSHENTRY K7WSJOBSA,,Q7ENTRY,Q7ENTRY
26W= FSHENTRY K8WSJOBSA,,Q8ENTRY,Q8ENTRY
27*W FSHENTRY K9WSJOBSA,,Q9ENTRY,Q9ENTRY
27H4 FSHENTRY K10WSJOBSA,Q10ENTRY,,Q10ENTRY
27N= FSHENTRY K11WSJOBSA,Q11ENTRY,,Q11ENTRY
27TG BITDEFS CONTEXT,12,XFSTART
28*6 BITDEFS CONTEXT,16,XREMOTE
28SQ [ DEFINES THE CQPRINT/CQ1 BLOCK
29#B #DEF ZGA = A1 [GROUP A INDICATORS
29S2 #DEF ZGB = ZGA+1 [GROUP B INDICATORS
2=?L #DEF ZGC = ZGB+1 [GROUP C INDICATORS
2=R= #DEF ZGD = ZGC+1 [GROUP D INDICATORS
2?=W #DEF ZGE = ZGD+1 [GROUP E INDICATORS
2?QG #DEF ZGF = ZGE+1 [GROUP F INDICATORS
2#=6 #DEF ZGG = ZGF+1 [GROUP G INDICATORS
2#PQ #DEF ZJCOUNT = ZGG [JOB COUNT FOR 'WJ'
2*9B #DEF ZGH = ZGG+1 [GROUP H INDICATORS
2*P2 #DEF ZNAME = ZGH+1 [JOB NAME
2B8L #DEF ZUSER = ZNAME+3 [USER NAME
2BN= #DEF ZPROP = ZUSER+3 [PROPERTY NUMBER
2G5L #DEF ZLCOUNT= ZPROP+1 [COUNT OF JOB NOS. STORED
2GK= #DEF ZLJOB = ZLCOUNT+1 [JOB NUMBER
2H4W [ DEFINES THE CQPRINT/CQ11
2HJG #DEF WJOBNO = A1 [JOB NUMBER
2J46 #DEF WNAME = WJOBNO+1
2JHQ #DEF WUSER = WNAME+3
2K3B #DEF WMISC = WUSER+3
2KH2 #DEF WJLSTAT = WMISC
2L2L #DEF WYONQ = WMISC+1
2LG= #DEF WCONTEXT= WYONQ+1
2L^W #DEF WSOURCE1= WCONTEXT+1
2MFG #DEF WSOURCE2= WSOURCE1+1
2M^6 #DEF WSOURCE3= WSOURCE2+1
2NDQ #DEF WURGE = WSOURCE3+1
2NYB #DEF WCPI = WURGE+1
2PD2 #DEF WTIMEJ = WCPI+1
2PXL #DEF WARRIVED= WTIMEJ
2QC= #DEF WPROGTIME =WTIMEJ+2
2QWW #DEF WARRIVET= WPROGTIME
2RBG #DEF WCSIZE = WPROGTIME+2
2RW6 #DEF WFWT = WCSIZE+1
2STB #DEF WJLSTATX=WFWT
2T*2 #DEF WTLR = WFWT+1
2TSL #DEF WTSWAPS = WTLR+1
2W#= #DEF WMAXSIZE= WTSWAPS+1
2WRW #DEF WWT1 = WMAXSIZE+1
2X?G #DEF WWT2 = WWT1+1
2XR6 #DEF WWT3 = WWT2+1
2Y=Q #DEF WEXTRA = WWT3+1
2YQB #DEF WPERPTR = WEXTRA+1
329= #DEF WCOREPRI = WPERPTR+1
32NW #DEF WMILLPRI = WCOREPRI+1
338G #DEF SIZOCQ11 = WMILLPRI+1-A1
35LL #DEF OCOREBIT = #20
366= #DEF OWAITBIT = #40
36KW [
375G BITDEFS WEXTRA,0,XWELL,XLIMBO
384Q BITDEFS WEXTRA,2,XEXPR
38JB BITDEFS EXT+11,9,YLIMBO
3942 XK9 +K9
39HL XQEND +FLOWQ
3CWQ XPRESS #34631463 [CPI OF EXP'D JOB
3F*L [ S/R TO GET NEXT HIGHEST JOB NO. FROM CQPRINT/CQ1
3FT= [ LAST JOB NO. IS HELD IN AWORK3
3G#W NXNO MHUNTW 3,CQPRINT,CQ1
3GSG LDX 6 AWORK3(2) [LAST JOB NO.
3H#6 NGN 4 1
3HRQ LDX 0 ZLCOUNT(3) [COUNT OF LIVE JOBS
3J?B BZE 0 NXNO9
3JR2 NXNO2 BXGE 6 ZLJOB(3),NXNO4 [J IF ALREADY O/P
3K=L BXL 4 ZLJOB(3),NXNO4 [J IF NOT SMALLEST JOB NO.
3KQ= LDX 4 ZLJOB(3)
3L9W NXNO4 ADN 3 1
3LPG BCT 0 NXNO2
3M96 BNG 4 NXNO9
3MNQ STO 4 AWORK3(2) [NEXT HIGHEST JOB NO.
3N8B NXNO7 EXIT 5 1
3NN2 NXNO9 EXIT 5 0
3PM= [ O/P START JOB ONFO. TO 'WS' FILE
3Q6W Q1ENTRY [MULTIPLE JOB O/P(JOBS IN CQ1)
3W3W LDN 7 0
3WHG BRN NJB
3YG2 Q3ENTRY
44C2 MHUNTW 3,CQPRINT,CQ11 [PTR TO CQPRINT/CQ11 BLOCK
44WL ORX 7 GSIGN [XCODE INDICATOR
45B= STO 7 WJOBNO(3) [SAVE XCODE IND.& JOB NO.
45TW ERX 7 GSIGN
46*G BRN NJB4
47SB Q2ENTRY [SINGLE JOB O/P
4?PB LDX 7 ACOMMUNE4(2) [JOB NO. FOR O/P
4#92 ORX 7 GSIGN
4#NL NJB STO 7 AWORK3(2)
4*8= [ WRITE THE REQUIRED INFO TO THE 'WS' FILE
4*MW LDX 0 ACOMMUNE1(2)
4B7G STO 0 AWORK4(2) [DEPTH OF 'WS' FILE
4BM6 MHUNTW 3,CQPRINT,CQ1
4C6Q LDX 4 ZGH(3)
4CLB STO 4 AWORK1(2) [O/P LEVEL INDICATORS
4D62 BNG 7 NJB2 [J IF SINGLE JOB O/P
4DKL NJB1 CALL 5 NXNO [GET JOB NO.
4F5= BRN OPF [J IF NO MORE JOB NOS.
4FJW NJB2 MHUNTW 3,CQPRINT,CQ11
4H3Q LDXC 7 AWORK3(2) [GET JOB NO. .
4HHB BCC £ [AND .
4J32 STO 7 WJOBNO(3) [STORE IN CQ11
4JGL NJB4 STOZ A1+1(3) [ZEROISE .
4K2= LDN 5 A1+1(3) [CQ11 BLOCK
4KFW LDN 6 A1+2(3)
4K^G MOVE 5 SIZOCQ11-2
4RT2 NUJ
4S#L [ STORE BASIC 'RUNNING' JOB INFORMATION
4SS= JOBLOCK 7,2
4T?W BNG 2 NSJ [J IF NO JOB BLOCK
4TRG HLSAV 2,SET,SAVING,JOBQ,NSJ [J IF BEING SAVED
5FS6 LDN 4 JNAME(2)
5G?Q LDN 5 WNAME(3)
5GRB MOVE 4 3 [JOB NAME
5H?2 LDN 4 JUSER(2)
5HQL LDN 5 WUSER(3)
5J== MOVE 4 3 [USER NAME
5JPW LDX 4 JMISC(2)
5K9G STO 4 WMISC(3) [JMISC
5KP6 LDX 4 JURGE(2)
5L8Q STO 4 WURGE(3)
5MML JBC NUJ0,2,JBEXPREQ [J IF NOT EXPRESSED
5N7= BS 3,XEXPR
5NLW NUJ0
5PL6 LDX 4 JCPI(2)
5Q5Q STO 4 WCPI(3)
5RJL LDX 4 ACOREP(2)
5S4= STO 4 WCOREPRI(3) [CORE PRIORITY
5SHW LDEX 0 JMISC(2)
5T3G BZE 0 TML7 [J IF NO CORE INFO.
5TH6 FPCAJO 1,2
5W2Q LDX 0 ASU1(1)
5WGB STO 0 GEN4
5X22 LDX 0 ASU2(1)
5XFL STO 0 GEN3
5X^= LDX 0 ASU3(1)
5YDW STO 0 GEN2
5YYG LDX 0 ASU4(1)
5^D6 STO 0 GEN1
5^XQ LDN 4 4
62CB TML3 LDCH 0 AMILLP(2)
62X2 BNZ 0 TML5
63BL SMO 4
63W= LDX 0 GEN0
64*W BNG 0 TML5 [J IF MEMBER NOT ACTIVE
64TG LDN 0 30
65*6 TML5 DCH 0 WMILLPRI(3)
65SQ BCHX 3 £
66#B BCHX 2 £
66S2 BCT 4 TML3
67?L LDX 1 FX1
67R= SBN 2 1 [RESET POINTERS
68=W SBN 3 1
68QG TML7
69PQ LDX 4 HTIMEJ(2)
6=9B STO 4 WTIMEJ(3)
6=P2 LDX 4 HTIMEJ+1(2)
6?8L STO 4 WTIMEJ+1(3)
6?N= LDX 4 APROGTIME(2)
6#7W STO 4 WPROGTIME(3)
6#MG LDX 4 APROGTIME+1(2)
6*76 STO 4 WPROGTIME+1(3)
6*LQ LDX 4 JCSIZE(2)
6B6B STO 4 WCSIZE(3)
6CK= LDXC 0 WJOBNO(3)
6D4W BCS NUJ1 [J IF HLS XCODE
6F46 LDN 0 OCOREBIT
6FHQ SMO FX2
6G3B ANDX 0 AWORK1
6GH2 BZE 0 NUJ3 [J IF PROG INFO. NOT REQ'D
6HG= NUJ1
6H^W LDEX 4 JMISC(2)
6JFG BZE 4 NUJ3 [J IF NO CORE IMAGE
6J^6 NGN 4 1 [FWT IF NOT YET RUN
6KDQ STO 4 WFWT(3)
6KYB LDX 4 CLEANCT [GET TIME NOW
6LD2 LDX 5 JCFWT(2)
6LXL JBS NUJ15,2,JBPLUG [J IF PLUGGED IN
6MC= BNG 5 NUJ3 [J IF NOT YET RUN
6MWW SBX 4 APROCTIME
6NBG ADX 4 JCTLR(2)
6NW6 NUJ15
6P*Q STO 4 WTLR(3) [TIME LAST RUN
6PTB LDX 6 GSIGN
6Q*2 BNG 5 NUJ2 [J IF FWT NOT AVAILABLE YET
6QSL LDX 1 FX1
6R#= MPY 5 XK9(1)
6RRW NUJ2 STO 6 WFWT(3) [FAIR WAIT TIME
6S?G #SKI G4
6SR6 (
6T=Q STO 2 4 [SAVE ADDR. OF JOBBLOCK
6TQB FPCAJO 2
6W=2 HUNT2 2,BSTB,BSCB
6WPL LDX 5 ATSWAPS(2)
6X9= LDX 6 AMAXSIZE(2)
6XNW STO 5 WTSWAPS(3)
6Y8G STO 6 WMAXSIZE(3)
6YN6 LDX 2 4 [ADDR. OF JOBBLOCK
6^7Q )
6^MB NUJ3 FCAJO 2 [FIND JOB'S CPAT
7272 LDN 4 JSOURCE1(2)
72LL LDN 5 WSOURCE1(3)
736= MOVE 4 3 [STORE IN CQ11
73KW LDX 4 CONTEXT(2)
745G STO 4 WCONTEXT(3) [CONTEXT BITS
773= JBC NUJ35,2,YLIMBO [J IF NOT LIMBO
77GW BS 3,XLIMBO [SET LIMBO BIT IN CQ11
78^Q NUJ35 LDXC 0 WJOBNO(3)
79FB BCS NUJ37 [J IF HLS XCODE
79^2 LDN 0 OWAITBIT
7?XG SMO FX2
7#C6 ANDX 0 AWORK1
7#WQ BZE 0 NUJ6 [NO WAITING INFO. REQ'D
7F?B NUJ37
7FR2 LDN 6 FLOWQ
7G=L NUJ4 LDX 2 6
7GQ= LDX 2 FPTR(2)
7MLG BXE 2 XQEND(1),NUJ6 [J IF NOT WAITING
7N66 XFSHNBNUJWT
7P5B LDX 6 2
7PK2 SBN 2 CHAINADD
7Q4L BXU 7 JOBNO(2),NUJ4 [J IF NOT REQD JOB
7QJ= LDEX 0 ATYPE(2)
7R3W STO 0 WWT1(3) [STORE WAITING STYLE IN CQ11
7R4R #UNSET EWAITFILE
7R5N (
7R6K [ DS8221 CODE
7R7G [ TEST FOR WAITING STYLES #72 & #136 AND
7R8C [ STORE CSN OF STORAGE UNIT IN CQ11 BLOCK
7R9# LDX 5 ACOMMUNE9(2) [PICK UP CSN IN X5
7R=9 SBN 0 #72
7R?6 BZE 0 NUJ5 [#72 = TO ACCESS SCA
7R#3 SBN 0 #136-#72
7R#Y BZE 0 NUJ5 [#136= TO OBTAIN SCA LOCKOUT
7R*T LDX 5 ACC4(2)
7RBQ ADN 0 #136-#35 [IF MAG TAPE
7RCM )
7RDJ #UNSET EWAITFILE
7RFF #SKIP
7RGB (
7RHG LDX 5 ACC6(2)
7S36 SBN 0 #6 [IF WAITING FOR FILE AVAILABLE
7SGQ BZE 0 NUJ5 [FCB IN X5
7T2B LDX 5 ACC4(2)
7TG2 SBN 0 #35-#6 [IF MAG. TAPE
7TPS )
7T^L BZE 0 NUJ5 [TSN IN X5
7XDG LDXC 5 AWORK1(2)
7XN# ... BCS £
7XY6 SBN 0 #167-#35
7YCQ BZE 0 NUJ5
7YXB LDX 5 CLONG2(2)
7^C2 ADN 0 #167-#24
85#2 BNZ 0 NUJ5
85RL LDX 0 ACC5(2) [FSTART OF FILE
86?= STO 0 WWT3(3)
87Q6 LDX 0 ACC6(2) [FILEFILESTORE NO.
889Q DCH 0 WWT3(3)
8992 LDX 5 ACC4(2) [FBLKS OF FILE
89NL NUJ5 STO 5 WWT2(3)
8=8= NUJ6
8B5= BRN WRIT
8G^G NSJ
8HF6 [ STORE BASIC INFORMATION ABOUT THE SAVED JOB
8HYQ SHLSQ 7,2,WRITOFF [J IF JOB NO LONGER EXISTS
8JDB LDN 4 HLSJNAM(2)
8JY2 LDN 5 WNAME(3)
8KCL MOVE 4 3 [STORE JOBNAME IN CQ11
8KX= LDN 4 HLSUNAM(2)
8LBW LDN 5 WUSER(3)
8LWG MOVE 4 3
8MB6 LDX 4 HLSSTAT(2)
8MTQ STO 4 WMISC(3)
8N*B LDX 4 HLSYONQ(2)
8NT2 STO 4 WYONQ(3)
8P#L LDX 4 HLSPCT(2)
8PS= STO 4 WSOURCE3(3)
8Q?W WRIT
8QRG [ WRITE INFORMATION TO 'WS' FILE
8S=B LDXC 0 WJOBNO(3)
8SQ2 BCC WRIT5 [J IF NOT HLS XCODE
8T9L ACROSS WSPERIS,2
8TP= WRIT5
8WNG LDX 2 FX2
8X86 LDX 0 AWORK4(2)
8XMQ STO 0 ACOMMUNE1(2) [DEPTH OF 'WS' FILE
8Y7B DOWN QPRINT,1 [WRITE INFO. TO 'WS' FILE
8YM2 BRN X2ER
8^6L BRN X2BRK
8^L= LDX 0 AWORK3(2)
925W BNG 0 OPF9 [J IF SINGLE JOB O/P
92KG BRN NJB1 [GET NEXT JOB NO.
9356 WRITOFF
93JQ LDXC 0 WJOBNO(3)
944B BCC WRIT5 [J IF NOT HLS XCODE
94J2 MFREEW CQPRINT,CQ11
98YL ACROSS HLSREAD,30
99D= X2ER UP [ERROR
99XW X2BRK UPPLUS 1 [BREAK IN
9=CG OPF MHUNTW 1,CQPRINT,CQ1
9=X6 STOZ ZLCOUNT(1)
9?BQ STOZ ZLJOB(1)
9?WB OPF9 UPPLUS 2 [OK
9#TL #PAGE
9**= STOJCT
9*SW [ UPDATE MOP/BACK COUNT
9B#G [ ON ENTRY X1 LINK ADDRESS
9BS6 [ X5 0 IF MOP 1 IF BACKGROUND
9C?Q MHUNTW 2,CQPRINT,CQ1
9CRB LDN 0 1
9D?2 SMO 5
9DQL ADS 0 ZJCOUNT(2) [UPDATE MOP/BACK COUNT
9F== LDX 2 FX2
9FPW EXIT 1 0
9G9G [
9M5Q #PAGE
9MKB Q4ENTRY
9N52 [ S/R TO CHECK IF REQ'D 'STARTED JOB .
9NJL [ AND STORE JOB IN X4 IF WS (X4=0 IF NOT REQ'D BY WS
9P4= [ OR UPDATEJOB COUNT IF 'WJ'
9PHW [ ON ENTRY & EXIT X1=FX1 & X2=FX2
9Q3G [ X3 ADDR. OF JOB BLOCK ON ENTRY &EXIT
9QH6 [ X6 LINK ADDRESS
9R2Q [
9RGB FINDJOBQ 3,ACOMMUNE5(2),TNS90 [REFIND JOBQUE BLOCK
9S22 LDX 5 AWORK1(2)
9SFL SLL 5 2
9S^= BPZ 5 TNS90 [J IF NO LIVE JOBS REQD
9TDW SLL 5 1
9TYG BNG 5 TNS90 [J IF ONLY SAVED JOBS REQD
=4R= BZE 5 TNS40 [J IF ALL LIVE JOBS REQ'D
=PR6 LDX 4 JMISC(3)
=Q=Q SLL 5 1
=QQB BPZ 5 TNS6 [ NO 'MOP' CHECK
=R=2 BNG 4 TNS90 [NOT MOP JOB
=RPL TNS6 SLL 5 1
=S9= BPZ 5 TNS8 [NO 'BACK' CHECK
=SNW BPZ 4 TNS90 [NOT BACK JOB
=T8G TNS8 SLL 5 1
=TN6 BPZ 5 TNS10 [NO 'REAL' CHECK
=W7Q LDN 0 #600
=WMB ANDX 0 JMISC(3)
=X72 BZE 0 TNS90 [NOT 'REAL' JOB
=XLL TNS10 SLL 5 1
=Y6= BPZ 5 TNS12 [NO 'CORE' CHECK
=YKW LDEX 0 JMISC(3)
=^5G BZE 0 TNS90 [J IF NO CORE IMAGE
=^K6 TNS12 SLL 5 1
?24Q BPZ 5 TNS14 [NO 'EXPRESS' CHECK
?342 JBC TNS90,3,JBEXPREQ [J IF NOT EXPRESSED
?5^Q TNS14 SLL 5 1
?6FB LDX 4 JPRIV(3)
?6^2 ANDN 4 #2
?7DL BPZ 5 TNS15 [NO 'SYS' CHECK
?7Y= BZE 4 TNS90 [J IF NOT SYS ISSUED
?8CW BRN TNS16
?8XG TNS15 BPZ 7 TNS16
?9C6 BNZ 4 TNS90
?9WQ TNS16 SLL 5 1
?=BB BPZ 5 TNS20 [NO 'USER' CHECK
?=W2 LDN 0 3
??*L TNS18 SMO 0
??T= LDX 4 JUSER-1(3)
?##W SMO 0
?#SG BXU 4 AWORK2-1(2),TNS90 [WRONG USER?
?*#6 BCT 0 TNS18
?*RQ TNS20 SLL 5 1
?B?B BZE 5 TNS40 [NO FURTHER CHECKS
?LK2 HLSAV 3,SET,SAVING,JOBQ,TNS90 [J IF JOB 'BEING SAVED'
?M4L FCAJO 2,3 [FIND CPAT
?MJ= BPZ 5 TNS22 [NO FSTART CHECK
?N3W JBC TNS90,2,XFSTART [J IF NOT FULLY STARTED
?NHG TNS22 LDX 4 JSOURCE3(2)
?P36 ANDX 4 BITS22LS
?PGQ SLL 5 1
?Q2B BPZ 5 TNS24 [NO CLUSTER CHECK
?QG2 BZE 4 TNS90 [J IF NOT CLUSTER JOB
?Q^L TNS24 SLL 5 1
?RF= BPZ 5 TNS26 [NO CENTRAL CHECK
?RYW BNZ 4 TNS90 [J IF NOT CENTRAL JOB
?SDG TNS26 SLL 5 1
?SY6 BPZ 5 TNS28 [NO PR CHECK
?TCQ ERX 4 7
?TXB ANDX 4 BITS22LS
?WC2 BNZ 4 TNS90 [WRONG PROPERTY
?WWL TNS28 SLL 5 1
?XB= BPZ 5 TNS40 [NO WAITING CHECK
#BGL LDX 4 JOBNO(2)
#C2= TNS29L
#CFW LDN 2 FLOWQ [SEARCH WAITING LIST
#C^G TNS29 LDX 2 FPTR(2)
#K*B TXU 2 XQEND(1)
#KT2 BCC TNS90 [J IF NOT WAITING
#L#L XFSHNBNOTWT
#M?W TXU 4 JOBNO-CHAINADD(2)
#MRG BCS TNS29
#N?6 TNS40
#NQQ [ UPDATE COUNT OF LIVE JOBS IF WJ
#P=B [ OR PUT JOB NO. IN X4 IF WS
#PQ2 UPD
#Q9L BNG 7 UPD4 [J IF COUNTING
#QP= LDX 4 JOBNUM(3)
#R8W BRN TNS91
#RNG UPD4 LDX 5 JMISC(3)
#S86 SRL 5 23 [ SET B23 IF BACK
#SMQ CALL 1 STOJCT [ADD 1 TO MOP/BACK COUNT
#T7B TNS90 LDN 4 0 [JOB NOT REQD BY WS
#TM2 TNS91
#^4B SMO FX2
#^J2 STO 4 ACOMMUNE4 [RETURN X4 VIA ACOMMUNE4
*23L UP
*2H= #END
^^^^ ...363354330002