{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: WTSTAT867)}}
====== WTSTAT867 ======
(George Source)
**Macros used:** [[george:macro:BLOCK|BLOCK]], [[george:macro:BUTTON|BUTTON]], [[george:macro:CHANGE|CHANGE]], [[george:macro:CLEAR|CLEAR]], [[george:macro:CONSOLE|CONSOLE]], [[george:macro:DOWN|DOWN]], [[george:macro:DUMP|DUMP]], [[george:macro:EXTRACODE|EXTRACODE]], [[george:macro:FCAJO|FCAJO]], [[george:macro:FINDJOBQ|FINDJOBQ]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GFCBC|GFCBC]], [[george:macro:HUNT2J|HUNT2J]], [[george:macro:JBC|JBC]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:ON|ON]], [[george:macro:OR|OR]], [[george:macro:READ|READ]], [[george:macro:READY|READY]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SWAP|SWAP]], [[george:macro:UP|UP]], [[george:macro:WSRV|WSRV]]
22^= #LIS K0WTSTAT>K0ALLGEO>K0GREATGEO>K0COMMAND
234P ... SEG WTSTAT,867,SECTION CENT
2388 ...[
23?M ...[
23C6 ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
23GK ...[
23L4 ...[ VERSION 866 WAS PRODUCED FOR DS8221
23PH ...[ AN ENHANCEMENT TO PROVIDE DETAILS OF FILES
23T2 ...[ FOR WHICH JOBS ARE WAITING. 19.11.81
23YG SEGENTRY K1WTSTAT,Q1ENTRY
24D6 [ DEFINES THE CQPRINT/CQ11
24XQ #DEF WJOBNO = A1 [JOB NUMBER
25CB #DEF WNAME = WJOBNO+1
25X2 #DEF WUSER = WNAME+3
26BL #DEF WMISC = WUSER+3
26W= #DEF WYONQ = WMISC+1
27*W #DEF WCONTEXT= WYONQ+1
27TG #DEF WSOURCE1= WCONTEXT+1
28*6 #DEF WSOURCE2= WSOURCE1+1
28SQ #DEF WSOURCE3= WSOURCE2+1
29#B #DEF WURGE = WSOURCE3+1
29S2 #DEF WCPI = WURGE+1
2=?L #DEF WTIMEJ = WCPI+1
2=R= #DEF WARRIVED= WTIMEJ
2?=W #DEF WPROGTIME =WTIMEJ+2
2?QG #DEF WARRIVET= WPROGTIME
2#=6 #DEF WCSIZE = WPROGTIME+2
2#PQ #DEF WFWT = WCSIZE+1
2*9B #DEF WTLR = WFWT+1
2D?W #DEF WTSWAPS = WTLR+1
2D*4 #DEF WMAXSIZE= WTSWAPS+1
2DB= #DEF WWT1 = WMAXSIZE+1
2DCD #DEF WWT2 = WWT1+1
2DDL #DEF WWT3 = WWT2+1
2DFS #DEF WEXTRA = WWT3+1
2DH2 #DEF WPERPTR = WEXTRA+1
2DKB TDIRGENL 4H/C1)
2DLQ WAIT 10HWAITING:-
2DP* #UNSET EWAITFILE
2DRY (
2DWH WORKTEXT 4H -
2D^6 WORK 8HWORKFILE
2F3P )
2F6B XPTR
2FL2 UBASE
2G5L # TABLE FOR WAITING STYLES REFERENCED BY WAITING STYLE/2
2GK= #HAL 0,R1-XPTR
2H4W #HAL R2-XPTR,R3-XPTR
2HJG #HAL R4-XPTR,R5-XPTR
2J46 #HAL R6-XPTR,R7-XPTR
2JHQ #HAL R10-XPTR,0
2K3B #HAL R12-XPTR,0
2KH2 #HAL R14-XPTR,R15-XPTR
2MFG #HAL 0,R17-XPTR
2M^6 #HAL R20-XPTR,R21-XPTR
2NDQ #HAL R22-XPTR,R23-XPTR
2NYB #HAL R24-XPTR,R25-XPTR
2PD2 #HAL R26-XPTR,R27-XPTR
2PXL #HAL R30-XPTR,R31-XPTR
2QC= #HAL R32-XPTR,R33-XPTR
2QWW #HAL R34-XPTR,R35-XPTR
2RBG #HAL R36-XPTR,R37-XPTR
2RW6 #HAL R40-XPTR,R41-XPTR
2S*Q #HAL R42-XPTR,R43-XPTR
2STB #HAL R44-XPTR,0
2T*2 #HAL 0,0
2TSL #HAL R50-XPTR,R51-XPTR
2W#= #HAL R52-XPTR,R53-XPTR
2WRW #HAL R54-XPTR,R55-XPTR
2X?G #HAL R56-XPTR,R57-XPTR
2XR6 #HAL R60-XPTR,R61-XPTR
2Y=Q #HAL R62-XPTR,R63-XPTR
2YQB #HAL R64-XPTR,R65-XPTR
2^=2 #HAL R66-XPTR,R67-XPTR
2^PL #HAL R70-XPTR,R71-XPTR
329= #HAL R72-XPTR,R73-XPTR
32NW #HAL R74-XPTR,0
338G #HAL R76-XPTR,R77-XPTR
33N6 #HAL R100-XPTR,R101-XPTR
347Q #HAL 0,R103-XPTR
35LL #SKI G4<1$1
366= #HAL R104-XPTR,0
36KW #HAL R106-XPTR,R107-XPTR
375G #HAL 0,0
37K6 #HAL R112-XPTR,0
384Q #HAL R114-XPTR,0
38JB #SKI G4
3942 #HAL R116-XPTR,R117-XPTR
39HL #SKI G4<1$1
3=3= #HAL R116-XPTR,0
3=GW #HAL R120-XPTR,R121-XPTR
3?2G #SKI G4
3?G6 #HAL 0,R123-XPTR
3?^Q #SKI G4<1$1
3#FB #HAL 0,0
3#^2 #HAL R124-XPTR,0
3*2? #UNSET EWAITFILE
3*3J (
3*4T #REP 4
3*66 0
3*7C #HAL R136-XPTR,0
3*8N #REP 3
3*9^ 0
3*?= )
3*#H #UNSET EWAITFILE
3**S #SKIP
3*C5 (
3*DL #REP 8
3*Y= 0
3B84 )
3BCW #HAL 0,R147-XPTR
3BXG #HAL R150-XPTR,0
3C3C #REP 5
3C7# 0
3C?9 #HAL R164-XPTR,0
3C*S #HAL 0,R167-XPTR
3C*X #HAL 0,0
3CB5 #HAL 0,R173-XPTR
3CBR #HAL R174-XPTR,0
3CC6 #DEF WSLONG=0?-UBASE
3CWQ WSNUM +WSLONG*2+1
3DBB R1
3DW2 #11555762 [9MOR
3F*L 6HE CORE
3FT= R2
3G#W #22555762 [18MOR
3GSG 15HE BACKING STORE
3H#6 R3
3HRQ #35455644 [END
3J?B 26H OF BACKING STORE TRANSFER
3JR2 R4
3K=L #42544163 [LAS
3KQ= 31HT BLOCK OF FILE TO BE READ DOWN
3L9W R5
3LPG #52304357 [(CO
3M96 39HMMUNICATION FILE) RECORD TO BE APPENDED
3MNQ R6
3N8B #30465154 [FIL
3NN2 21HE TO BECOME AVAILABLE
3P7L R7
3PM= #41564567 [NEW
3Q6W 30H BLOCK OF FILE TO BE READ DOWN
3QLG R10
3R66 #40435755 [3200M
3RKQ 29HMUNICATION FILE TO BE CREATED
3S5B R12
3SK2 #21465154 [FIL
3T4L 14HE TO BE ERASED
3TJ= R14
3W3W #33555762 [MOR
3WHG 24HE SHEETS TO BE AVAILABLE
3X36 R15 #27556554 [MUL
3XGQ 20HTI-FILE TO BE FROZEN
3Y^L R17
3^F= #26455644 [ END
3^YW 19H OF SCHEDULER PERIS
42Y6 R20
43CQ #21644160 [TAP
43XB 14HES TO BE READY
44C2 R21 #25423663 [B.S
44WL 18H.JAM TO BE CLEARED
45B= R22
45TW #30446555 [DUM
46*G 21HPER TO FINISH DUMPING
46T6 R23
47#Q #23645720 [TO
47SB 16HFREEZE FILESTORE
48#2 R24
48RL #10624564 [8RET
49?= 5HRIEVE
49QW R25
4==G #32415663 [ANS
4=Q6 23HWER TO QUESTION COMMAND
4?9Q #DEF R26=R6
4?PB R27
4#92 #44576564 [OUT
4#NL 33HPUT PERIPHERAL FOR ONLINE COMMAND
4*8= R30
4*MW #26457057 [EXO
4B7G 19HTIC TO BE ALLOCATED
4BM6 R31
4C6Q R32
4CGF SEGENTRY K50WTSTAT [MENDED HLSON/HLSOFF
4CMY [ TO APPEND - '/RE-ACTIVATED BY HLS'
4CTC [HENCE CHAR LENGTH OF 41H AND TOTAL LENGTH OF #54
4D2W #54645720 [TO
4D8* 41HBE MADE FULLY STARTED
4DKL R33
4F5= #16674151 [WAI
4FJW 11HT EXTRACODE
4G4G R34 #21525742 [JOB
4GJ6 14H TO BE UNSAVED
4H3Q R35 #24606257 [PRO
4HHB 17HCESSOR FOR A TAPE
4J32 R36 #27624555 [REM
4JGL 20HOTE ENGAGE BUTTON
4K2= R37 #21565756 [NON
4KFW 14H-STANDARD S.U.
4K^G R40
4LF6 #50444563 [DES
4LYQ 37HTRUCTIVE READER TO FREE BACKING STORE
4MDB R41
4MY2 #60455644 [END
4NCL 45H OF OBJ. PROGRAM TRANSFER (OR TIME INTERRUPT)
4NX= R42
4PBW #21525742 [JOB
4PWG 14H TO BE STOPPED
4QB6 R43
4QTQ #23525742 [JOB
4R*B 16H TO BE CONNECTED
4RT2 R44
4S#L #14455644 [END
4SS= 9H OF A JOB
4T?W R50
4TRG #15435756 [CON
4W?6 10HSOLE INPUT
4WQQ R51
4X=B #24455644 [END
4XQ2 17H OF CONSOLE INPUT
4Y9L R52
4YP= #25455644 [END
4^8W 18H OF CONSOLE OUTPUT
4^NG R53
5286 #12446562 [DUR
52MQ 7HING EMS
537B R54
53M2 #12455644 [END
546L 7H OF EMS
54L= R55
555W #34435762 [COR
55KG 25HE UNJAMMER TO CLEAR BLOCK
5656 R56
56JQ #11605757 [POO
574B 6HL TAPE
57J2 R57
583L #23644160 [TAP
58H= 16HE TO BE RELEASED
592W R60
59GG #25445743 [DOC
5=26 18HUMENT TO BE LOADED
5=FQ R61
5=^B #26554147 [MAG
5?F2 19H. TAPE TO BE LOADED
5?YL R62
5#D= #22465762 [FOR
5#XW 15H TIME INTERRUPT
5*CG R63
5*X6 #26675762 [WOR
5BBQ 19HK TAPE TO BE LOADED
5BWB R64
5CB2 #23644160 [TAP
5CTL 16HE TO BE UNLOADED
5D*= R65
5DSW #06412044 [A D
5F#G 3HECK
5FS6 R66
5G?Q #20624567 [REW
5GRB 13HIND TO FINISH
5H?2 R67
5HQL #24445162 [DIR
5J== 17HECT ACCESS DEVICE
5JPW R70
5K9G #22457057 [EX0
5KP6 15HFILE TO BE FREE
5L8Q R71
5Q5Q #37646265 [TRU
5QKB 28HSTED PROGRAM TO RELEASE S.U.
5QNT #UNSET EWAITFILE
5QS# (
5QXR R72 #23645720 [TO
5R3= 16HACCESS SCA OF SU
5R6P )
5R=8 #UNSET EWAITFILE
5R*M #SKIP
5RF6 (
5RJL R72 #15645720 [TO
5S4= 10HACCESS SCA
5S#4 )
5SHW R73
5T3G #26416464 [ATT
5TH6 19HRIBUTIONS TO CHANGE
5W2Q R74
5WGB #13455644 [END
5X22 8H OF DUMP
5XFL R76
5X^= #35412042 [A B
5YDW 26HACKING STORE TO BE ENGAGED
5YYG R77
5^D6 #42415454 [ALL
5^XQ 31HOCATED PERIPHERAL TO BE ENGAGED
62CB R100
62X2 #25455644 [END
63BL 18H OF LISTFILE/INPUT
63W= R101
64*W #30455644 [END
64TG 21H OF SYSTEM ISSUED JOB
65*6 R103
65SQ #23443643 [D.C
66#B 16H.FILE FOR READER
66S2 R104 #14604147 [PAG
67?L 9HE COMMAND
6=P2 R106
6?8L #17645720 [TO
6?N= 12HBE MOPPED ON
6#7W R107 #15645720 [TO
6#MG 10HBE ONLINED
6*76 R112 #21415620 [AN
6*LQ 14HEXECUTIVE SLOT
6B6B R114 #35415620 [AN
6BL2 26HOPERATOR COMMAND TO FINISH
6C5L R116 #22525742 [JOB
6CK= 15H TO BE UNSAVED
6GH2 R120
6H2L #16465762 [FOR
6HG= 11H SWAP SPACE
6H^W R121 #21465154 [FIL
6JFG 14HE TO BE COPIED
6MC= R124 #35435755 [COM
6MWW 26HMAND ISSUER TO BE RELEASED
6M^F #UNSET EWAITFILE
6N44 (
6N6M R136 #52465762 [FOR
6N9= 39H PROCESSOR TO OBTAIN SCA LOCKOUT FOR SU
6N?T )
6NBG R147 #30444164 [DAT
6NW6 21HA COLLECTION TO START
6P*Q R150 #26675051 [WHI
6PTB 19HLST COLLECTING DATA
6Q2J R164 #13455644 [END
6Q7Q 8H OF DUMP
6Q=B R167 #31516042 [IPB
6Q?= 22H OR SU TO BE DEDICATED
6Q## R173 #30414343 [ACC
6Q#B 21HESS TO :SYSTEM.OUTPUT
6Q#G R174 #46624563 [RES
6Q#L 35HPONSE FROM COMMUNICATIONS PROCESSOR
6Q*2 [
6QSL [
6R#= [
6RRW XDAYL +10 [DAY OF MILLISECS
6S?G XDAYM +2513920
6SR6 TENK +10000
6SY# #UNSET EWAITFILE
6T5G WANYFGN 4H4096
6T=Q MAGIC +7036875
6TQB TWENTFOURHR +60*60*24/K9*1000 [1 DAY OF SC COUNTS
6W=2 Q1ENTRY
6WPL MHUNTW 3,ADATA,CSTORE
6X9= LDN 4 A1(3) [X4 TO WAIT MESS
6XNW LDN 6 WAIT(1)
6Y8G LDX 7 4
6YN6 MVCH 6 10
6^7Q MHUNTW 2,CQPRINT,CQ11
6^MB LDX 5 WWT1(2) [B15-23 OF ATYPE
7272 TXL 5 WSNUM(1)
72LL BCC TWT9 [J IF WAIT STYLE NOT IN TABLE
736= LDN 1 UBASE(1)
73KW SRC 5 1
745G ADX 1 5
74K6 LDX 6 0(1)
754Q LDX 1 FX1
75JB BNG 5 TWT2
7642 SRL 6 12
76HL TWT2 ANDN 6 4095
773= BZE 6 TWT9 [J IF WT STYLE NOT IN TABLE
77GW ADX 6 FX1
782G ADN 6 XPTR
78G6 LDX 3 6
78^Q LDCH 3 0(3)
79FB BCHX 6 £
79^2 MVCH 6 0(3) [MOVE IN SUBMESSAGE
7=DL LDN 0 #20
7=Y= LDX 2 7
7?CW DCH 0 0(2) [NEED A GAP FOR CERTAIN WSTYLES
7?XG BCHX 7 £
7#C6 MHUNTW 2,CQPRINT,CQ11
7#CD #UNSET EWAITFILE
7#CQ (
7#D4 [ DS8221 CODE
7#DB [ TEST FOR WAITING STYLES #6 & #12
7#DN LDX 5 WWT1(2)
7#F2 SBN 5 #6 [ #6 = FILE TO BECOME AVAILABLE
7#F# BZE 5 TWTCQFILE
7#FL SBN 5 #12-#6 [ #12= FILE TO BE ERASED
7#FY BNZ 5 TWT7
7#G= TWTCQFILE
7#GJ [ IF CQPRINT/CQFILE CHAINED AFTER WAITING ACTIVITY (ASSUMED
7#GW [ TO BE A CPAT), EXTRACT FILE DETAILS
7#H8 LDXC 0 WJOBNO(2) [ XO = JOB NUMBER
7#HG BCS £ [ B0 = HLS XCODE FLAG
7#HS FINDJOBQ 3,0,TWT9 [ FIND JOB BLOCK
7#J6 FCAJO 3 [ FIND CPAT
7#JD LDX 6 ACC6(3) [ FCB NO. / 'WORK'
7#JQ LDEX 5 ATYPE(3) [ WAITING STYLE
7#K4 HUNT2J 3,CQPRINT,CQFILE,,TWTNOCQ
7#KB LDN 6 CQWTUSER(3) [ ^ FILE DETAILS
7#KN LDN 3 0 [ 'NO CSN' FLAG
7#L2 BRN TWT4
7#L# TWTNOCQ
7#LL [ NO CQPRINT/CQFILE BLOCK
7#LY [ USE ACC6 (X6) OF WAITING ACTIVITY TO
7#M= [ EXTRACT FILE DETAILS
7#MJ [ EXIT IF WAITING STYLE (X5) HAS CHANGED
7#MW SBX 5 WWT1(2)
7#N8 BNZ 5 TWT9 [ DIFFERANT STYLE
7#NG TXU 6 WORK(1) [ X6 = 'WORK' IF WAITING FOR
7#NS BCS TWT2A [ A ! FILE
7#P6 LDN 6 WORKTEXT(1) [ MOVE ' - WORKFILE' INTO
7#PD MVCH 6 12 [ ADATA/CSTORE BLOCK
7#PQ BRN TWT9
7#Q4 TWT2A
7#QB [ USE X6 TO FIND FCB
7#QN LDN 5 0
7#R2 [ END OF DS8221 CODE
7#R# #UNSET EWAITTEST
7#RL GFCBC 6,2,NOCQERR
7#RY #UNSET EWAITTEST
7#S= #SKIP
7#SJ GFCBC 6,2,TWT9
7#SW )
7#T8 #UNSET EWAITFILE
7#TG #SKIP
7#TS (
7#WQ LDX 5 WWT1(2) [WAITING STYLE
7*BB SBN 5 6
7*W2 BNZ 5 TWT7
7B*L LDN 5 0
7BT= LDX 6 WWT2(2) [BACK2 OF FCB
7C#W )
7LM= LDN 6 FUSER1(2) [ USERNAME
7LX4 LDN 3 0 [NO TSN IND.
7L^M JBC TWT4,2,BFDIR [J IF NOT DIRECTORY
7M4= LDX 3 GSIGN
7M6W TWT4 LDN 5 2
7MLG LDX 2 7
7N66 LDN 0 #12 [:
7NKQ TWT5 DCH 0 0(2)
7P5B BCHX 7 £
7PK2 MVCH 6 12
7Q4L LDX 2 7
7QJ= TWT6 SLC 2 2 [BACKSPACE TO 1ST NON-SPACE
7R3W SBN 2 1
7RHG SRC 2 2
7S36 LDCH 0 0(2)
7SGQ SBN 0 #20
7T2B BZE 0 TWT6
7TG2 BCHX 2 £
7T^L LDN 0 #36 [.
7WF= LDX 7 2
7WYW BCT 5 TWT5 [THRO' LOOP TWICE
7W^Y LDN 0 #30
7X32 DCH 0 0(2)
7X44 BCHX 2 £
7X48 BPZ 3 TWT63 [J IF NOT DIRECTORY
7X4# SMO FX1
7X4D LDN 1 TDIRGENL
7X4J MVCH 1 4 [MOVE IN GEN/LANG CODE
7X4N LDX 7 2
7X4S BRN TWT9
7X4Y TWT63
7X56 LDX 1 6
7X68 LDX 5 1(1) [GET GEN. NO.
7X7= SMO FX1
7X8# DVR 5 TENK
7X9B LDCT 7 #200
7X=D LDN 5 4
7X?G MODE 1
7X#J TWT65 CBD 6 0(2) [SET UP GEN. NO.
7X#S LDCH 0 0(2)
7X*4 SBN 0 #20
7X*# BZE 0 TWT67 [IGNORE SPACES
7X*L BCHX 2 £
7XBN TWT67 BCT 5 TWT65
7XCQ LDN 0 #37
7XDS DCH 0 0(2)
7XFW BCHX 2 £
7XGY ADN 1 2 [SET UP LANG. CODE
7XH7 LDN 5 4 [MOVE IN LANG. CODE......
7XHB TWT68 LDCH 0 0(1) [...LESS SPACES
7XHK DCH 0 0(2)
7XHS BCHX 1 £
7XJ3 SBN 0 #20
7XJ= BZE 0 TWT69 [J IF SPACE
7XJF BCHX 2 £
7XJN TWT69 BCT 5 TWT68
7XK4 LDN 0 #31
7XL6 DCH 0 0(2)
7XM8 BCHX 2 £
7XN= LDN 0 #20
7XP# DCH 0 0(2)
7XQB BCHX 2 £
7XRD LDX 7 2
7XSG BZE 3 TWT9 [J IF NO TSN
7XTJ LDX 6 3 [GET TSN.....
7XWL BRN TWTSN [...AND J IF TO TSN O/P CODE
7XWN #UNSET EWAITFILE
7XWQ (
7XWS [ DS8221 CODE
7XWW [ TEST FOR WAITING STYLES #70, #72 & #136
7XWY TWT7 SBN 5 #70-#12
7XX2 BZE 5 TWTEXOF [ #70 = FOR EXOFILE
7XX4 LDX 6 WWT2(2) [ SUPPLEMENTARY INFO
7XX6 SBN 5 #72-#70
7XX8 BZE 5 TWT10 [ #72 = TO ACCESS SCA OF SU
7XX= SBN 5 #136-#72
7XX# BZE 5 TWT10 [ #136= FOR SCA LOCKOUT OF SU
7XXB BZE 6 TWT9 [ NO MORE INFO TO ACT ON
7XXD ADN 5 #136-#35
7XXG [ END OF DS8221 CODE
7XXJ )
7XXL #UNSET EWAITFILE
7XXN #SKIP
7XXQ (
7XY6 TWT7 LDX 6 WWT2(2)
7YCQ BZE 6 TWT9 [J IF NO SUPPLEMENTARY W/S
7YXB SBN 5 #27 [STYLE #35 HAS TSN IN ACC4
7^78 )
7^C2 BZE 5 TWTSN
7^WL SBN 5 #22 [#57 & #61 HAVE
82B= BZE 5 TWTSN [ TSN IN...
82TW SBN 5 2 [ CLONG2...
83*G BZE 5 TWTSN
83T6 ADN 5 #61-#24
84#Q BNZ 5 TWNSN
84SB [ FILE TO BE RETRIEVED
85#2 LDX 5 WWT3(2) [FSTART. X6=FBLKS (WWT3)
85XT ANDX 5 BSB18
85^= SMO FX2
862M STO 4 ACOMMUNE4
8644 LDCH 4 WWT3(2)
865F WSRV 6,5,4,2,3,TWT71 [X2->FILENAME,X3 HAS TSN
866W SMO FX2
868? LDX 4 ACOMMUNE4
86?= LDX 6 2
89NL BRN TWT4 [O/P AS FOR #6 WS
89SH TWT71 SMO FX2
89YD LDX 4 ACOMMUNE4 [RESET CHAR CT
8=4* BRN TWT9
8=8= TWTSN LDX 2 7
8=MW LDN 0 #23 [#
8?7G LDXC 6 6 [CLEAR BIT 0
8?M6 BCC TWTSN2
8#6Q LDN 0 #70 ['X' FOR XENOTAPE
8#LB TWTSN2
8*62 DCH 0 0(2)
8*KL BCHX 2 £
8B5= LDN 0 8
8BJW TWTSN4
8C4G SLL 5 3
8CJ6 SLL 56 3
8D3Q DCH 5 0(2)
8DHB BCHX 2 £
8F32 BCT 0 TWTSN4
8FGL BRN TWT88
8G2= TWNSN SBN 5 #65-#24
8GFW BZE 5 TWDCK [STYLES #65 AND #66 HAVE
8G^G [ DECK NO. IN CLONG2
8H7Q BCT 5 SUSN
8HYQ TWDCK LDX 2 7
8JDB LDN 0 10
8JY2 DVS 5 0 [CONVERT DECK NO.
8KCL DCH 6 0(2)
8KX= BCHX 2 £
8LBW DCH 5 0(2)
8LWG BCHX 2 £ [REMAINDER
8MB6 TWT88 LDX 7 2
8MJR BRN TWT9
8MM2 SUSN SBN 5 #167-#66
8MP9 BZE 5 TWTSN [#166 HAS CSN IN X6
8MTQ [ X7 1ST FREE CHARACTER
8N87 TWT9
8NGJ LDX 2 4
8NT2 SBX 7 4
8P#L SLC 7 2
8PS= LDX 2 FX2
8Q?W STO 7 ACOMMUNE7(2) [CHAR. COUNT
8QRG UP
8QRJ #UNSET EWAITFILE
8QRL (
8QRN [ DS8221 CODE
8QRQ [ ADD WAITING INFO : (CSN,FILENAME(FGN))
8QRS TWTEXOF
8QRW LDXC 0 WJOBNO(2) [ X0 = JOB NUMBER
8QRY BCS £ [ B0 = HLS XCODE FLAG
8QS2 FINDJOBQ 3,0,TWT9 [ FIND JOB BLOCK
8QS4 FCAJO 3 [ FIND CPAT
8QS6 #UNSET EWAITTEST
8QS8 HUNT2J 3,EWDAS,EXOF,,TWTERR
8QS= #UNSET EWAITTEST
8QS# #SKIP
8QSB HUNT2J 3,EWDAS,EXOF,,TWT9
8QSD LDX 6 ASUSN(3) [ STORE CSN IN ADATA/CSTORE
8QSG CALL 0 TWTCSN
8QSJ LDN 0 #34 [ STORE ','
8QSL DCH 0 0(2)
8QSN BCHX 2 £
8QSQ LDX 7 2 [ MOVE FILENAME
8QSS LDN 6 FIP(3)
8QSW MVCH 6 12
8QSY LDX 2 7 [ REMOVE TRAILING SPACES
8QT2 TEX1 SLC 2 2
8QT4 SBN 2 1
8QT6 SRC 2 2
8QT8 LDCH 0 0(2)
8QT= SBN 0 #20
8QT# BZE 0 TEX1
8QTB BCHX 2 £
8QTD LDX 0 EXMARK(3) [ STORE FGN
8QTG ANDN 0 BHIGH
8QTJ BNZ 0 TEX6 [ NO FGN SPECIFIED
8QTL LDN 0 #30 [ STORE OPENING BRACKET
8QTN DCH 0 0(2)
8QTQ BCHX 2 £
8QTS LDX 0 EXMARK(3)
8QTW ANDN 0 BANY
8QTY BZE 0 TEX2 [ FGN SPECIFIED
8QW2 SMO FX1 [ STORE '4096' IF
8QW4 LDN 1 WANYFGN [ 'ANY FGN' SPECIFIED
8QW6 MVCH 1 4
8QW8 BRN TEX5
8QW= TEX2 LDX 7 FIP+4(3) [ CONVERT FGN TO DECIMAL
8QW# SRL 7 12
8QWB LDN 0 0
8QWD SMO FX1
8QWG DVD 7 TENK
8QWJ LDN 1 0
8QWL ADN 0 1
8QWN LDN 7 3
8QWQ MODE 1
8QWS TEX3 CBD 0 0(2)
8QWW LDCH 6 0(2)
8QWY SBN 6 #20
8QX2 BZE 6 TEX4
8QX4 BCHX 2 £
8QX6 TEX4 BCT 7 TEX3
8QX8 MODE 0
8QX= CBD 0 0(2)
8QX# BCHX 2 £
8QXB TEX5 LDN 0 #31 [ STORE CLOSING BRACKET
8QXD DCH 0 0(2)
8QXG BCHX 2 £
8QXJ TEX6 LDN 0 #31 [ STORE CLOSING BRACKET
8QXL DCH 0 0(2) [ OF FILE DESCRIPTION
8QXN BCHX 2 £
8QXQ LDX 7 2 [ RESET X7
8QXS BRN TWT9
8QXW TWT10
8QXY [ TWT7 CODE BRNS HERE FOR CSN TO BE STORED IN ADATA/CSTORE BLOCK
8QY2 [ X6 = CSN
8QY4 CALL 0 TWTCSN
8QY6 BRN TEX6
8QY8 TWTCSN
8QY= [ SUBROUTINE TO STORE CSN IN ADATA/CSTORE BLOCK
8QY# [ X1,X3,X4,X5 UNCHANGED
8QYB LDX 2 7
8QYD LDN 7 #30 [STORE OPENING BRACKET
8QYG DCH 7 0(2) [ OF FILE DESCRIPTION
8QYJ BCHX 2 £
8QYL LDN 7 6
8QYN SLL 6 3
8QYQ TWCSN SLC 6 6
8QYS DCH 6 0(2)
8QYW BCHX 2 £
8QYY SRL 6 3
8Q^2 BCT 7 TWCSN
8Q^4 EXIT 0 0
8Q^6 #UNSET EWAITTEST
8Q^8 (
8Q^= TWTERR
8Q^# GEOERR 1,DS8221
8Q^B NOCQERR
8Q^D GEOERR 1,DS8221A
8Q^G )
8Q^J )
8R?6 #END
^^^^ ...607335230001