LIBTSN867 [ICL George 3]

This page is read only. You can view the source, but not change it. Ask your administrator if you think this is wrong.
{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: LIBTSN867)}}
====== LIBTSN867 ======
(George Source)

**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:ALTLEND|ALTLEND]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:HUNT|HUNT]], [[george:macro:KEEPREP|KEEPREP]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:PUTREP2|PUTREP2]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SSEARCH|SSEARCH]], [[george:macro:UP|UP]], [[george:macro:UPPLUS|UPPLUS]], [[george:macro:USEROPEX|USEROPEX]]

<code - LIBTSN867.txt>22FL          SEG      LIBTSN,,N.R.BOULT,LIBRARY
22^=    #   
23DW          SEGENTRY K1LIBTSN,QK1LIBTSN   
23JR ...[   
23NN ...[  (C)   COPYRIGHT  INTERNATIONAL COMPUTERS LTD  1982   
23SK ...[   
23YG    #   
24D6    #     THIS SEGMENT IS ENTERED FROM USEROPEN AT K1 IF THE TAPE HAS NOT   
24XQ    #     BEEN FOUND IN THE DIRECTORY SPECIFIED IN THE FILE/FABSNB, AND A   
25CB    #     TSN ONLY HAD BEEN GIVEN IN THE ONLINE COMMAND.
25X2    #   
26BL    #     SYSTEM.SERIAL IS SEARCHED AND IF FOUND AND NOT WRONGED, QUERY,
26W=    #     TO BE RETURNED OR DEADED, ANOTHER USEROPEN IS GIVEN SPECIFYING
27*W    #     THE USERNAME FROM SYSTEM.SERIAL.  
27TG    #     IF TSN NOT FOUND IN SYSTEM.SERIAL LIBTSN GOES ACROSS TO   
28*6    #     K2LIBINSEC
28SQ    SUWR           #2000000 
29#B    SOWR           #1000000 
29S2    SQUE           #400000  
2=?L    STBD           #10000000
2=R=    #   
2?=W    #   
2?QG    QK1LIBTSN   
2#=6          LDX   7  ACOMMUNE1(2) 
2#PQ          STO   7  AWORK1(2)
2*9B          LDX   7  ACOMMUNE2(2) 
2*P2          STO   7  AWORK2(2)
2B8L          HUNT     3,FILE,FABSNB
2BN=          SMO      HDREC(3) 
2C7W          LDX   6  A1+1(3)  
2CMG          SSEARCH  NOTIN,6             [FIND ANY ENTRY IN :SYSTEM.SERIAL
2D76          LDX   0  2(3)                [ENTRY FOUND 
2DLQ          BZE   0  NOTOW               [J IF NOT
2F6B          LDX   0  5(3) 
2FL2          BNG   0  NOTOW               [J IF TO BE RETURNED 
2G5L          SLL   0  1
2GK=          BNG   0  WORK 
2H4W          LDX   0  5(3) 
2HJG          ANDX  0  STBD(1)  
2J46          BNZ   0  TBD                 [J IF TO BE DEADED   
2JHQ          LDX   0  5(3) 
2K3B          ANDX  0  SUWR(1)  
2KH2          BNZ   0  UWR                 [J IF USER WRONGED   
2L2L          LDX   0  5(3) 
2LG=          ANDX  0  SOWR(1)  
2L^W          BNZ   0  OWR                 [J IF OPERATOR WRONGED   
2MFG          LDX   0  5(3) 
2M^6          ANDX  0  SQUE(1)  
2NDQ          BNZ   0  QUE                 [J IF QUERY STATUS   
2NYB          LDX   2  3
2PD2          HUNT     3,FILE,FABSNB
2PXL          ADN   2  2
2QC=          ADN   3  A1+1 
2QWW          MOVE  2  3                   [MOVE IN USER NAME   
2RBG          STOZ     3(3) 
2RW6          ADN   3  3
2S*Q          LDN   4  1(3) 
2STB          MOVE  3  5                   [ZEROIZE LOCAL NAME  
2T*2          NGN   0  1
2TSL          STO   0  6(3) 
2W#=          STO   6  7(3) 
2WRW          SBN   3  A1+4 
2X?G          LDN   0  10   
2XR6          STO   0  HDREC(3) 
2Y=Q          ALTLEND  3,12,FILE,FABSNB    [CORRECT LENGTH  
2YQB          CLOSETOP                     [SYSTEM.SERIAL   
2^=2          USEROPEX XBRKIN,AWORK1(2),AWORK2(2)   
2^PL          UPPLUS   1
329=    NOTIN   
32NW          CLOSETOP  
338G          ACROSS   LIBINSEC,2   
33N6    UWR 
347Q          KEEPREP  7,USWRONG
34MB          BRN      UPCL 
3572    OWR 
35LL          KEEPREP  7,OPWRONG
366=          BRN      UPCL 
36KW    QUE 
375G          KEEPREP  7,QUERY  
37K6          BRN      UPCL 
384Q    TBD 
38JB          KEEPREP  7,DEADED 
3942          BRN      UPCL 
39HL    XBRKIN  
3=3=          UP
3=GW    NOTOW   
3?2G          LDX   3  5(3) 
3?G6          SLL   3  1
3?^Q          BNG   3  WORK                [J IF WORK TAPE  
3#FB          KEEPREP  7,POOLTAPE   
3#^2          BRN      UPCL 
3*DL    WORK
3*Y=          KEEPREP  7,WORKTAPE   
3BCW    UPCL  CLOSETOP  
3BXG          PUTREP2  7
3CC6          UPPLUS   1
3CWQ          MENDAREA 50,K99LIBTSN 
3DBB    #END
^^^^ ...42526004000100000000
</code>