WSRV [ICL George 3]

This page is read only. You can view the source, but not change it. Ask your administrator if you think this is wrong.
{{htmlmetatags>metatag-description:(ICL George 3 and George 4 GIN macro: WSRV)}}
====== WSRV ======
(GIN Macro)

**Defined in:** [[george:source:DUMP-MACROS|DUMP-MACROS]]

**Used in:** [[george:source:WHATRVSA867|WHATRVSA867]], [[george:source:WTSTAT867|WTSTAT867]]

<code - WSRV.mac.txt>
 **F? ...[??? WSRV SECT FILE FGN 65 DOC  
 **P5 ...[   
 *B8P ...[   THIS MACRO SEARCHES AROUND THE OFFLINE  
 *BN* ...[   CHAIN AND THE ACTIVITY LIST IN ORDER
 *C7^ ...[   TO FIND A TSN OF A RETRIEVE TAPE THAT   
 *CMK ...[   CAN SATISFY THE RETRIEVAL OF THE FILE   
 *D79 ...[   SPECIFIED BY %A, %B, AND %C..   
 *DLT ...[   %A CONTAINS THE INCREMENT NUMBER
 *F6F ...[   %B CONTAINS THE FILE NUMBER 
 *FB? ...[   %C CONTAINS THE FILESTORE NUMBER
 *FL5 ...#MAC WSRV   
 *G5P ...[   
 *GK* ...[   FIRST FIND FILE/FREQ BLOCK  
 *H4^ ...[   
 *HJK ...      LDX   1  BOLC                [START OF OFLC   
 *J49 ...M1WHATRV
 *JHT ...      LDX   1  FPTR(1)             [SKIP FDT FIRST TIME AROUND  
 *K3F ...      BXE   1  CXOL,M2WHATRV       [J IF END OF OFLC
 *KH5 ...      BXL   %A FDTINCNUM(1),M2WHATRV [J IF INCREMENT NOT THERE  
 *L2P ...      BXU   %A FDTINCNUM(1),M1WHATRV [J IF INCREMENT NOT YET REACHED
 *L7X ...      BXL   %C FDTFILSTR(1),M2WHATRV [J IF FILESTORE NOT THERE  
 *L*5 ...      BXU   %C FDTFILSTR(1),M1WHATRV [J IF FILESTORE NOT YET REACHED
 *LG* ...      BXL   %B FDTFILNUM(1),M2WHATRV [J IF FILE NOT THERE   
 *L^^ ...      BXU   %B FDTFILNUM(1),M1WHATRV [J IF FILE NOT YET REACHED 
 *MFK ...      LDX   %D 1                   [FILE FOUND  
 *M^9 ...      ADN   %D FFUSER1             [%D POINTS TO START OF USERNAME  
 *NDT ...[   
 *NYF ...[   NOW FIND FILE/FDINCS BLOCK  
 *PD5 ...[   
 *PJ2 ...      LDX   1  BOLC                [X1 -> OFLC  
 *PMX ...      LDX   0  A1(1)               [COUNT OF ENTRIES
 *PRS ...      BZE   0  M11WHATRV           [J IF NO ENTRIES 
 *PXP ...      LDX   1  FX2                 [START SEARCH FROM PRESENT ACTIVITY  
 *QC* ...M3WHATRV
 *QW^ ...      LDX   1  FPTR(1)  
 *RBK ...      BXE   1  FX2,M11WHATRV       [J IF NO FDINCS  
 *RW9 ...      LDX   0  ATYPE(1) 
 *S*T ...      SRL   0  12   
 *STF ...      ERN   0  +FILE+FDINCS 
 *T*5 ...      BNZ   0  M3WHATRV            [J IF NOT A FDINCS BLOCK 
 *TNS ...      LF       1,FDINCFSNO,%B      [X%B => FILESTORE NUMBER 
 *W4H ...      BXU   %C %B,M3WHATRV         [J IF NOT CORRECT FILESTORE  
 *WD= ...      LDX   0  FDINCNO(1)          [WE HAVE A FDINCS,X0 => NO OF ENTRIES
 *WR^ ...M5WHATRV
 *X?K ...      BZE   0  M3WHATRV            [J IF NOT CORRECT FDINCS 
 *XM# ...      SBN   0  FDINCLEN            [UPDATE MODIFIER 
 *Y33 ...      SMO      0
 *YBQ ...      LDX   %B FDINCINC(1)         [%B => INCREMENT NUMBER POSITIONED AT
 *YQF ...      BXL   %B %A,M3WHATRV         [J IF NOT CORRECT FDINCS 
 *^PP ...      BXU   %B %A,M5WHATRV         [J IF NOT CORRECT INCREMENT NUMBER   
 B29* ...      LDX   %E FDINCTSN(1)         [%E => TSN   
 B2N^ ...      BRN      M12WHATRV           [EXIT
 B7K9 ...M2WHATRV
 B84T ...      LDX   1  FX1                 [NO FREQ BLOCK   
 B8*4 ...      BRN      %F   
 B8K? ...M11WHATRV   
 B8KS ...      STOZ     %E                  [NO FDINCS - INDICATE THIS   
 B8L* ...M12WHATRV   
 B8LX ...      LDX   1  FX1                 [RESET X1
 B?2K ...#NOR
</code>