FILELOG [ICL George 3]

This page is read only. You can view the source, but not change it. Ask your administrator if you think this is wrong.
{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: FILELOG)}}
====== FILELOG ======
(George Source)

**Macros used:** [[george:macro:CLOSE|CLOSE]], [[george:macro:ERALLWF|ERALLWF]], [[george:macro:ERASEND|ERASEND]], [[george:macro:FJOCA|FJOCA]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GDE|GDE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:JBC|JBC]], [[george:macro:MFREE|MFREE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:OPEN|OPEN]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:TESTRPN2|TESTRPN2]], [[george:macro:TRACEIF|TRACEIF]], [[george:macro:UP|UP]]

<code - FILELOG.txt>22FL          SEG      FILELOG,,GEORGE PORTER,FILESTORE 
22^=          SEGENTRY K1FILELOG,START  
23DW    SLAN           4HC1                [TEMPORARY DIRECTORY LANGUAGE
23YG                   4HB1B0              [MONITORING FILE LANGUAGE
24D6                   4HB5B1              [JOB-DESCRIPTION-FILE LANGUAGE   
24XQ                   +0   
25CB    # THIS SEGMENT ERASES THE THE TEMP FILE STACK & THE MONITORING FILE.
25X2    #     IF FILES CANT BE ERASED BECAUSE THEY ARE OPEN, A TO BE ERASED BIT 
26BL    #     BE LEFT IN THEIR DIRECTORY ENTRIES.   
26W=    [   
27*W    START                              [ENTRY POINT 
27TG          TRACEIF  K6FILELOG,99,299,JOBNO(2),FILELOG
28*6          ERALLWF                      [ERASE WORKFILES 
28SQ          SETNCORE 6,1,FILE,FLOCNB  
29#B          SETNCORE 10,3,FILE,FABSNB 
29S2          LDN   0  4                   [RECORD HEADER   
2=?L          STO   0  A1(3)               [HEADER  
2=R=          FJOCA    1,2                 [GET X1->JOB BLOCK   
2?=W          LDN   2  JUSER(1) 
2?QG          ADN   3  A1+1 
2#=6          MOVE  2  3                   [USERNAME TO FABSNB  
2#PQ          MHUNTW   3,FILE,FLOCNB
2*9B          LDN   2  JNAME(1) 
2*P2          ADN   3  A1   
2B8L          MOVE  2  3                   [LOCAL NAME TO FLOCNB
2BN=          LDCT  4  2
2C7W          ANDX  4  JMISC(1)            [BIT 7 OF JMISC SET IF TEMP DIR CREAT
2CMG          SLC   4  8                   [SET X4 =0 OR 1              [SEE NEW
2D76          ERN   4  1                   [=0 IF TEMP DIR EXISTS   
2DLQ          OPEN     NO,GENERAL          [OPEN USERS DIRECTORY
2F6B          TESTRPN2 OK,NO
2FL2    NEXT
2G5L          SMO      4                   [MODIFIER FOR LANGUAGE WORD  
2GK=          LDX   3  SLAN(1)             [GET NEXT LANGUAGE WORD  
2H4W          MHUNT    1,FILE,FLOCNB
2HJG          BZE   3  XITA                [J IF NO MORE TEMP FILES 
2J46          STO   3  A1+5(1)             [LANGUAGE
2JHQ          ADN   4  1                   [INCREASE LANGUAGE WORD MODIFIER 
2K3B ...      STOZ     A1+4(1)             [GEN 1   
2L2L          STOZ     A1+3(1)             [REEL
2LG=          GDE                          [FIND DIRECTORY ENTRY FOR THIS FILE  
2L^W          TESTRPN2 OK,NEXT             [JDF MAY NOT EXIST   
2MFG          MHUNTW   1,FILE,ENT   
2M^6          JBC      XFREE,1,BETEMP      [IGNORE UNLESS TEMPORARY FILE (?)
2NDQ          MHUNT    2,FILE,FABSNB
2NYB          LDX   0  ALOGLEN(2)   
2PD2          STO   0  A1(2)               [SET REC HEADER = LOGICAL LENGTH 
2PXL          ADX   2  0
2QC=          ADN   2  A1-6 
2QWW          MHUNT    1,FILE,FLOCNB       [FIND LOCAL NAME 
2RBG          ADN   1  A1   
2RW6          MOVE  1  6                   [MOVE INTO END OF FABSNB 
2S*Q          ERASEND                      [ERASE NEXT TEMP FILE
2STB          BRN      NEXT 
2T*2    XFREE   
2TSL          FREECORE 1                   [ENT 
2W#=          BRN      NEXT 
2WRW    XITA
2X?G          FREECORE 1                   [FLOCNB  
2XR6          MFREE    FILE,FABSNB  
2Y=Q          CLOSE                        [CLOSE USER'S DIRECTORY  
2YQB          UP
2^=2    NO    GEOERR   BRIEFPM,FILELOG     [UNABLE TO OPEN USER'S DIRECTORY 
2^PL    #END
^^^^ ...71446730000300000000
</code>