{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: WSPARAM867)}}
====== WSPARAM867 ======
(George Source)
**Macros used:** [[george:macro:BC|BC]], [[george:macro:BITDEFS|BITDEFS]], [[george:macro:BRUSEN|BRUSEN]], [[george:macro:BXE|BXE]], [[george:macro:BXU|BXU]], [[george:macro:CHEKLFN2|CHEKLFN2]], [[george:macro:CHNUMCOD|CHNUMCOD]], [[george:macro:ERRORX|ERRORX]], [[george:macro:FJOCA|FJOCA]], [[george:macro:ISPROPN|ISPROPN]], [[george:macro:JBC|JBC]], [[george:macro:JMBAC|JMBAC]], [[george:macro:JMBC|JMBC]], [[george:macro:JMBS|JMBS]], [[george:macro:MFREE|MFREE]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:NAME|NAME]], [[george:macro:OPSCON|OPSCON]], [[george:macro:OUTPARAM|OUTPARAM]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SPARABEG|SPARABEG]], [[george:macro:TESTRACE|TESTRACE]], [[george:macro:TESTRPN2|TESTRPN2]], [[george:macro:UP|UP]], [[george:macro:UPPLUS|UPPLUS]], [[george:macro:VFREE|VFREE]], [[george:macro:WSNARROW|WSNARROW]]
22FL #LIS K0WSPARAM>K0ALLGEO>K0GREATGEO>K0COMMAND
22^= ... SEG WSPARAM,867,SECTION CENT
23YG [
244C ...[
248# ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
24#9 ...[
24D6 [ THIS SEGMENT READS THE WS/WJ PARAMETERS
24XQ [ AND SETS UP PARAMETER INDICATORS IN CQPRINT/CQ1
25CB [
25X2 SEGENTRY K1WSPARAM,Q1ENTRY [READ PARAMETERS
26BL SEGENTRY K2WSPARAM,Q2ENTRY [OUTPARAM SELECTION DETAILS
26W= [ DEFINES THE CQPRINT/CQ1 BLOCK
27*W #DEF ZGA = A1 [GROUP A INDICATORS
27TG #DEF ZGB = ZGA+1 [GROUP B INDICATORS
28*6 #DEF ZGC = ZGB+1 [GROUP C INDICATORS
28SQ #DEF ZGD = ZGC+1 [GROUP D INDICATORS
29#B #DEF ZGE = ZGD+1 [GROUP E INDICATORS
29S2 #DEF ZGF = ZGE+1 [GROUP F INDICATORS
2=?L #DEF ZGG = ZGF+1 [GROUP G INDICATORS
2=R= #DEF ZGH = ZGG+1 [GROUP H INDICATORS
2?=W #DEF ZNAME = ZGH+1 [JOB NAME
2?QG #DEF ZUSER = ZNAME+3 [USER NAME
2#=6 #DEF ZPROP = ZUSER+3 [PROPERTY NUMBER
2#PQ #DEF ZLCOUNT= ZPROP+1 [COUNT OF JOB NOS. STORED
2*9B #DEF ZLJOB = ZLCOUNT+1 [JOB NUMBER
2*P2 #DEF NGA = 1
2B8L #DEF NGB = 2
2BN= #DEF NGC = 3
2C7W #DEF NGD = 4
2CMG #DEF NGE = 5
2D76 #DEF NGF = 6
2DLQ #DEF NGG = 7
2F6B #DEF NGH = 8
2FL2 [
2G5L [ GROUP F BITS
2GK= BITDEFS ZGF,9,YSAVE
2H4W BITDEFS ZGF,12,REALTIME,YCORE,YEXPR
2HJG BITDEFS ZGF,17,YFSTA,,,,YWAIT,YNSAV
2HNC [ WORD FOLLOWING USED AS WSNARROW MARKER
2HS# SEGENTRY K50WSPARAM
2HY9 WSNARROW +0
2J46 BITDEFS WSNARROW,1,WSNARROWOP,WSNARROWALL
2J83 WSNARBITS #77437777 [MASK TO REMOVE BITS FOR WSNARROW
2J?Y WSNPRFUL #00777400 [PROG AND FULL BITS
2JCT [ WS PARAM TABLE
2JHQ PARM
2K3B SJOB 4HJOB0 [GROUP A #01
2KH2 #01400000
2L2L SGROUPB
2LG= SALL 4HALL0 [GROUP B #02- ALL MUST B 1ST
2L^W #02300001
2MFG SWELL 4HWELL
2M^6 #02200000
2NDQ SNCAN 4HNCAN
2NYB #02000001
2PD2 SSTAR 4HSTAR
2PXL #02100000
2QC= SCLUS 4HCLUS [GROUP C #03
2QWW #03000040
2RBG SPROP 4HPROP
2RW6 #03000010
2S*Q SCENT 4HCENT
2STB #03000020
2T*2 SSYS 4HSYS0
2TSL #03000400
2W#= SUSER 4HUSER [GROUP D #04
2WRW #04000200
2X?G SMOP 4HMOP0 [GROUP E #05
2XR6 #05020000
2Y=Q SBACK 4HBACK
2YQB #05010000
2^=2 SWAIT 4HWAIT [GROUP F #06
2^PL #06000004
329= SFSTA 4HFSTA
32NW #06000100
338G SSAVE 4HSAVE
33N6 #06040000
347Q SEXPR 4HEXPR
34MB #06001000
3572 SCORE 4HCORE
35LL #06002000
366= SREAL 4HREAL
36KW #06004000
375G SNSAV 4HNSAV
37K6 #06000002
384Q SGROUPG
38JB SLIST 4HLIST [GROUP G #07
3942 #07000001
39HL SHERE 4HHERE
3=3= #07000002
3=GW SNAME 4HNAME [GROUP H #10
3?2G #10740404
3?G6 #SKI G3
3?^Q (
3#FB SSIZE 4HSIZE
3#^2 #10601404
3*DL )
3*Y= #SKI G4
3BCW (
3BXG SQUOT 4HQUOT
3CC6 #10601404
3CWQ )
3DBB STIME 4HTIME
3DW2 #10606404
3F*L SURG 4HURG0
3FT= #10630404
3G#W SCONT 4HCONT
3GSG #10740704
3H#6 SPROG 4HPROG
3HRQ #10777634
3J?B SWHYW 4HWHYW
3JR2 #10740644
3K=L SFULL 4HFULL
3KQ= #10777774
3L9W 0 [END OF PARAMETERS
3LPG [
3LWN SUSER2 +5
3M3W 5HUSER: [2ND FORM OF USER PARAMETER
3M96 PARMBITS #00777777
3MNQ UNSETGH #10777644 [DEFAULT GROUP H SETTING
3N8B SWNCAN #00200001 [WELL/NCAND INDICATORS
3NN2 [
3P7L [ COMMAND IN ERROR
3PM= [
3Q6W XEROUT
3QLG ERRORX 0(3),1(3)
3R66 XEROUT9
3RKQ UP
3S5B QPAR
3SK2 [ S/R TO GET A PARAMETER
3T4L [ AND CHECK IF IN LOCAL FILENAME FORMAT
3TJ= [ ON ENTRY X4 HOLDS COUNT OF CHS. IN IDENTIFIER
3W3W [ X5 HOLDS PARAMETER IDENTIFIER
3WHG [ X6 LINK ADDRESS
3X36 [ EXIT +0 IF NOT IN LOCAL FILENAME FORMAT
3XGQ [ +1 IF NULL
3Y2B [ +2 IF OK
3YG2 SBX 6 FX1
3Y^L SPARABEG 1,4 [GET PARAM GIVEN IN X5
3^F= ADX 6 FX1
3^YW QPAR2 CHEKLFN2 QPAR8,QPAR9 [CHECK LOCAL FILENAME
42DG EXIT 6 2 [ OK
42Y6 QPAR8 EXIT 6 1 [ NULL PARAMETER
43CQ QPAR9 EXIT 6 0 [ ERROR IN FORMAT
43XB PNMOVE
44C2 [ S/R TO TRANSFER A FILENAME
44WL [ ON ENTRY X0 ADDRESS OF I/P
45B= [ X1 ADDRESS OF O/P
45TW [ X5 WORK ACC.
46*G [ X7 COUNT OF CHARS.(IN BOTTOM 12 BITS)
46T6 [NB. CHAR. COUNT MUST NOT BE ZERO
47#Q LDX 5 ACES
47SB STO 5 0(1) [SPACE FILL O/P AREA
48#2 STO 5 1(1)
48RL STO 5 2(1)
49?= ANDN 7 #7777 [GET CHAR. COUNT
49QW SMO 7
4==G MVCH 0 0 [TRANSFER FILENAME
4=Q6 VFREE CPB,CUNI
4?9Q LDX 1 FX1
4?PB LDX 2 FX2
4#92 EXIT 6 0
4#NL Q1ENTRY
4*8= [
4*MW [ GET 'WS' PARAMETERS
4B7G [ AND SET UP CQPRINT/CQ1
4BM6 [ ACOMMUNE1 :-
4C6Q [ B0 SET IF ONLY SELECTION DETAILS (IE. WJ)
4CLB [ B0 UNSET IF ALL 'WS' PARAMETERS
4D62 [
4DKL LDX 7 ACOMMUNE1(2)
4F5= STO 7 AWORK4(2) [SAVE 'WJ-WS' MARKER
4FJW STRT
4G4G [ INITIALISE PARAMETERS
4GJ6 SETNCORE 17,3,CQPRINT,CQ1 [GET WS PARAMETER BLOCK
4H3Q STOZ A1(3) [AND INITIALISE IT
4HHB LDN 4 A1(3)
4J32 LDN 5 A1+1(3)
4JGL MOVE 4 16
4K2= BNG 7 PARA2 [J IF ONLY SELECTION PARAM
4KFW PARA
4K^G [ PICK UP THE 'WS' PARAMETERS
4LF6 OPSCON SPEC,SPEC [J IF OPERATOR CONTEXT
4LYQ PARA2 SPARUNACC [PICK UP NEXT PARAMETER
4MDB MHUNT 3,CPB,CUNI
4MY2 LDX 7 ANUM(3)
4NCL BNG 7 PARA9 [J IF NO MORE PARAMETERS
4NX= BNZ 7 PTA [J IF NOT NULL PARAMETER
4PBW PARA8 VFREE CPB,CUNI [FREE PARAM BLOCKS
4PWG BRN PARA2
4QB6 PARA9 MFREE CPB,CUNI
4QTQ BRN SDP [SET DEFAULTS
4R*B PTA
4RT2 [ CHECK THAT PARAMETER IS IN PRE-DEFINED TABLE
4S#L [ NB. ONLY 2,3,4 CHAR. PARAMETERS CHECKED FOR.
4SS= LDX 4 PARM(1)
4T?W LDX 5 4
4TRG LDX 6 APARA(3)
4W?6 BZE 4 NUM [J IF NOT IN TABLE
4WQQ ANDN 4 #7777
4X=B BZE 4 PTA2 [J IF 2CHAR. PARAMETER
4XQ2 ANDN 4 #77
4Y9L BZE 4 PTA4 [J IF 3CHAR. PARAMETER
4YP= BRN PTA6
4^8W PTA2 SRL 56 6
4^NG PTA4 SRL 56 6
5286 PTA6 BXE 5 6,PSET [J IF PARAMETER FOUND
52MQ BDX 1 PTA
537B NUM
53M2 [ CHECK IF PARAMETER IS A JOB NUMBER
546L LDX 0 AWORK4(2)
54L= BNG 0 XER [J IF 'WJ'
555W CHNUMCOD 1,3,XBRK2 [CONVERT BINARY
55KG TESTRPN2 OK,XER [J IF NOT NUMERIC
55QN LDX 6 ACOMMUNE1(2)
55XW BNG 6 XER [J IF NEG JOB NO.
562G BZE 6 XER
5656 MHUNT 3,CPB,CUNI
56JQ NAME 3,ADATA,CSTORE [SAVE CUNI IN CASE OF ERROR
574B MHUNTW 3,CQPRINT,CQ1 [FIND 'WS' PARAM BLOCK
583L STO 6 ZLJOB(3) [STORE JOB NO.
58H= NUM4 LDX 4 SJOB+1(1) [GET PARAMETER IDENT.
592W LDCH 5 SJOB+1(1) [GROUP TYPE
59GG BRN PSET2
5=26 SPEC
5=FQ [ CHECK IF FIRST 2 PARAMETERS ARE JOBNAME,:USERNAME
5=^B LDN 4 1
5?F2 LDCT 5 #120 [:
5?YL CALL 6 QPAR [GET USERNAME
5#D= BRN XER5 [FORMAT ERROR
5#XW BRN PARA8 [MISSING
5*CG LDX 6 JPARNUM(3)
5*X6 SBN 6 3
5BBQ BPZ 6 XER [NOT 1ST/2ND PARAMETER
5BWB MHUNTW 1,CQPRINT,CQ1
5CB2 LDN 0 APARA(3)
5CTL ADN 1 ZUSER
5D*= LDX 7 ANUM(3)
5DSW CALL 6 PNMOVE [STORE USERNAME
5F#G SPARUNACC [GET NEXT UNAC. PARAM.
5FS6 CALL 6 QPAR2 [CHECK IF JOB NAME
5G?Q BRN XER5 [FORMAT ERROR
5GRB BRN XER3 [MISSING
5H?2 BRN XJB4
5HQL PSET
5J== [ PICK UP INFORMATION FOLLOWING THE PARAMETER IDENTIFIER
5JPW [ AND SET PARAMETER IDENTIFIERS
5K9G LDXC 0 AWORK4(2)
5KP6 BCC PSET1 [J IF ALL 'WS' PARAMS REQ'D
5L8Q LDX 0 1
5LNB SBX 0 FX1
5M82 SBN 0 SJOB-PARM
5MML BZE 0 XER [INVALID PARAMETER
5N7= SBN 0 SLIST-SJOB
5NLW BPZ 0 XER [INVALID PARAMETER
5P6G PSET1 MHUNTW 3,CQPRINT,CQ1
5PL6 LDX 4 PARM+1(1)
5Q5Q LDCH 5 PARM+1(1)
5QKB LDX 1 FX1
5R52 BXE 4 SJOB+1(1),XJB [J IF JOB PARAMETER
5RJL BXE 4 SPROP+1(1),XPR [J IF PR PARAMETER
5S4= BXE 4 SUSER+1(1),XUS [J IF USER PARAMETER
5SHW PSET2 ADX 3 5
5T3G LDX 6 ZGA-1(3) [GROUP IDENT.
5TH6 BZE 6 PSET4 [1ST PARAMETER OF GROUP
5W2Q SBN 5 NGF [OTHERWISE GROUP F,H POS.
5WGB BZE 5 PSET4 [GROUP F
5X22 SBN 5 NGH-NGF
5XFL BNZ 5 XER1 [NOT GROUP H
5X^= PSET4 ORS 4 ZGA-1(3) [SET PARAMETER INDICATOR
5YDW BRN PARA8
5YYG XJB
5^D6 [ GET JOB NAME
5^XQ OPSCON XER,XER [ERROR IF IN OPERATOR CONTEXT
62CB LDN 4 3
62X2 LDX 5 SJOB(1)
63BL CALL 6 QPAR [GET JOB NAME
63W= BRN XER5 [FORMAT ERROR
64*W BRN XER3 [MISSING
64TG XJB4 MHUNTW 1,CQPRINT,CQ1
65*6 NAME 3,ADATA,CSTORE [SAVE CUNI IN CASE OF ERROR
65SQ LDX 7 ANUM(3)
66#B LDN 0 APARA(3)
66S2 LDX 3 1
67?L ADN 1 ZNAME
67R= CALL 6 PNMOVE [STORE JOB NAME IN CQPRINT/CQ1
68=W BRN NUM4
68QG XPR
69=6 [ GET PROPERTY NUMBER
69PQ LDN 4 4
6=9B LDX 5 SPROP(1)
6=P2 CALL 6 QPAR [GET PROPERTY NAME
6?8L BRN XER5
6?N= BRN XPR8 [PROPERTY NAME MISSING
6BL2 ISPROPN XBRK2,6 [CONVERT TO PROP. NO.
6C5L BZE 6 XEROUT9 [J IF UNKNOWN PROPERTY
6CK= SMO 6
6D4W LDN 0 0
6DJG SBN 0 1
6F46 BNZ 0 XPR2 [J IF NOT CENTRAL PROP.
6FHQ LDN 6 0
6G3B XPR2 MFREE CPB,CUNI
6GH2 MHUNTW 3,CQPRINT,CQ1
6H2L SMO 6
6HG= XPR4 LDN 6 0 [REMOVE TOP 2 BITS
6H^W STO 6 ZPROP(3) [STORE IN CQPRINT/CQ1
6JFG LDX 4 SPROP+1(1) [PARAMETER TYPE
6J^6 LDCH 5 SPROP+1(1) [GROUP TYPE
6KDQ BRN PSET2
6KYB XPR8 LDX 6 JSOURCE3(2) [SET DEFAULT PROPERTY
6LD2 BRN XPR2
6LXL XUS
6MC= [ GET USER NAME
6MWW LDN 4 4
6NBG LDX 5 SUSER(1)
6NW6 CALL 6 QPAR [GET USERNAME
6P*Q BRN XUS4 [FORMAT ERROR
6PTB BRN XUS8 [MISSING
6Q*2 XUS1 LDX 7 ANUM(3)
6QSL LDN 6 APARA(3)
6R#= XUS2 MHUNTW 1,CQPRINT,CQ1
6RRW LDX 0 6 [ADDR. OF USERNAME
6S?G LDX 3 1
6SR6 ADN 1 ZUSER
6T=Q CALL 6 PNMOVE [STORE USERNAME
6TQB LDX 4 SUSER+1(1) [PARAMETER IDENT.
6W=2 LDCH 5 SUSER+1(1) [GROUP IDENT.
6WPL BRN PSET2
6WR8 XUS4 LDCH 6 APARA(3)
6WSQ SBN 6 #12 [USERNAME PRECEDED BY :
6WW# BNZ 6 XER5 [J IF FORMAT ERROR
6WXW MFREE CPB,CUNI
6W^D SPARABEG 1,SUSER2(1) [GET USERNAME
6X32 CALL 6 QPAR2
6X4J BRN XER5
6X66 BRN XER5 [FORMAT ERROR
6X7N BRN XUS1
6X9= XUS8 BRUSEN XER
6XNW FJOCA 2
6Y8G LDN 7 12 [LENGTH OF USERNAME
6YN6 LDN 6 JUSER(2) [ADDR. OF DEFAULT USER
6^7Q BRN XUS2
6^MB SDP
7272 [ SET DEFAULT PARAMETER INDICATOR
72LL MHUNTW 3,CQPRINT,CQ1
736= LDX 4 ZGA(3)
73KW LDN 7 5
745G SDP2 SMO 7
74K6 LDX 5 ZGB-1(3)
754Q BNZ 5 SDP4 [J IF GROUP SELECTION
75JB BCT 7 SDP2
7642 LDX 0 SSTAR+1(1)
76HL SDP3 STO 0 ZGB(3) [SET STAR FOR INDV. JOBS
773= BNZ 4 SDP6 [J IF INDIV. JOB SELECTED
77GW [ SET INDIVIDUAL JOB SELECTION PARAMS.ETC.
782G OPSCON XER4,XER4 [J IF OPERATOR CONTEXT
78G6 LDX 0 JOBNO(2)
78^Q STO 0 ZLJOB(3) [SAVE USER'S JOB NO.
79FB LDX 4 SJOB+1(1)
79^2 STO 4 ZGA(3) [SET PARAMETER IDENT.
7=DL BRN SDP10
7=Y= SDP4 BNZ 4 XER1 [J IF INDV. JOB SELECTED
7?CW SDP6 OPSCON SDP9,SDP9 [J IF OPERATOR CONTEXT
7?XG LDX 5 ZUSER(3) [WORD 1 OF USERNAME IF ANY
7#C6 BRUSEN SDP85 [J IF NO USER CONTEXT
7#WQ [ SET USERNAME/INDICATOR
7*BB FJOCA 2
7*W2 BNZ 5 SDP7 [J IF USERNAME GIVEN
7B*L SMO FX2
7BT= LDX 0 AWORK4
7C#W BNG 0 SDP10 [J IF 'WJ'
7CSG BRN SDP8
7D#6 SDP7 LDX 0 ZUSER(3)
7DRQ LDX 4 ZUSER+1(3)
7F?B LDX 5 ZUSER+2(3)
7FR2 TXU 0 JUSER(2)
7G=L TXU 4 JUSER+1(2)
7GQ= TXU 5 JUSER+2(2)
7H9W BCS XER1 [J IF WRONG USER
7HPG SDP8 LDN 4 JUSER(2)
7J96 LDN 5 ZUSER(3)
7JNQ MOVE 4 3 [STORE USERNAME
7K8B LDX 4 SUSER+1(1) [..OTHERWISE SET GROUP IDENT.
7KN2 ORS 4 ZGD(3)
7L7L BRN SDP10
7LM= SDP85 BNZ 5 XER1 [J IF USERNAME REQUESTED
7M6W LDX 5 ZPROP(3)
7MLG BNZ 5 XER1 [J IF PROP. REQUESTED
7N66 BRN SDP10
7NKQ [ SET PROPERTY NO./INDICATOR
7P5B SDP9 SMO JSOURCE3(2)
7PK2 LDN 6 0 [PROPERTY NO.
7Q4L BZE 6 SDP10 [J IF WS ISSUED FROM CENT.OP
7QJ= LDX 5 ZGC(3)
7R3W BZE 5 SDP95 [J IF NO PROPERTY GIVEN
7RHG BXU 6 ZPROP(3),XER1 [J IF WRONG CLUSTER
7S36 SDP95 LDX 0 AWORK4(2)
7SGQ BNG 0 SDP10 [J IF 'WJ'
7T2B STO 6 ZPROP(3)
7TG2 LDX 5 SPROP+1(1)
7T^L ORS 5 ZGC(3) [SET GROUP IDENT. ETC.
7WF= [ SET O/P DEFAULT PARAMETER
7WYW SDP10 LDX 2 FX2
7XDG LDXC 0 AWORK4(2)
7XY6 BCS XLG [J IF 'WJ'
7YCQ LDX 4 ZGG(3)
7YXB BNZ 4 SDP18 [J IF O/P SET
7^C2 OPSCON SDP12,SDP12 [J IF OPERATOR CONTEXT
7^WL BRN SDP15
82B= SDP12 LDX 4 SWELL+1(1)
82TW ANDX 4 ZGB(3)
83*G BXU 4 SWELL+1(1),SDP15 [J IF NO 'WELL' REQ'D
83T6 LDX 4 SLIST+1(1) [OTHERWISE O/P TO LP
84#Q BRN SDP17
84SB SDP15 LDX 4 SHERE+1(1) [O/P HERE
85#2 SDP17 STO 4 ZGG(3)
85RL SDP18 OPSCON SDP20,SDP20 [J IF OPERATOR CONTEXT
86?= BXU 4 SHERE+1(1),SDP20 [J IF NOT 'HERE'
86QW LDN 4 #40
87=G TESTRACE 4,XER2 [ERROR IF NO COMMENT TRACE
87Q6 SDP20 LDX 4 ZGH(3)
889Q BNZ 4 SDP30 [J IF O/P LEVEL SPECIFIED
88PB LDX 4 UNSETGH(1)
8992 STO 4 ZGH(3) [SET DEFAULT O/P LEVEL
89NL SDP30
8=8= XLG
8=MW [. CHECK LOGIC OF GROUP SELECTION PARAMETERS
8?7G LDX 4 ZGA(3)
8?M6 BNZ 4 XLG9 [J IF NOT GROUP SELECTION
8#6Q XLG1 LDX 4 ZGB(3)
8#LB BNZ 4 XLG2 [J IF GROUP B SET
8*62 LDX 4 SSTAR+1(1)
8*KL STO 4 ZGB(3) [SET 'STARTED' JOB INDICATOR
8B5= XLG2 LDX 4 ZGF(3)
8BJW LDN 5 0
8C4G BNZ 4 XLG4 [J IF GROUP F PARAMS PRESENT
8CJ6 LDX 4 ZGC(3)
8D3Q BXE 4 SSYS+1(1),XLG6 [J IF 'SYS' SET
8DHB BRN XLG7
8F32 XLG4 SLL 4 9
8FGL BPZ 4 XLG6 [J IF NO 'SAVED' PARAM.
8G2= ERX 4 GSIGN
8GFW BNZ 4 XER1 [J IF OTHER 'F' PARAM.
8G^G LDX 4 ZGC(3)
8HF6 BXE 4 SSYS+1(1),XER1 [SAVED SYS NOT POSSIBLE
8HYQ LDX 4 ZGE(3)
8JDB BXE 4 SMOP+1(1),XER1 [SAVED MOP NOT POSSIBLE
8JY2 XLG6 ORX 5 SWNCAN(1) [WELL/NCAND JOBS NOT POSSIBLE
8KCL XLG62 ANDX 5 PARMBITS(1)
8KX= ORS 5 ZGB(3)
8LBW ERS 5 ZGB(3) [UNSET NCAND/WELL INDICATOR(S)
8LWG XLG7 JMBAC XLG9,3,YWAIT,YFSTA,YEXPR,YCORE,REALTIME
8MB6 BC 3,YNSAV
8MTQ JBC XLG9,3,REALTIME [J IF REALTIME IND SET
8N*B BC 3,YCORE [REMOVE CORE ID. IF REAL
8NT2 XLG9 LDX 4 ZGB(3)
8P#L SLL 4 6
8PS= BZE 4 XER1 [J IF MUTUALLY EXCL. SEL. PARAMS.
8Q44 [
8Q?W XAS
8Q#^ [ NOW CHECK IF WSNARROW IN USE
8Q*R [ IF WSNARROW ALL, THEN REMOVE MOP & NAME FIELDS
8QBK [ IF WSNARROW OP, AND IF WS WAS ISSUED IN OPERATOR CONTEXT,
8QCC [ TO BE OUTPUT "HERE", DO THE SAME
8QD= LDX 2 FX2
8QDF LDX 0 AWORK4(2)
8QDN BNG 0 XAS1 [J IF "WJ"
8QDX JMBS XAS2,1,WSNARROWALL
8QF6 JMBC XAS1,1,WSNARROWOP [J IF NOT IN USE
8QF* LDN 0 #20
8QGD ANDX 0 CONTEXT(2)
8QHH BZE 0 XAS1 [J IF NOT OPERATOR CONTEXT
8QHT LDX 0 ZGG(3) [CHECK O/P
8QJ7 ANDN 0 1
8QJF BNZ 0 XAS1 [J IF "LIST"
8QJR [
8QK5 XAS2
8QKC LDX 0 WSNPRFUL(1)
8QKP ANDX 0 ZGH(3)
8QLS ERX 0 WSNPRFUL(1)
8QMX BNZ 0 XAS1 [J IF NOT PROG OR FULL
8QP2 LDX 0 WSNARBITS(1)
8QQ5 ANDS 0 ZGH(3) [REMOVE UNWANTED BITS
8QRG [ ASSEMBLE JOB SELECTION PARAMETERS INTO
8R?6 [ A MORE USABLE FORM
8RQQ XAS1 LDN 4 0
8S=B LDN 5 5
8SQ2 XAS6 SMO 5
8T9L ORX 4 ZGB-1(3) [COLLECT INDICATORS
8TP= BCT 5 XAS6
8W8W SLL 4 6
8WNG LDX 0 ZGA(3)
8X86 BNZ 0 XAS7 [J IF INDV. JOB SEL
8XMQ ORX 4 GSIGN [SET GROUP SELECT. IND
8Y7B XAS7 STO 4 ZGA(3) [AND STORE INDICATORS
8YM2 XAS8 UPPLUS 2
8^6L [
8^L= [ BREAK IN EXIT
925W [
92KG XBRK2 UPPLUS 1
9356 [
93JQ [ COMMAND ERRORS
944B [
94J2 XER CALL 3 XEROUT
953L +APFERR [FORMAT ERROR
95H= -1
962W XER1 CALL 3 XEROUT
96GG +APCERR [INVALID COMBINATION
9726 -1
97FQ XER2 CALL 3 XEROUT
97^B +JMTRACE
98F2 -1
98YL XER3 CALL 3 XEROUT
99D= +JPARMIS [JOB NAME MISSING
99XW +JJOBNA
9=CG XER4 CALL 3 XEROUT
9=X6 +JPARMIS [MISSING PARAMETER
9?BQ -1
9?WB XER5 CALL 3 XEROUT
9#B2 +JNLFNF [WRONGLY FORMED NAME
9#TL -1
9**= [ SET UP SELECTION DETAILS IN PARAMETER BLOCK
9*SW Q2ENTRY
9B#G LDX 6 ACOMMUNE6(2) [GET SELECT. INDS.
9BS6 SETNCORE 14,3,ADATA,CSTORE
9C?Q ADN 3 A1 [SEL. DETAILS PTR (S.D.P)
9CRB STO 3 ACOMMUNE3(2) [START ADDR. OF DETAILS
9D?2 LDN 0 #30
9DQL DCH 0 0(3) [DEP. '(' IN CSTORE
9F== BCHX 3 £ [UPDATE S.D.P.
9FPW LDN 5 SGROUPG-SGROUPB/2 [COUNT OF SEL. PARAMS
9G9G LDN 4 0 [NO PARAM. O/P IND
9GP6 SDET3 LDX 0 SALL+1(1) [GET NEXT SEL. PARAM.
9H8Q SLL 0 6
9HNB STO 0 ACOMMUNE7(2)
9J82 ANDX 0 6
9JML BXU 0 ACOMMUNE7(2),SDET8 [J IF SEL PARM. MISSING
9K7= ERS 0 6 [REMOVE SEL. INDS.
9KLW BZE 4 SDET5 [J IF NO DETS. O/P YET
9L6G LDN 2 4
9LL6 MVCH 2 1 [DEP. ')' IN CSTORE
9M5Q SDET5 LDCT 4 #340 [PARM O/P IND
9MKB LDN 7 4 [MAX. CHARS. IN SEL. DET.
9N52 LDX 2 1
9NJL SDET7 LDCH 0 SALL(2)
9P4= BZE 0 SDET8 [END OF SEL. DET.
9PHW DCH 0 0(3) [PUT PARM IN CSTORE
9Q3G BCHX 2 £
9QH6 BCHX 3 £
9R2Q BCT 7 SDET7
9RGB SDET8 ADN 1 2 [PTR TO NEXT SEL. PARM
9S22 LDX 2 FX2
9SFL BCT 5 SDET3
9S^= LDN 0 #31 [END OF DETAILS
9TDW DCH 0 0(3) [ SO TERM. WITH ')'
9TYG BCHX 3 £ [UPDATE SDP
9WD6 SBX 3 ACOMMUNE3(2)
9WXQ SLC 3 2 [COUNT OF CHS. IN CSTORE
9XCB OUTPARAM 3,A1,ADATA,CSTORE
9XX2 MFREEW ADATA,CSTORE
9YBL UP
9YW= #END
^^^^ ...654066620001