(George Source)
Macros used: APPEND, BXE, BXL, BXU, CHAIN, CLOSE, COBJUNUSE, COBJUSE, CREATEB, DOWN, FI, FILEMOVE, FILENUMB, FON, FSHCODE, FSHENTRY, FSHSKIP, GEOERR, HLSINFORM, HUNTMISB, IF, INFORM, ISSUJOB, JANON, JBC, JBS, JENV, JENVNOT, JSWIN, LGEOG, LONGCOOR, LONGHALT, LONGOFF, LONGSET, MENDAREA, MFREE, MHUNT, MHUNTW, ON, OPEN, PICKREP, PUTREP2, SEGENTRY, SETNCORE, SETUPCORE, SUICIDE, SWIN, TESTREP2, TESTRPN2, THEN, TIMECON, TRANSBEG, TRANSRET, UP, VFREEW
22FL #SEG PERFCHAP85 [- A.P.HOLDEN
22^= #OPT K0PERFCHAP=0
23DW #LIS K0PERFCHAP>K0ALLGEO
23YG 8HPERFCHAP
24D6 [ THIS CHAPTER IS ACTIVATED EVERY DATINTERVAL MINUTES TO
24XQ [ APPEND STATISTICS TO :SYSTEM.PERFORMANCE(-0).
25CB [ A NEW FILE IS CREATED AFTER (APERFWAIT) HRS (12) AND
25X2 [ A JOB TO LIST THE OLD ONE IS ISSUED
26BL SEGENTRY K1PERFCHAP,XK1PERF
26W= SEGENTRY K2PERFCHAP,XK2PERF
27*W SEGENTRY K3PERFCHAP,XK3PERF
27D5 ...[
27G# ... FSHENTRY K4PERFCHAP,,SENTFROMA,SENTFROMA
27JH ... FSHENTRY K5PERFCHAP,SENTFROMB,,SENTFROMB
27LQ ... FSHENTRY K7PERFCHAP,,SETUPREC,SETUPREC
27N^ ... FSHENTRY K8PERFCHAP,SETLOAD,,SETLOAD
27R8 ...[
27TG [ VARIOUS DATA:
28*6 NAMEB +16
28SQ 60HMASTER :SYSTEM 00000000PERFORMANCE 0000@0000000
29#B PJOB +28
29S2 28HRJ PERFJOB,:SYSTEM,PERFLIST
2=?L NEXT #20000001 [NEXT GENERATION
2=R= SORTG +11
2?=W #SKI G3
2?QG 16HGEORGE 3 LOADED
2#=6 #SKI G4
2#PQ 16HGEORGE 4 LOADED
2*9B 4H ON
2*P2 UDATE 12H AT
2B8L UTIME 8H
2BN= [ RECORD FORMAT FOR APPEND BLOCK:
2C7W #DEF RDATE=A1+1
2CMG #DEF RTIME=A1+3
2D76 #DEF RMOPS=A1+5
2DLQ #DEF RBAKS=A1+6
2F6B #DEF RCORS=A1+7
2FL2 #DEF ROBJC=A1+8
2G5L #DEF RGEOC=A1+9
2GK= #DEF RFREC=A1+10
2H4W #DEF RGMIL=A1+11
2HJG #DEF ROMIL=A1+13
2J46 #DEF RBRED=A1+15
2JHQ #DEF RBWRT=A1+17
2K3B #DEF RBSPS=A1+19
2KH2 #DEF RCTRA=A1+21
2L2L #DEF RONLS=A1+23
2LG= #DEF RCHCH=A1+25
2L^W #DEF VAR=RCHCH+1
2MFG [ SINGLE LENGTH STATS TABLE:
2M^6 SSL +ACHAP,+RGEOC [CORE FOR GEOCHAPS
2NYB +CHCHCOUNT,+RCHCH [COUNT OF CHAPTER CHANGES
2S*Q [ DOUBLE LENGTH STATS TABLE:
2STB SDL +GPROGTIME,+ROMIL [OBJECT MILL
2T*2 +GEOTIME,+RGMIL [GEORGE MILL
2TSL +BSFSR,+RBRED [FS READS
2W#= +BSFSW,+RBWRT [FS WRITES
2WRW +BSAPS,+RBSPS [SWAP TRANSFERS
2X?G +BSCHCH,+RCTRA [CHAPTER TRANSFERS
2XR6 +BSONLY,+RONLS [ONLINE TRANSFERS (BS)
2Y=Q SEND
2Y#F ...[
2YB8 ...[ EXEC MODE "S/R" FOR BMEEP ENVIR
2YCX ...[
2YFL ...XEC '170 0 601
2YH* ... MODE 0
2YK4 ...#ORD
2YLR ... BRN #20
2YNG ...#EXT
2YQB [
2^=2 [ DIY S/R TO SET UP ANB FOR PERFORMANCE(-0) _ X3
2^PL [
329= SETNB SBX 4 FX1
32NW CREATEB 2
338G SEGENTRY APC14
33N6 #OPT APCSZ=450
347Q LDN 0 APCSZ
34MB DLA 0 CEINF3(2)
34P^ ... FSHCODE AORB
34SJ ...(
34X7 ... MHUNT 2,FILE,FABSNB
34^Q ... BPZ 2 SEXIT
354* ...)
3572 SETNCORE 16,2,FILE,FABSNB
35LL LDX 3 2
366= ADN 1 NAMEB
36KW ADN 2 A1
375G MOVE 1 16
37K6 LDX 1 FX1
37SY ...SEXIT
384Q ADX 4 FX1
38JB EXIT 4 0
3942 [
39HL [ ENTRY FROM EMS
3=3= [
3=GW XK1PERF [SETS UP INITIAL FILE IF NEC
3=N4 ... FSHSKIP [ REDUNDANT CODE & SHOULD BE REMOVED
3=T= ...( [ FROM STANDARD GEORGE ALSO
3?2G LDX 0 CHAPQUOTA [ GET CHAPTERQUOTA
3?G6 SLL 0 1 [ DOUBLE IT
3?^Q STO 0 AWORK1(2) [ AND USE AS FIRST AVERAGE
3#FB LDX 0 IMOPJOBS
3#^2 SLL 0 1
3*DL ADX 0 BACKJOBS
3*Y= STO 0 AWORK2(2) [ FIRST VALUE FOR JOBLIMIT
3*^H ...)
3B2S ... FSHCODE AORB
3B45 ...( [ MARKERS USED FOR SHARED FILESTORE
3B5B ... STOZ AWORK1(2) [ BIT 0 = 'COLLECTING STATS FOR "B"'
3B6M ... [ BIT 23= 'WAITING FOR RECOED FROM "B"'
3B7Y ... STOZ AWORK2(2) [ HOLDS ACTIVITY NO. OF PERF. ACT. SO
3B99 ... [ SUPERVISORY MAY RETURN BLOCK TO IT.
3B=G ... STOZ AWORK3(2) [ =0 IF DIDN'T COLLECT FOR "B" LAST
3B?R ... [ SNAPSHOT ; =1 IF ON FIRST SNAPSHOT
3B*4 ... [ (I.E. LOADED REC.) ELSE = FX2
3BB* ...)
3BBK ... JENVNOT N1CME,CME
3BBT ... STOZ K30+K45+1
3BC5 ... STOZ IDLESYS
3BC* ... STOZ IDLESYS+1
3BCK ...N1CME
3BCW STOZ K30+K45
3BXG STOZ EXECIDLE
3CC6 STOZ EXECIDLE+1
3CWQ X1 CALL 4 SETNB
3D6J ...OPECRE [CREATE FILE OR TRY TO
3DBB OPEN NOBRK,CREATE,APPEND,QUERY,COMMUNE
3DW2 TESTA TESTREP2 OK,SOPEN,ALREADY,THERE,LOST,PLOST,TEMPLOST,PLOST
3F*L GEOERR 1,UNOPEN
3FT= [ FILE ALREADY EXISTS
3G#W THERE OPEN NOBRK,APPEND,QUERY,COMMUNE
3GF# ... TESTREP2 OK,SOPEN,NOFILE,OPECRE,LOST,PLOST,TEMPLOST,PLOST
3GKQ ...[
3GQ8 ...[ TEST FOR NOFILE IN CASE FILE HAS BEEN ERASED
3GWL ...[ IF SO BRANCH BACK TO CREATE A NEW ONE
3H34 ...[
3H7G ... GEOERR 1,UNOPEN2
3H#6 [
3HRQ [ ENTRY FROM K2/K1
3J?B [ OPENS NEW FILE AND SETS UP SPECIAL RECORD TO INDICATE
3JR2 [ G3 OR G4 -EX&TS TO K2 TO APPEND.
3K=L [
3KQ= XK3PERF
3L9W CALL 4 SETNB
3LPG NEWFILE
3M96 LDX 4 NEXT(1)
3MNQ STO 4 A1+14(3) [ALTER GEN-NO TO +1
3MQ# ... FSHCODE AORB
3MRW ...(
3MTD ... FILENUMB 4 [ COUNT NO OF FILES OPEN
3MX2 ... BZE 4 NONOPEN [ J. IF NONE
3MYJ ...NXTFILE [ ELSE MAY HAVE FILE OPEN IF WAITING
3N26 ... CLOSE [ FOR A RECORD FROM "B" WHEN M/C "A"
3N3N ... BCT 4 NXTFILE [ GETS A 'FNEARLY' REPLY. MUST CLOSE
3N5= ...NONOPEN [ ANY FILES OPEN BEFORE CREATING NEW
3N6S ...) [ ONES.
3N8B OPEN NOBRK,CREATE,APPEND,QUERY,COMMUNE
3ND8 ... FSHSKIP
3NN2 TESTREP2 OK,RUNJOB,WRGEN,SUICIDE
3NP3 ... FSHCODE AORB
3NQ4 ...(
3NR5 ... TESTREP2 OK,NOWB,WRGEN,SUICIDE
3NS6 ... BRN SUICIDE
3NT7 ...NOWB
3NW8 ... MHUNT 3,FILE,FABSNB
3NX9 ... LDN 0 #22 [ CHANGE NAME IN FABSNB TO
3NY= ... ADS 0 A1+12(3) [ 'PERFORMANCEB' AND
3N^? ... CALL 4 SETNB [ OPEN FILE FOR M/C "B"
3P2# ... OPEN NOBRK,CREATE,APPEND,COMMUNE,QUERY
3P3* ... TESTRPN2 OK,SUICIDE
3P4B ... FILEMOVE 1,0 [ MOVE FILE FOR "A" TO TOP OF STACK
3P5C ... BRN RUNJOB
3P6D ...)
3P7L NOBRK GEOERR 1,PERFCHAP
3PM= [
3Q6W [ GEN. NO. 4095 REACHED; SO GIVE UP; BUT FIRST
3QLG [ TELL OPERATORS THAT WE ARE DISAPPEARING
3R66 [
3RKQ SUICIDE
3S5B INFORM 1,ERASEPERF,1
3S6R ... FSHCODE AORB
3S88 ...(
3S9K ...SUIC2
3S?2 ... FILENUMB 7 [ SEE IF ANY FILES OPEN
3S#C ... BZE 7 TODIE
3S*S ...NXTCL
3SC9 ... CLOSE [ & IF SO CLOSE THEM ALL
3SDL ... BCT 7 NXTCL [ BEFORE
3SG3 ...TODIE [ 'SUICIDE'ING
3SHD ...)
3SK2 MFIN SUICIDE [GIVE UP IF GEN 4095
3T4L RUNJOB [ISSUE PERFJOB
3TJ= SETNCORE 9,2,ADATA,CREADL
3W3W LDX 4 PJOB(1)
3WHG STO 4 A1(2) [NO OF CHARS
3X36 ADN 1 PJOB+1
3XGQ ADN 2 CPDATA
3Y2B MOVE 1 7 [MOVE RJ COMMAND IN
3YG2 ISSUJOB 0
3Y^L [
3^F= [ SETUP SPECIAL RECORD.
3^YW SOPEN MFREE FILE,FABSNB
3^^N ... FSHCODE AORB
422G ...(
4246 ... JBC NOBRUN,,FSHRUNNING
425Q ... MHUNT 1,FSH,FAPB [ ELSE SET UP A 'LOADED' RECORD
426J ... BNG 1 NOBRUN [ FOR FILE "B"
427B ... SETNCORE 11,2,FILE,FAPB
4288 ... MHUNT 1,FSH,FAPB
4292 ... LDN 6 A1(1)
429S ... LDN 7 A1(2)
42=L ... MOVE 6 11
42?D ... LDX 2 FX2
42#= ... LDX 0 GSIGN [ SET 'COLLECTING FOR "B" MARKER'
42*4 ... ORS 0 AWORK1(2) [ TO GET RECORD APPENDED
42*W ...NOBRUN
42B2 ... FILENUMB 7
42B6 ... SBN 7 2
42B= ... BNG 7 NCLOSEB
42BB ... CLOSE 1
42BG ...NCLOSEB
42BN ... LDX 1 FX1
42CG ...)
42DG SETNCORE 11,2,FILE,FAPB
42Y6 ADN 1 SORTG
43CQ ADN 2 A1
43XB MOVE 1 11
44C2 ADN 2 UDATE-SORTG
44WL LDN 1 IDENTITY+4 [DATE GEORGE LOADED
45B= MOVE 1 2
45TW ADN 2 UTIME-UDATE
46*G LDN 1 IDENTITY+2 [TIME GEORGE LOADED
46T6 MOVE 1 2
47#Q LDN 7 0 [PERFWAITTIME IN MINUTES
47SB LDN 5 0 [CLEAR SWITCH
48#2 [
48RL [ ENTRY TO APPEND TO PERFORMANCE FILE;
49?= [ COLLECT STATISTICS AND SLEEP.
49QW [
4==G XK2PERF
4=Q6 APPEND [APPEND
4?9Q PICKREP 6
4?PB CLOSE
4#92 HLSINFORM (GEOERR),PERFORM,,5 [- FOR JW PHASE 4
4#NL MFREE FILE,FAPB
4#P3 ... FSHCODE AORB
4#PD ...(
4#PT ... LDX 0 AWORK1(2)
4#Q= ... BPZ 0 NONFORB [ J. IF NOT COLLECTING FOR "B"
4#QM ... MHUNT 1,FILE,FAPB [ ELSE SEE IF RECORD ALREADY BACK
4#R4 ... BPZ 1 NOWAITB [ J. IF IT IS
4#RF ... LDN 0 1 [ ELSE
4#RW ... ADS 0 AWORK1(2) [ SET 'WAITING FOR RECORD FROM "B"'
4#S? ... BRN NONFORB
4#SN ...NOWAITB
4#T5 ... LDX 0 AWORK3(2) [ RECORD ALREADY HERE FOR "B"
4#TG ... SBN 0 1 [
4#TX ... BNZ 0 NOTLOADR [ J. IF IT IS NOT A 'LOADED' RECORD
4#W# ... ERN 5 1 [ ELSE CLEAR BIT 23 OF X5 (HLS INFO)
4#WP ...NOTLOADR
4#X6 ... ORN 5 2 [ SET BIT 22 OF X5 (RECORD APPENDED TO
4#XH ... LDX 0 GSIGN [ "B" FILE MARKER IN HLS INFO)
4#XY ... ERS 0 AWORK1(2) [ CLEAR 'COLLECTING FOR "B"' MARKER
4#Y* ... LDX 4 6 [ REMEMBER APPEND REPLY FOR "A"
4#YQ ... BRN XK2PERF [ & J. TO DO APPEND TO "B"
4#^7 ...NONFORB
4#^J ... LDX 0 AWORK3(2) [ SEE IF JUST APPENDED 'LOADED' RECORD
4#^^ ... SBN 0 1 [ FOR "B".
4*2B ... BNZ 0 NOLDREC [ J. IF NOT ELSE
4*2R ... STO 2 AWORK3(2) [ CLEAR 'FIRST RECORD' MARKER BY
4*38 ... [ SETTING 'COLLECTED FOR "B" LAST TIME'
4*3K ... ERN 5 1 [ RESET 'DATA RECORD' MARKER (HLS INFO)
4*42 ...NOLDREC
4*4C ... LDN 0 2
4*4S ... ANDX 0 5 [ WAS LAST APPEND DONE ON "B" FILE (HLS
4*59 ... BZE 0 TREPA [ INFO BIT SET).IF NOT, ONLY 1 APPEND
4*5L ... ERS 0 5 [ REPLY TO CHECK (X6) ELSE CLEAR HLS
4*63 ... PUTREP2 4 [ INFO BIT FOR "B" AND CHECK PREVIOUS
4*6D ... TESTREP2 OK,TREPA,FNEARLY,K3PERFCHAP [ REPLY IN X4
4*6T ...TREPA
4*7= ...)
4*8= PUTREP2 6
4*MW TESTREP2 OK,SLOOP,FNEARLY,K3PERFCHAP
4B7G GEOERR 1,CANTAPP
4BM6 [ WAIT FOR DATINTERVAL MINS.
4C6Q SLOOP BZE 5 PCOLL [J IF LAST RECORD 'SPECIAL'
4CLB VFREEW FILE,CREATE
4CND ...#UNS ISFC
4CQG ...(
4CSJ ... LDX 3 CASTATPTR
4CWL ... BZE 3 SLOOP1
4CYR ... DOWN PERFCAS,1
4D2G ...)
4D49 ...SLOOP1
4D62 LDN 3 0 [TIME WAITING TO APPEND
4D*S ... FSHSKIP
4DKL MWAIT LDN 4 60/FONINTP
4DMT ... FSHCODE AORB
4DQ4 ...(
4DS? ...MWAIT
4DWG ... NGN 4 1 [ SET -VE SHOWS LONGCOOR NOT YET DONE
4DYP ...)
4F2Y ... FSHSKIP
4F5= LONGHALT MFIN,ADPSTYLE,4
4F5Q ... FSHCODE AORB
4F6= ...(
4F6Q ...REWAIT
4F7= ... LONGSET ADPSTYLE,(GEOERR) [ SET WATING STYLE
4F7Q ... MHUNT 1,FILE,FAPB
4F8= ... BPZ 1 SHERENOW [ J. IF /FAPB ARRIVED
4F8Q ... LDN 4 60/FONINTP
4F9= ... LONGCOOR TIMEUP,4 [ ELSE WAIT FOR TIME OR /FAPB ARRIVAL
4F9Q ... MHUNT 1,FILE,FAPB [ IF WOKEN UP SEE WHY
4F== ... BNG 1 TIMEUP [ J. IF NOT FOR /FAPB
4F=Q ...SHERENOW
4F?= ... LONGOFF [ CLEAR LONGSET FIELD
4F?Q ... LDN 0 0
4F#= ... DEX 0 AWORK1(2) [ CLEAR 'WAITING FOR RECORD FROM "B"'
4F#Q ... APPEND
4F*= ... PICKREP 6
4F*Q ... CLOSE
4FB= ... ORN 5 2 [ SET 'RECORD APPENDED FOR "B" MARKER
4FBQ ... HLSINFORM (GEOERR),PERFORM,,5
4FC= ... ERN 5 2 [ AND CLEAR IT AGAIN
4FCQ ... MFREE FILE,FAPB
4FD= ... PUTREP2 6
4FDQ ... TESTREP2 OK,TIMEUP,FNEARLY,K3PERFCHAP
4FF= ...TIMEUP
4FFQ ... LONGOFF [ CLEAR LONGSET FIELD
4FG= ... BNG 4 REWAIT [ J. IF NEVER STARTED WAIT
4FGQ ... LDEX 4 CLONG3(2) [ ELSE GET UNEXPIRED PERIOD AND
4FH= ... BNZ 4 REWAIT [ J. TO CONTINUE WAITING
4FHQ ...)
4FJW LDCT 0 #040
4G4G ANDX 0 FINISH
4G## ... FSHSKIP
4GJ6 BNZ 0 MFIN
4GWH ... FSHCODE AORB
4H8Y ... BNZ 0 SUIC2
4HHB SEGENTRY K79PERFCHAP
4J32 [ MACRO CSDMOPTO MENDS HERE
4JGL ... SEGENTRY APC6
5WGB ADN 3 1
5X22 BXL 3 CDATINT,MWAIT [AND UNTIL TIME UP
5XFL ADX 7 CDATINT [UPDATE TIME WAITING TO LIST
5X^= TXL 7 APERFWAIT
5YDW BCC K3PERFCHAP [J IF TIME UP
5YYG [ READY TO COLLECT STATISTICS
5^D6 PCOLL CALL 4 SETNB [TO OPEN LATEST FILE
5^XQ OPEN NOBRK,APPEND,QUERY,COMMUNE
62CB TESTREP2 OK,OK,LOST,PLOST,TEMPLOST,TLOST,NOFILE,X1
62X2 GEOERR 1,UNOPEN
63BL PLOST OPEN NOBRK,EMPTY,APPEND,COMMUNE [SO EMPTY LAST FILE
63W= TESTREP2 OK,SOPEN [AND BEGIN AGAIN
64*W GEOERR 1,PERFLOST
64TG TLOST MHUNT 3,FILE,FABSNB
65*6 BRN NEWFILE
65*J ...OK
65B2 ... FSHCODE AORB
65BD ...(
65BM ... LDX 2 FX2
65BW ... JBS MCBUP,,FSHRUNNING [ CHECK IF "B" RUNNING
65C# ... STOZ AWORK3(2) [ CLEAR '"B" RUNNING LAST SNAPSHOT'
65CQ ... LDEX 0 AWORK1(2) [ 'WAITING FOR RECORD FROM "B"' ??
65C^ ... STOZ AWORK1(2) [ CAN'T COLLECT FOR 'B' ANY MORE !!!
65D8 ... BZE 0 MCBDOWN [ IF NOT ALL IS O.K.
65D= ... STO 7 AWORK2(2) [PRESERVE X7
65D# ... FILENUMB 7 [HOW MANY FILES OPEN?
65DB ... SBN 7 1 ['B ' FILE STILL OPEN?
65DD ... BZE 7 NOMORE [ ONLY A FILE OPEN
65DK ... CLOSE 1 [ ELSE MUST CLOSE FILE FOR "B" AS
65DQ ...NOMORE LDX 7 AWORK2(2)
65DX ... VFREEW FSH,FAPB [ RECORD CANNOT ARRIVE NOW - ALSO
65F8 ... BRN MCBDOWN [ FREE THE FSH/FAPB LOADED RECORD
65FG ...MCBUP
65FY ... LDX 0 AWORK3(2)
65GB ... BNZ 0 NOLOADED [ J.IF COLLECTED FOR "B" LAST SNAPSHOT
65GS ... LDN 0 1 [ ELSE SET 'LOADED RECORD FOR "B"' BIT
65H= ... STO 0 AWORK3(2) [ AND SET UP A LOADED RECORD AS "B"
65JR ... STO 7 AWORK2(2) [PRESERVE X7
65JS ... SETNCORE 11,2,FILE,FAPB [ HAS JUST COME LIVE
65JT ... MHUNT 1,FSH,FAPB
65JW ... LDN 6 A1(1)
65K2 ... LDN 7 A1(2)
65KD ... MOVE 6 11
65KJ ... LDX 2 FX2
65KP ... LDX 7 AWORK2(2) [ BRING BACK X7
65L2 ...NOLOADED
65L# ... LDX 2 FX2
65LQ ... LDEX 0 AWORK1(2)
65M8 ... BNZ 0 MCBDOWN [ J.IF STILL 'WAITING FOR "B" RECORD'
65ML ... LDX 0 GSIGN [ ELSE
65N4 ... ORS 0 AWORK1(2) [ SET 'COLLECTING FOR "B"' MARKER
65NG ... MHUNTW 3,FILE,FABSNB [ AND
65NY ... LDN 0 #22 [ CHANGE FABSNB TO 'PERFORMANCEB'
65PB ... ADS 0 A1+12(3)
65PS ...TRYAGAIN
65Q= ... OPEN NOBRK,APPEND,QUERY,COMMUNE [ OPEN FILE FOR "B"
65QN ... TESTREP2 OK,SLAVEOPEN,NOFILE,SNOFILE [ J. IF OPENED OK OR NONEXIST
65R6 ... MHUNT 3,FILE,FABSNB [ ELSE
65RJ ... LDN 0 #22 [ CHANGE FABSNB BACK
65S2 ... SBS 0 A1+12(3) [ TO 'PERFORMANCE
65SD ... CLOSE [ AND CLOSE FILE FOR "A"
65SW ... LDX 0 GSIGN [ CLEAR 'COLLECTING
65T# ... ERS 0 AWORK1(2) [ FOR "B"' MARKER
65TQ ... BRN NEWFILE [ J. TO CREATE 2 NEW FILES
65W8 ...SNOFILE
65WL ... CALL 4 SETNB [ FILE DONT EXIST - SET UP CREATE BLOK
65X4 ... OPEN NOBRK,APPEND,CREATE,QUERY,COMMUNE [ & OPEN 'CREATE' IT
65XG ... TESTREP2 OK,SLAVEOPEN,ALREADY,TRYAGAIN [ J. IF OK OR EXISTS
65XY ... BRN SUICIDE [ ELSE GIVE UP PERF. MONITORING
65YB ...SLAVEOPEN
65YS ... VFREEW FILE,CREATE [ - IF THERE WAS ONE
65^= ... FILEMOVE 1,0 [ MOVE "A" FILE BACK TO TOP
65^N ... LDX 0 AWORK3(2) [ CHECK IF 'LOADED' RECORD FOR "B" TO
6626 ... SBN 0 1 [ BE APPENDED - IF SO, DONT GET DATA
662J ... BZE 0 MCBDOWN [ RECORD FROM "B"
6632 ... HUNTMISB 3,JWELL,BCOUNTS
663D ... LDX 4 ALOGLEN(3)
663W ... SETUPCOR 4,3,JWELL,BCOUNTS
664# ... HUNTMISB 2,JWELL,BCOUNTS
664Q ... LDN 0 A1(2) [ ELSE SET UP COPY OF JWELL/BCOUNTS
6658 ... LDN 1 A1(3) [ FOR "B" TO USE
665L ... SMO ALOGLEN(2)
6664 ... MOVE 0 0
666G ... LDX 2 FX2
666Y ... LDX 0 ACTNUM(2) [ AND SAVE ACTIVITY NO. FOR
667B ... STO 0 AWORK2(2) [ RETURN SUPERVISORY TO FIND US !
667M ... TRANSBEG FSHPERFID,PERFCHAP,4,JWELL,BCOUNTS,ACOMMUNE1,MCBDOWN,AUT-
667Y ... ,SUP
668= ...MCBDOWN [ T/BEG TO COLLECT STATS FROM "B"
668N ... MFREE FILE,FABSNB [ TIDY UP
6696 ...SENTFROMA
669J ...SKIPB
66=2 ...)
66#B [
66S2 [ READY TO COLLECT STATISTICS
67?L [
67R= [
67YD ... FSHSKIP
685L ... MFREE FILE,FABSNB [ TIDY UP
68=W LDX 4 ACTPROGS [ GET NO. OF CORE IMAGES
68QG LDX 6 ACTPROGS [ AND REMEMBER
69=6 ... ADX 4 BSUN
69PQ ... SLL 4 1
6=9B ... ADX 4 BSUN
6=P2 ... ADN 4 31
6*LQ SETUPCORE 4,3,FILE,FAPB [ GET BLOCK
6*T2 ... LDX 5 6
6B3= ... SLL 5 1
6B9G ... ADN 5 28
6BCQ ... STO 5 A1(3)
6BL2 LDN 4 FDATE [ LOCATE TO-DAY'S DATE
6C5L LDN 5 RDATE(3)
6CK= MOVE 4 2
6D4W TIMECON CLEANCT [ GET TIME
6DJG LDN 4 ACOMMUNE1(2)
6F46 ADN 5 2
6FHQ MOVE 4 2
6G3B [ SINGLE LENGTH IN.
6GH2 LDN 4 SDL-SSL/2
6H2L LDX 2 FX1
6HG= QUOS SMO SSL(2)
6H^W LDX 0 0
6JFG SMO SSL+1(2)
6J^6 STO 0 0(3)
6KDQ ADN 2 2
6KYB BCT 4 QUOS
6LD2 [ SIMILARLY D/L
6LXL LDN 4 SEND-SDL/2
6MC= QUOD LDX 0 SSL(2)
6MWW SMO SSL+1(2)
6NBG LDN 1 0(3)
6NW6 MOVE 0 2
6P*Q ADN 2 2
6PTB BCT 4 QUOD
6Q9= ... COBJUSE
6QK6 ... STO 0 ROBJC(3) [- CORE FOR OBJECT PROGS
6Q^2 ...#UNS ISTDP
6R#W ...(
6RNQ ... COBJUNUSE [- 'FREE' OBJECT CORE
6S4L ... ADX 0 CFREE
6SDG ...)
6SSB ...#UNS ISTDP
6T8= ...#SKI
6TJ6 ...(
6TY2 ...#SKI G4
6W?W ...(
6WMQ ... LDX 0 COBJFREE [- 'FREE' OBJECT CORE
6X3L ... SLL 0 10
6XCG ... ADX 0 CFREE [- FREE CORE
6XRB ...)
6Y7= ...#SKI G3
6YH6 ... LDX 0 CFREE
6YX2 ...)
6^=W ... STO 0 RFREC(3) [- TOTAL FREE CORE
6^MB [ NOW SEARCH JOBQUEUE TO ASCERTAIN:
7272 [ 1) NO OF MOP/BACKGROUND JOBS
72LL [ 2) NO OF JOBS WITH CORE-IMAGES
736= [ 3) OF (2) THE JOBNUM + CORE SIZE/QUOTA
73KW LDN 2 BJOBQ
745G BXL 6 ACTPROGS,SAME
74K6 LDX 6 ACTPROGS [TAKE MIN VALUE PREV/PRES
754Q SAME STO 6 RCORS(3) [NO OF CORE-IMAGES
75JB ADX 6 6
7642 STO 6 VAR(3) [REC HDDR
76HL LDN 1 VAR+1(3) [PTR TO 1ST FREE WORD
79FB QSEEK
7=DL BZE 6 NOJBS
7=Y= LDX 2 FPTR(2)
7?CW BXE 2 CXJO,NOJBS [NO MORE
7?XG LDX 4 ALOGLEN(2)
7#C6 SBN 4 ASTJOB
7#WQ BZE 4 QSEEK [NON USER JOB
7F?B LDX 4 JMISC(2)
7FR2 ANDN 4 #77
7G=L BZE 4 QSEEK [OR NOT A CORE-IMAGE
7GQ= SBN 6 2
7H9W LDX 4 JOBNUM(2)
7HPG STO 4 0(1) [JOBNO IN
7J96 LDX 4 JCSIZE(2)
7JNQ STO 4 1(1) [AND SIZE/QUOTA IN
7K8B ADN 1 2
7KN2 BRN QSEEK
7L7L ... FSHSKIP
7P5B NOJBS HUNTMISB 2,JWELL
7P6R ... FSHCODE AORB
7P88 ...(
7P9K ...NOJBS
7P?2 ... FSHCODE A,SKIPINB [ USE DATA FOR "A" JOBS
7P#C ... HUNTMISB 2,JWELL,ACOUNTS
7P*S ...SKIPINB
7PC9 ... FSHCODE B,SKIPINA [ USE DATA FOR "B" JOBS
7PDL ... MHUNTW 2,JWELL,BCOUNTS
7PG3 ...SKIPINA
7PHD ...)
7PK2 LDEX 0 JOBENTS+JWENTRY+JOBCTS(2)
7Q4L STO 0 RMOPS(3)
7QJ= LDEX 0 JOBENTS+JOBCTS(2)
7WYW STO 0 RBAKS(3) [STORE NO OF BACKGROUND.
7XDG [ AND NOW FOR SOMETHING COMPLETELY DIFFERENT.
7XY6 [ WE SEARCH THE BS CHAIN
7YCQ [ THE BS CHAIN
7YXB ... LDN 6 0
7^C2 ... ADN 1 1
7^WL ... LDX 2 BBAC
82B= ...REBSA JENVNOT NOCME,CME
82TW ... JANON CPPTR(2),XANON
83*G ... LGEOG CPPTR(2),4
83T6 ... JSWIN CPPTR(2),SWIN
84#Q ... ADN 4 1000
84SB ... JENV SWIN,CME
85#2 ...NOCME LGEOG CPPTR(2),4
85RL ...SWIN STO 4 0(1)
86?= ... LDX 4 AWORK4(2)
86QW ... STO 4 1(1)
87=G ... LDX 4 ACOMMUNE1+6(2)
87Q6 ... STO 4 2(1)
889Q ... ADN 6 3
88PB ... ADN 1 3
8992 ...XANON LDX 0 BACK2(2)
89NL ... ADN 0 1
8=8= ... SBX 2 ASBSAB
8=MW ... BXU 0 BSUN,REBSA
8*62 [ END OF COLLECTION !
8*KL [
8*MJ ... SEGENTRY APC9
8*PG ...#UNS CME01
8*RD ...#SKI
8*TB ... BRN NOTCME
8*X# ...#UNS CME01
8*^= ... NULL
8B38 ... JENVNOT NOTCME,CME
8B56 ... LDN 4 998
8B74 ... STO 4 0(1)
8B92 ... LDN 4 IDLESYS
8B=Y ... LDN 5 1(1)
8B#W ... MOVE 4 2
8BBS ... ADN 6 3
8BCR ... ADN 1 3
8BDQ ...NOTCME SEGENTRY APC10
8BGN ... SEGENTRY APC3
8BJW #UNS APC51
8C4G #SKI
8CJ6 BRN NOIDE [ SKIP EXEC IDLE TIME
8D3Q #UNS APC51
8DHB LDN 4 999 [ SET DEVICE TYPE '999'
8F32 STO 4 0(1)
8FGL LDN 4 EXECIDLE [ GET DATA ADDRESS
8G2= LDN 5 1(1)
8GFW MOVE 4 2 [ AND STORE
8GPN ... ADN 6 3
8GTK ... ADN 1 3
8G^G NOIDE SEGENTRY APC8
8G^M ... LDX 4 1
8G^S ... SBX 1 6
8G^W ... SBN 1 1
8G^^ ... STO 6 0(1)
8H26 ... LDX 1 4
8H2? ... ADS 6 A1(3)
8H2H ...
8H3J ... SEGENTRY APC601
8H4K ...
8H5L ... IF ENV,MEEP
8H6M ... THEN
8H7N ... LDX 2 K31+63 [- CONSOLE T/W IN BDT
8H8P ... LDX 2 0(2) [- X2 -> T/W DEVICE LIST
8H9Q ... LDX 1 FX1
8H=R ... ADN 1 XEC [- EXEC MODE ROUTINE
8H?S ... ADX 1 GEODATUM [- ABSOLUTE ADDRESS
8H#T ... STO 1 K55+2(2) [- STORE IN DEVICE LIST
8H*W ... ALLOT 0 2 [- CALL ROUTINE IN EXEC MODE ('156)
8HBX ... FI
8HCY ...
8HF6 LDN 5 1
8HGT ... FSHCODE B,SKIPINA2
8HJJ ...(
8HL? ... MFREE JWELL,BCOUNTS [ NO LONGER REQUIRED HERE OR IN "A"
8HN2 ... TRANSBEG FSHPERFID,PERFCHAP,5,FILE,FAPB,ACOMMUNE1,,AUT,SUP
8HPP ... [ TO RETURN STATS /FAPB TO "A"
8HRD ... TRANSRET [ AND /FSHARED TO NORMAL SERVICE
8HT7 ...SKIPINA2
8HWW ...)
8HYQ BRN XK2PERF
8H^5 ... FSHCODE A,SKIPINB2
8H^D ...(
8H^R ...SENTFROMB [ ENTRY FOR RETURN SUPERVISORY
8J26 ... FINDACTN 3,AWORK2(2),NOPERFACT [ LOCATE PERFORMANCE ACTIVITY
8J2F ... MHUNTW 2,FILE,FAPB
8J2S ... LDX 3 ACTRING(3)
8J37 ... SBN 3 ACTRING [ CHAIN /FAPB ON 'BPTR' OF FOLLOWING
8J3G ... CHAIN 2,BPTR(3) [ ACT SO IT WONT GET CONFUSED.
8J3T ... FON ADPSTYLE [ WAKE UP PERF ACT IF SNOOZING
8J48 ...NOPERFACT
8J4H ... TRANSRET [ RETURN /FSHARED TO NORMAL SERVICE
8J4W ...SKIPINB2
8J59 ...)
8J5J ... FSHCODE B,SKIPINA3
8J5X ...(
8J6= ...SETUPREC [ ENTRY FROM EMS IN "B"
8J6K ... STOZ K30+K45 [
8J6Y ... STOZ EXECIDLE [ INITIALISE EXEC IDLE COUNTS
8J7? ... STOZ EXECIDLE+1 [
8J7L ... SETNCORE 11,2,FSH,FAPB
8J7^ ... ADN 1 SORTG [
8J8# ... ADN 2 A1 [
8J8M ... MOVE 1 11 [ SET UP 'LOADED' RECORD
8J92 ... ADN 2 UDATE-SORTG
8J9* ... LDN 1 IDENTITY+4
8J9N ... MOVE 1 2
8J=3 ... ADN 2 UTIME-UDATE
8J=B ... LDN 1 IDENTITY+2 [ & GET /FSHARED TO SEND IT TO "A"
8J=P ... MOVE 1 2
8J?4 ... TRANSBEG FSHPERFID,PERFCHAP,8,FSH,FAPB,ACOMMUNE1,,AUT,SUP
8J?C ... UP
8J?Q ...SKIPINA3
8J#5 ...)
8J#D ... FSHCODE A,SKIPINB3
8J#R ...(
8J*6 ...SETLOAD [ ENTRY (SUPERVISORY) FROM EMS IN "B"
8J*F ... FINDACTF 2,,GENERAL,CPERFACT,NOPERFACT,FPTR [ LOCATE PERF. ACT.
8J*S ... MHUNTW 3,FSH,FAPB [ & IF NOT THERE GIVE UP ELSE
8JB7 ... LDX 2 ACTRING(2)
8JBG ... SBN 2 ACTRING [ CHAIN FSH/FAPB ON 'BPTR' OF NEXT ACT
8JBT ... CHAIN 3,BPTR(2) [ TO KEEP IT OUT OF THE WAY
8JC8 ... BRN NOPERFACT
8JCH ...SKIPINB3 [ TO RETURN /FSHARED TO NORMAL SERVICE
8JCW ...)
8JDB MENDAREA 60
8JY2 #END
^^^^ ...721555010004